dict-sig.sml

signature DICT =
sig
    type 'a dict
    type key

    exception NotFound of key
    
    val empty : 'a dict
    val find : key * 'a dict -> 'a (* may raise NotFound *)
    val bind : key * 'a * 'a dict -> 'a dict
end

dict-test.sml

structure StringDict = DictFn(structure Key = StringKey)

val my_dict =
    List.foldr (fn ((k, v), d) => StringDict.bind (k, v, d)) StringDict.empty
    [ ("foo", 1)
    , ("baz", 2)
    , ("bax", 3)
    , ("bar", 4)
    ]

fun index k = 
    print ("my_dict[" ^ k ^ "] = " ^ Int.toString (StringDict.find (k, my_dict)) ^ "\n")
    handle StringDict.NotFound k => print ("my_dict[" ^ k ^ "] = NULL\n")

val () = List.app index ["foo", "bar", "asdf"]

dict.sml

functor DictFn (structure Key : KEY) :> DICT where type key = Key.key =
struct

    type key = Key.key
    type 'a dict = (key * 'a) list

    exception NotFound of key

    val empty = []
    fun find (k, d) =
            case List.find (fn (k', _) => Key.equal (k, k')) d
              of NONE => raise NotFound k
               | SOME (_, v') => v'
    fun bind (k, v, d) = (k, v)::d

end

key-sig.sml

signature KEY =
sig
    type key 
    val equal : key * key -> bool
end

Makefile

.DEFAULT: dict-test

dict-test: dict-test.uo
	mosmlc -toplevel $^ -o $@

key-sig.ui key-sig.uo: key-sig.sml
	mosmlc -toplevel -c $^

dict-sig.ui dict-sig.uo: dict-sig.sml
	mosmlc -toplevel -c $^

dict.ui dict.uo: key-sig.ui dict-sig.ui dict.sml
	mosmlc -toplevel -c $^

string-key.ui string-key.uo: key-sig.ui string-key.sml
	mosmlc -toplevel -c $^

dict-test.ui dict-test.uo: string-key.ui dict.ui dict-test.sml
	mosmlc -toplevel -c $^

clean:
	$(RM) *.ui *.uo test

string-key.sml

structure StringKey :> KEY where type key = string =
struct
    type key = string
    val equal = op =
end