Medium - Elixir Process Registry Tutorial Part 4

process_registry_v04.exs

defmodule ProcessRegistry do
  use GenServer

  # Client API #
  def start_link do
    GenServer.start_link(__MODULE__, nil, name: :registry)
  end

  def register_name(key, pid) when is_pid(pid) do
    GenServer.call(:registry, {:register_name, key, pid})
  end

  def unregister_name(key) do
    GenServer.call(:registry, {:unregister_name, key})
  end

  def whereis_name(key) do
    GenServer.call(:registry, {:whereis_name, key})
  end

  # Server API #
  def init(nil) do
    {:ok, %{}}
  end

  def handle_call({:unregister_name, key}, _from, registry) do
    {:reply, key, Map.delete(registry, key)}
  end

  def handle_call({:register_name, key, pid}, _from, registry) do
    case Map.get(registry, key, nil) do
      nil ->
        Process.monitor(pid)
        registry = Map.put(registry, key, pid)
        {:reply, :yes, registry}

      _ -> {:reply, :no, registry}
    end
  end

  def handle_call({:whereis_name, key}, _from, registry) do
    {:reply, Map.get(registry, key, :undefined), registry}
  end
end