Apple Script that _should_ export all selected .pages documents to PDF. Doesn't work due to Sandboxing.

Pages2PDF.script

on run {input, parameters}
	repeat with _document in input
		
		tell application "Finder"
			set _directory to get container of file _document
			
			set _documentName to name of _document
			if _documentName ends with ".pages" then ¬
				set _documentName to text 1 thru -7 of _documentName
			
			set _PDFName to _documentName & ".pdf"
			set _incrementIndex to 1
			repeat until not (exists file _PDFName of _directory)
				set _PDFName to ¬
					_documentName & "-" & (_incrementIndex as string) & ".pdf"
				set _incrementIndex to _incrementIndex + 1
			end repeat
			
			set _location to (_directory as string) & _PDFName
		end tell
		
		tell application "Pages"
			
			activate
			open _document
			
			with timeout of 1200 seconds
				export front document to file _location as PDF
			end timeout
			
			close front document
			
		end tell
		
	end repeat
	return input
end run