IDrank20ProteinShakesIn5SecondsBecauseJohnCenaFuckingRobbedMyDumbbells (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title IDrank20ProteinShakesIn5SecondsBecauseJohnCenaFuckingRobbedMyDumbbells
author Stingby12
homepage https://www.tiktok.com/@jzuqiai/video/7283862246881545505

again_interval 0.05

verbose_logging

========
OBJECTS
========

Background
brown lightbrown
10101
10101
10101
10101
10101
CrackedFloor
brown lightbrown black
12101
10220
20202
12121
10121
Hole
brown lightbrown black
12221
22222
22222
22222
12221
Wall
red darkred
00010
11111
01000
11111
00010
Void
black



Player0
black orange green black 
.000.
.111.
33333
.222.
.3.3.
Player1
black orange yellow black 
.000.
.111.
33333
.222.
.3.3.
Player2
black orange red black 
.000.
.111.
33333
.222.
.3.3.
Player3
black orange pink black 
.000.
.111.
33333
.222.
.3.3.
PlayerX
darkgray
.....
.....
00000
.....
.0.0.

Weight
black darkgray
.000.
01110
01010
01110
.000.
WeightH
black darkgray
00000
00000
..1..
00000
00000
WeightV
black darkgray
00.00
00.00
00100
00.00
00.00
RollH
transparent
RollV
transparent
StopTP
transparent

Protein
darkbrown gray
.111.
.000.
.010.
.010.
.000.

Cena
black orange blue darkblue
..1..
.333.
23332
23332
.0.0.
CenaDead
black orange blue darkblue
.22..
0333.
.3331
0333.
.22..



Button
blue darkblue
.....
.000.
.010.
.000.
.....
PressedTP
transparent
CloseTP
transparent
DoorGClose
green darkgreen
11111
10001
10001
10001
11111
DoorGOpen
green
0.0.0
.....
0...0
.....
0.0.0
DoorPClose
red darkred
11111
10001
10001
10001
11111
DoorPOpen
red
0.0.0
.....
0...0
.....
0.0.0

=======
LEGEND
=======

■ = Void
. = Background
x = CrackedFloor

% = Wall
* = Weight
- = WeightH
| = WeightV

P = Player0
1 = Player1
2 = Player2
3 = Player3
O = Protein
£ = Cena

ù = Button
$ = DoorGClose
! = DoorPOpen

Player = Player0 or Player1 or Player2 or Player3
Weights = Weight or WeightH or WeightV

DoorOpen = DoorGOpen or DoorPOpen
DoorClose = DoorGClose or DoorPClose

Cover = Player or Protein or Weights
Block = Wall or Void or DoorClose or Protein or Weights

=======
SOUNDS
=======

Player0 move 67762507
Weight move 27191707
WeightH move vertical 27191707
WeightH move horizontal 35658707
WeightV move horizontal 27191707
WeightV move vertical 35658707
sfx4 88492304
Protein move 52112507

Hole create 81554502
sfx3 76468707

PlayerX create 51421706
sfx0 46704706
sfx1 60017703
CenaDead create 29964902
sfx2 23228101

PressedTP create 85762500
CloseTP create 11967904

undo 89674306
restart 27105906
endlevel 18414108

================
COLLISIONLAYERS
================

Background
CrackedFloor, Hole

Button
CenaDead
Void, Wall, Player, Cena, Protein, Weight, WeightH, WeightV, DoorClose

PlayerX
DoorOpen

PressedTP, CloseTP
RollH, RollV
StopTP

======
RULES
======

[ action Player PlayerX ] -> [ Player ] sfx0
[ action Player ] -> [ Player PlayerX ]

late [ PlayerX no Player ] -> [ ] sfx0
[ > Player ] [ StopTP ] -> [ > Player ] [ ]



[ > Player | Hole ] -> [ Player | Hole ] sfx3
[ > Player | Wall ] -> [ Player | Wall ]
[ > Player | DoorClose ] -> [ Player | DoorClose ]

[ > Player0 | Weight ] -> [ Player0 | Weight ]
horizontal [ > Player0 | WeightV ] -> [ Player0 | WeightV ]
vertical [ > Player0 | WeightH ] -> [ Player0 | WeightH ]
[ > Player | Weights | Block ] -> [ Player | Weights | Block ]


[ > Player0 PlayerX | Protein ] -> [ Player1 | ] sfx1
[ > Player1 PlayerX | Protein ] -> [ Player2 | ] sfx1
[ > Player2 PlayerX | Protein ] -> [ Player3 | ] sfx1

[ > Player3 | Cena ] -> [ Player0 | CenaDead ]
[ > Player3 PlayerX | Cena ] -> [ Player0 | CenaDead ]

[ > Player1 | Weight ] -> [ > Player0 | > Weight ]
[ > Player2 | Weight ] -> [ > Player1 | > Weight ]
[ > Player3 | Weight ] -> [ > Player2 | > Weight ]

horizontal [ > Player1 | WeightV ] -> [ > Player0 | > WeightV ]
horizontal [ > Player2 | WeightV ] -> [ > Player1 | > WeightV ]
horizontal [ > Player3 | WeightV ] -> [ > Player2 | > WeightV ]

vertical [ > Player1 | WeightH ] -> [ > Player0 | > WeightH ]
vertical [ > Player2 | WeightH ] -> [ > Player1 | > WeightH ]
vertical [ > Player3 | WeightH ] -> [ > Player2 | > WeightH ]



horizontal [ RollH | WeightH no StopTP ] -> [ > RollH | > WeightH ] again
vertical [ RollV | WeightV no StopTP ] -> [ > RollV | > WeightV ] again

horizontal [ > Player | WeightH | no Block ] -> [ Player > RollH | > WeightH | ] again
vertical [ > Player | WeightV | no Block ] -> [ Player > RollV | > WeightV | ] again

[ RollH | > WeightH | WeightH ] -> [ | WeightH StopTP > RollH | > WeightH ] sfx4
[ RollV | > WeightV | WeightV ] -> [ | WeightV StopTP > RollV | > WeightV ] sfx4

[ RollH | > WeightH | Protein ] -> [ | WeightH StopTP | > Protein ] sfx4
[ RollV | > WeightV | Protein ] -> [ | WeightV StopTP | > Protein ] sfx4

[ RollH | > WeightH | Block ] -> [ | WeightH StopTP | Block ] sfx4
[ RollV | > WeightV | Block ] -> [ | WeightV StopTP | Block ] sfx4

[ RollH | > WeightH | Cena ] -> [ | WeightH StopTP | CenaDead ] sfx4
[ RollV | > WeightV | Cena ] -> [ | WeightV StopTP | CenaDead ] sfx4



[ > Player | Protein ] -> [ > Player | > Protein ]

[ > Player1 | Protein | Protein ] -> [ > Player1 | > Protein | > Protein ]
[ > Player2 | Protein | Protein ] -> [ > Player2 | > Protein | > Protein ]

[ > Player2 | Protein | Protein | Protein ] -> [ > Player2 | > Protein | > Protein | > Protein ]

[ Player3 ] [ > Protein | Protein ] -> [ Player3 ] [ > Protein | > Protein ]


[ > Protein | stationary Block ] -> [ Protein | Block ]
[ > Player | stationary Protein ] -> [ Player | Protein ]

[ > Player1 CrackedFloor | Weight ] -> [ > Player2 Hole | > Weight ]
horizontal [ > Player1 CrackedFloor | WeightV ] -> [ > Player1 Hole | > WeightV ]
vertical [ > Player1 CrackedFloor | WeightH ] -> [ > Player1 Hole | > WeightH ]

[ > Player2 CrackedFloor ] -> [ > Player2 Hole ]
[ > Player3 CrackedFloor ] -> [ > Player3 Hole ]


[ Weights CrackedFloor ] -> [ Weights Hole ]
late [ Protein Hole ] -> [ Hole ] sfx2
late [ Weights Hole ] -> [ Hole ] sfx2
late [ Weights CrackedFloor ] -> again



late [ Button Cover ] -> [ Button Cover PressedTP ]
late [ PressedTP no Cover ] -> [ CloseTP ]
late [ CloseTP ] [ PressedTP ] -> [] [ PressedTP ]

late [ DoorGClose ] [ PressedTP ] -> [ DoorGOpen ] [ PressedTP ]
late [ DoorPOpen no Cover ] [ PressedTP ] -> [ DoorPClose ] [ PressedTP ]

late [ DoorPClose ] [ CloseTP ] -> [ DoorPOpen ] [ CloseTP ]
late [ DoorGOpen no Cover ] [ CloseTP ] -> [ DoorGClose ] [ CloseTP ]

==============
WINCONDITIONS
==============

no Cena

=======
LEVELS
=======

message Level 0 - Press X to drink protein shakes, then punch John Cena

■■■■■■■■■
■%%%%%%%■
■%.ooo.%■
■%.....%■
■%.....%■
■%..p..%■
■%.....%■
■%..£..%■
■%.....%■
■%%%%%%%■
■■■■■■■■■

message Level 1 - John Cena is a thief !!!

■■■■■■■■■■■■
■%%%%%%%%%%■
■%o...*...%■
■%o...*...%■
■%o.p.*.£.%■
■%o...*...%■
■%o...*...%■
■%%%%%%%%%%■
■■■■■■■■■■■■

message Level 2 - Do not let him hide

■■■■■■■■■■■■■
■%%%%%%%%%%%■
■%.....%.£.%■
■%.o.o.%...%■
■%.p.ù.$...%■
■%.o.o.%%%%%■
■%.....%%%%%■
■%%%%%%%%%%%■
■■■■■■■■■■■■■

message Level 3 - Give him all you have !

■■■■■■■■■■■■■
■%%%%%%%%%%%■
■%.....%.£.%■
■%.o.o.%...%■
■%.p.ù.$...%■
■%.o...%%%%%■
■%.....%%%%%■
■%%%%%%%%%%%■
■■■■■■■■■■■■■

message Level 4 - Switch alleyway

■■■■■■■■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%%%%%%%%■
■%..p..%%.....%%.....■
■%o...o%%o...o%%.....■
■%..*..$$..*..!!..£.o■
■%..ù..%%..ù..%%.....■
■%.....%%.....%%.....■
■%%%%%%%%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■■■■■■■■

message Level 5 - Combinaison lock

■■■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%%%■
■%.....%%%.....%■
■%.....%%%.o...%■
■%..£..!$!.o.pù%■
■%.....%%%.o...%■
■%.....%%%.....%■
■%%%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■■■

message Level 6 - Double thick

■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%■
■%%%%%%%.....%■
■%%...%%.....%■
■%%.p.$$..£..%■
■%%...%%.....%■
■%%%!%%%.....%■
■%%%!%%%%%%%%%■
■%.....%%%%%%%■
■%.o.o.%%.....■
■%.....%%.-.*.■
■%.o.o.%%.....■
■%..ù..%%.*.|.■
■%%%%%%%%.....■
■■■■■■■■■■■■■■■

message Level 7 - Under construction

■■■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%%%■
■....%%...%%....■
■*-*.%%.£.%%.$!.■
■....%%...%%....■
■%%%%%%%x%%%%%%%■
■%o...%%x%%....%■
■%..p.xxxxx...o%■
■%o...%%%%%....%■
■%%%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■■■

message Level 8 - Compass

■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%■
■%%%%..o..%%%%■
■%%%%.....%%%%■
■%%%%.....%%%%■
■%%%%%%x%%%%%%■
■%...%%x%%...%■
■%...%%x%%...%■
■%o..xxxxx..o%■
■%...xxxxx...%■
■%...%%x%%...%■
■%%%%%%x%%%%%%■
■%%%%.....%%%%■
■%%%%.£.p.%%%%■
■%%%%.....%%%%■
■%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■

message Level 9 - Round trip

■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%■
■..*%.....%*..■
■.-|%.p.£.%*|.■
■.**%.....%*..■
■%%%%%%x%%%%%%■
■...%%xxx%%...■
■...%xx%xx%...■
■.o.xxx%xxx.o.■
■...%xx%xx%...■
■...%%xxx%%...■
■%%%%%%x%%%%%%■
■.*|%.....%*..■
■..*%..o..%-*.■
■%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■

message Level 10 - Crossing the chasm

■■■■■■■■■■■■■■■■■■■
■..........%%%%%%%■
■..|..|..|.%%%%%%%■
■..........%%...%%■
■..|..|..|.%%.£.%%■
■..........%%...%%■
■%%%%%%%%%%%%%$%%%■
■%...%%%xxx%.....%■
■%...oooxxx%.....%■
■%.p.%%%xxxx..ù..%■
■%...oooxxx%.....%■
■%...%%%xxx%.....%■
■%%%%%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■■■■■

message Level 11 - Finished 50 balls reps

■■■■■■■■■■■■■■
■%%%%%%%%%%%%■
■%.....%%%%%%■
■%.....%...%%■
■%.o2o.$...%%■
■%.....%...%%■
■%.....%%$%%%■
■%%!!!%%...%%■
■%%xxx%%.£.%%■
■%%xxx%%...%%■
■%%xxx%%%%%%%■
■%..ù..%%%%%%■
■%.o.o.%%....■
■%.....%%.**.■
■%%%%%%%%....■
■■■■■■■■■■■■■■

message Level 12 - 6 pack in 1 minute

■■■■■■■■■
■%%%%%%%■
■%.....%■
■%..£..%■
■%.....%■
■%%xxx%%■
■%%***%%■
■%%ooo%%■
■%xxxxx%■
■%*****%■
■%ooooo%■
■%.....%■
■%..2..%■
■%.....%■
■%%%%%%%■
■■■■■■■■■

message Level 13 - Earthquake happens

■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%■
■%%%%%%%.xx..%■
■%...$xooxx..%■
■%.£.$xo*xxù2%■
■%...$xooxx..%■
■%%%%%%%.xx..%■
■%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■

message Level 14 - Falling apart

■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%■
■%%%%%xx%xx..%■
■%...$xooxx..%■
■%.£.$xo*xxù2%■
■%...$xooxx..%■
■%%%%%xx%xx..%■
■%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■

message Level 15 - Gone bowling

■■■■■■■■■■■■■■
■%%%%%.......■
■%o.o%.-..-..■
■%...%.-..-..■
■%...%.......■
■%%$%%%%%%%%%■
■%.........%%■
■%....-....%%■
■%o.2....ù..%■
■%....-....%%■
■%.........%%■
■%%$%%%%%%%%%■
■%...%.......■
■%.£.%.||.||.■
■%...%.......■
■%%%%%.......■
■■■■■■■■■■■■■■

message Level 16 - Self-destruct

■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%■
■%%%%%%%.xx..%■
■%...$xo-xx..%■
■%.£.$xooxxù2%■
■%...$xo-xx..%■
■%%%%%%%.xx..%■
■%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■

message Level 17 - Roll attack

■■■■■■■■■■■■■■■■■
■%%%%%%%%%%%%%%%■
■%.......%%%%%%%■
■%...|...%%%...%■
■%.-...|.$$$.o.%■
■%...ù..2$$$.o.%■
■%.|...-.$$$.o.%■
■%...-...%%%...%■
■%.......%%%%!%%■
■%%%%%%%%%%%%!%%■
■.|-|-||%..£%!%%■
■.......%.....%%■
■.......%%%%%%%%■
■■■■■■■■■■■■■■■■■

message Level 18 - No-protein diet

■■■■■■■■■■■■■■■■■
■%...%%%%%%%%%%%■
■%|-|%%......-.%■
■%%%%%%*|......%■
■%...%%....|-..%■
■%.£....2...$..%■
■%...%%....*..|%■
■%%%%%%.......*%■
■%...%%.-|....|%■
■%.*.%%.*....-*%■
■%...%%*....|-.%■
■%.*.%%......*.%■
■%...%%.|-.....%■
■%.*.%%$.......%■
■%...%%%%%%%%%%%■
■■■■■■■■■■■■■■■■■

message Level 19 - Alternating

■■■■■■■■■■■■■
■%%%%%%%%%%%■
■%....2....%■
■%.o.....o.%■
■%....o....%■
■%-|-|-|-|-%■
■%.........%■
■%|-|-|-|-|%■
■%xxxxxxxxx%■
■%.........%■
■%.%%%%%%%.%■
■%.........%■
■%....£....%■
■%%%%%%%%%%%■
■■■■■■■■■■■■■

message Level 20 - Backyard

■■■■■■■■■■■■■■■■■■■■■■■
■....%%%%%%%%%%%%%|...■
■.-|-%%%%%%%%.-..%|-..■
■%%%%%...%%xxo-x.%%%%%■
■%...$...o-..o-x.%%%%%■
■%.£.%.2.o-xx%%x.xxxù%■
■%...$...o-..o-x.%%%%%■
■%%%%%...%%xxo-x.%%%%%■
■..||%%%%%%%%.-..%-|-.■
■....%%%%%%%%%%%%%....■
■■■■■■■■■■■■■■■■■■■■■■■