bfencode.bf

[
Encodes the input string, until newline, to a Brainfuck program that prints this string

The BF code will use the current cell only, which is the fastest possible way to print
in Brainfuck, despite producing longer code than other methods.

registers:
- '+'/'-'/'.'
- prev
- input
- prevdup1
- newdup1
- cmp
- prevdup2
- newdup2
]

++++ ++++ ++++ ++++  ++++ ++++ ++++ ++++  ++++ ++++ +++
>>,
[<+<.>>-]
<<+++.--->
#
---- ---- --[++++ ++++ ++
  [>>+>>>+<<<<<-]
  >,[<+>>>+>>>+<<<<<-]
  #
  >>> go to cmp
  >[>[-<->>>-<]>+[-<<<+>[-]>>>]<<<]>[-]<< cmp (consumes prev2 and new2)
  [- if prev gt new
    >-< set else
    <[<->-] prev sub new
    <<<<++>>>> switch to minus
    <[<<<.>>>-]
    <<<+.--->>> print dot and reset to plus
    >>
  ]>+[- else (prev le new)
    <<<[>-<-] new sub prev
    >[<<<<.>>>>-]
    <<<<+++.--->>>> print dot
    >>
  ]
  <<[-] clear new
  <[-] clear prev
  <<
---- ---- --]

bfencode.min.bf

+++++++++++++++++++++++++++++++++++++++++++>>,[<+<.>>-]<<+++.--->----------[++++++++++[>>+>>>+<<<<<-]>,[<+>>>+>>>+<<<<<-]>>>>[>[-<->>>-<]>+[-<<<+>[-]>>>]<<<]>[-]<<[->-<<[<->-]<<<<++>>>><[<<<.>>>-]<<<+.--->>>>>]>+[-<<<[>-<-]>[<<<<.>>>>-]<<<<+++.--->>>>>>]<<[-]<[-]<<----------]