Automatic create and set html hidden field base on Bootstrap buttons radio values Javascript/Coffeescript plugin

buttons_radio.js.coffee

# Automatic create and set html hidden field
# base on Bootstrap buttons radio values
# Javascript/Coffeescript plugin
#
# Html/Slim
# 	.btn-group data-toggle='buttons-radio' data-field='offer[type]'  data-init-val=@offer.type
# 		a.btn href='#' data-val='flat' Flat
# 		a.btn href='#' data-val='house' House
#
# Usage
# 	$ -> Common.buttons_radio()
#
Common.buttons_radio = ->
	set_hidden_value = (name, val) ->
		$("[name='#{name}']").val(val).change()

	$(".btn-group[data-toggle='buttons-radio'] .btn").click (e) ->
		name = $(@).closest("[data-toggle='buttons-radio']").data('field')
		val = $(@).data('val')

		set_hidden_value(name, val)

		e.preventDefault()

	# create hidden fields before any click, allow use them in other scripts
	$(".btn-group[data-toggle='buttons-radio']").each ->
		name = $(@).data('field')
		if $("[name='#{name}']").size() == 0
			$("<input type='hidden' name='#{name}' />").appendTo(@)

	# restore selection base on html
	# (for validation on server and restory state after it)
	$(".btn-group[data-init-val]").each ->
		val = $(@).data('init-val')
		$(".btn[data-val='#{val}']", @).click()