notes-up 2.0.2 AUR patch

libmarkdown.patch

diff --unified --recursive --text src.org/Notes-up-2.0.2/vapi/libmarkdown.vapi src.new/Notes-up-2.0.2/vapi/libmarkdown.vapi
--- src.org/Notes-up-2.0.2/vapi/libmarkdown.vapi	2019-05-06 06:04:28.000000000 +0200
+++ src.new/Notes-up-2.0.2/vapi/libmarkdown.vapi	2020-04-03 02:06:35.690683270 +0200
@@ -41,7 +41,7 @@
 	public void initialize ();
 	public void with_html5_tags ();
 	public void shlib_destructor ();
-	public char markdown_version[];
+	public char markdown_version[512];
 
 	[Compact]
 	[CCode (cname = "MMIOT", cprefix = "mkd_", free_function = "mkd_cleanup")]
@@ -125,4 +125,4 @@
 		NOSTYLE,
 		EMBED
 	}
-}
\ No newline at end of file
+}

PKGBUILD

# Contributor: NicoHood <archlinux {cat} nicohood {dog} de>
# Maintainer: Matthew Sexton <wsdmatty (at) _gmail_ (dot) _com_>
# PGP ID: 97928FA059F8050487930EAFACF6C1A315EDCB52

pkgname=notes-up
_pkgname=Notes-up
pkgver=2.0.2
pkgrel=2
pkgdesc="Markdown style notes manager written for elementary OS"
arch=('i686' 'x86_64')
url="https://github.com/Philip-Scott/Notes-up"
license=('GPL2')
depends=('granite' 'gtksourceview3' 'webkit2gtk' 'gtkspell3' 'discount')
makedepends=('cmake' 'vala')
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/Philip-Scott/${_pkgname}/archive/${pkgver}.tar.gz" "libmarkdown.patch")
sha512sums=('071bf49ce970dabc815b79b768272efab4599ae0e496cc842b82b726d19bd645c7211d4ce9f56dda7cd6b77cad5ab4a1918ae9049fcec5bce6410929cc699dab'
            '99a265882133e1a034f6633ce3418cb182b791bb2d1b02e2326efb14e8345da78f916c5f791284e9c32fd42eaa33fad0c82f74ef5b7dab0fca049fda9d1fc31f')

prepare() {
    cd "${_pkgname}-${pkgver}"
    patch --forward --strip=2 --input="${srcdir}/libmarkdown.patch"
}

build() {
    cd "${_pkgname}-${pkgver}"
    mkdir -p build
    cd build
    cmake -Dnoele=1 -DCMAKE_INSTALL_PREFIX=/usr ../
    make
}

package() {
    make -C "${_pkgname}-${pkgver}/build" DESTDIR="${pkgdir}" install
}