The Grapheme Cluster regexes, in P6 regex form

egc.p6

# the EGC rule, in P6 form (UAX#29, Table 1b)

use v6;

# note that | alternatives in the Unicode syntax is really || in P6 syntax
# ("Note that given alternates (X|Y), the first match is taken.")

my token CRLF { <:GCB<CR>> <:GCB<LF>> }
my token RI-Sequence { <:GCB<Regional_Indicator>>+ }
my token Hangul-Syllable {
    || <:GCB<L>>*             <:GCB<V>>+ <:GCB<T>>*
    || <:GCB<L>>* <:GCB<LV>>  <:GCB<V>>* <:GCB<T>>*
    || <:GCB<L>>* <:GCB<LVT>>            <:GCB<T>>*
    || <:GCB<L>>+
    || <:GCB<T>>+
}

my token base { <-:M> }
my token extended_base { <base> | \c[ZERO WIDTH JOINER] | \c[ZERO WIDTH NON-JOINER] }
my token LGC {
    || <CRLF>
    || [ <RI-Sequence> | <Hangul-Syllable> | <-:GCB<Control>> ] <:Grapheme_Extend>*
    || .
}
my token EGC {
    || <CRLF>
    || <:GCB<Prepend>>*
       [ <RI-Sequence> | <Hangul-Syllable> | <-:GCB<Control>> ]
       [ <:Grapheme_Extend> | <:GCB<SpacingMark>> ]*
    || .
}

"नि" ~~ m:g/<LGC>/; say "Legacy Grapheme Cluster: ", +$/;
"नि" ~~ m:g/<EGC>/; say "Extended Grapheme Cluster: ", +$/;