Radio script for mpv

radio-mpv.bat

@echo off

rem # Listen to the radio using mpv
rem # Created by coreb1te
rem # Licensed by GPL v.2
rem # --------------------------------------
 set VERSION=

  set PLAY_COMMAND=mpv --ytdl=no --script-opts=autoload-disabled=yes
  set CACHE_OPTIONS=Enabled
  set COMMAND_TEST=mpv
  goto checking_mpv_system

 :listen_function
   cls
   echo.
   echo [Selected: %NAME_STATION%]
   echo [Command used: %PLAY_COMMAND%]
   echo.
   echo Type 'q' to return
   echo.
   %PLAY_COMMAND% %STATION%
   goto menu_broadcasting_stations

 :checking_mpv_system
   %COMMAND_TEST%
   if %ERRORLEVEL%==0 goto menu_broadcasting_stations
   cls
   echo.
   echo - Error: You must install mpv player -
   echo.
   echo - Help -
   echo     * Official website: http://mpv.io
   echo.
   echo Press 'ENTER' to exit
   pause > nul
   exit

 :menu_broadcasting_stations
  cls
  echo.
  echo modified radio-mpv %VERSION%
  echo.
  echo Available broadcasting stations:
  echo.
  echo (1)  - CRo_D-dur_Classical
  echo (2)  - TouhouRadio
  echo (3)  - No_Agenda_Stream
  echo (4)  - blank
  echo.
  echo (c)  - cache options
  echo (q)  - quit
  echo.
  echo CACHE: %CACHE_OPTIONS%
  echo.

  set /p BSTATION=Choose an option;

  if %BSTATION%==* goto error_start
  if %BSTATION%==q goto exit_menu
  if %BSTATION%==quit goto exit_menu
  if %BSTATION%==c goto enable_disable_cache
  if %BSTATION%==1 goto CRo_D-dur_Classical
  if %BSTATION%==2 goto TouhouRadio
  if %BSTATION%==3 goto No_Agenda_Stream
  if %BSTATION%==4 goto blank
  goto error_start

  :error_start
    cls
    echo.
    echo Invalid option, please, choose any available option
    echo.
    echo Press 'ENTER' to return
    pause > nul
    goto menu_broadcasting_stations

  :exit_menu
   exit

  :CRo_D-dur_Classical
    set NAME_STATION=CRo_D-dur_Classical
    set STATION=http://amp.cesnet.cz:8000/cro-d-dur-256.ogg.m3u
    goto listen_function
	
  :TouhouRadio
    set NAME_STATION=TouhouRadio
    set STATION=http://touhouradio.com:8000/touhouradio.mp3
    goto listen_function
	
  :No_Agenda_Stream
    set NAME_STATION=No_Agenda_Stream
    set STATION=http://listen.noagendastream.com:80/noagenda
    goto listen_function

  :blank
    set NAME_STATION=blank
    set STATION=
    goto listen_function

 :enable_disable_cache
  cls
  echo.
  echo [MPV CACHE]
  echo.
  echo (1) - Enable
  echo (2) - Enable and define amount
  echo (3) - Disable
  echo.
  set /p CACHE=Choose an option;

  if %CACHE%==* goto error_cache
  if %CACHE%==1 goto enable_cache
  if %CACHE%==2 goto enable_and_define_cache
  if %CACHE%==3 goto disable_cache
  goto error_cache

  :error_cache
    cls
    echo.
    echo Invalid option, please, choose any available option
    echo.
    echo Press 'ENTER' to return
    pause > nul
    goto enable_disable_cache

  :enable_cache
    set PLAY_COMMAND=mpv
    set CACHE_OPTIONS=Enabled
    goto menu_broadcasting_stations

  :enable_and_define_cache
    echo.
    set /p AMOUNT= Type the amount;
    set PLAY_COMMAND=mpv --cache=%AMOUNT%
    set CACHE_OPTIONS=Enabled (%AMOUNT% KiB)
    goto menu_broadcasting_stations

  :disable_cache
    set PLAY_COMMAND=mpv
    set CACHE_OPTIONS=Disabled
    goto menu_broadcasting_stations