MyBossFuckingRobbedMyCurrySoIStabbedHimToDeath (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title MyBossFuckingRobbedMyCurrySoIStabbedHimToDeath
author Stingby12
homepage https://www.tiktok.com/@jzuqiai/video/7282377091025243424

again_interval 0.05
run_rules_on_level_start

(
verbose_logging
)
========
OBJECTS
========

Background
darkbrown black
00000
00000
00100
00000
00000
Void
black

Wall
lightbrown yellow
11011
10101
01110
10101
11011

CurryX
orange
CurryTP
lightbrown
.....
.....
..0..
.....
.....
Curry1
orange lightbrown red
01210
10102
02010
10121
01010
Curry2
lightbrown orange red
01210
10102
02010
10121
01010

Crate
gray darkgray lightgray
20002
02120
01210
02120
20002
CrateHole
darkgray black gray
20002
02120
01110
02120
20002



PlayerX
black orange green darkgreen
.000.
.111.
22222
13331
.3.3.
PlayerSU
black orange lightgreen purple
.000.
11111
22222
.333.
.3.3.
PlayerSD
black orange lightgreen purple
.000.
.111.
22222
13331
.3.3.
PlayerSL
black orange lightgreen purple
.000.
.110.
12222
.3331
.3.3.
PlayerSR
black orange lightgreen purple
.000.
.011.
22221
1333.
.3.3.
PlayerDead
black orange green darkgreen
..21.
01233
0123.
01233
..21.

SwordU
brown white
..1..
..1..
..1..
.000.
..0..
SwordD
brown white
..0..
.000.
..1..
..1..
..1..
SwordL
brown white
.....
...0.
11100
...0.
.....
SwordR
brown white
.....
.0...
00111
.0...
.....
SwordHole
darkbrown white
..0..
..0..
00000
..0..
..0..

TurnX
transparent
BlockedX
transparent

GrabU
transparent
GrabD
transparent
GrabL
transparent
GrabR
transparent
NoGrabX
transparent



Boss
orange darkblue white
..0..
01210
01110
01.10
.1.1.
BossDead
orange darkblue red
20002
21111
02122
21111
20002
DeadU
red
.....
.....
.....
.....
.000.
DeadD
red
.000.
.....
.....
.....
.....
DeadL
red
.....
....0
....0
....0
.....
DeadR
red
.....
0....
0....
0....
.....

DogL
yellow white black
0.0..
202..
1100.
.1100
.1.1.
DogR
yellow white black
..0.0
..202
.0011
0011.
.1.1.
DogLDead
yellow white black red
.....
.....
0.0..
0000.
11310
DogRDead
yellow white black red
.....
.....
..0.0
.0000
01311
DeadDLR
red
00000
.....
.....
.....
.....
DeadDL
red
....0
.....
.....
.....
.....
DeadUL
red
.....
.....
.....
.....
....0
DeadDR
red
0....
.....
.....
.....
.....
DeadUR
red
.....
.....
.....
.....
0....

SightU
transparent
SightD
transparent
SightL
transparent
SightR
transparent

=======
LEGEND
=======

■ = Void
. = Background

# = Wall
% = CurryX
£ = CurryX and CurryTP
P = PlayerX
! = Boss
^ = SwordU
v = SwordD
< = SwordL
> = SwordR

* = Crate
& = DogL

PlayerS = PlayerSU or PlayerSD or PlayerSL or PlayerSR
Player = PlayerX or PlayerS

SwordH = SwordL or SwordR
SwordV = SwordU or SwordD
Sword = SwordH or SwordV

Dog = DogL or DogR
Sight = SightU or SightD or SightL or SightR

Curry = Curry1 or Curry2

Block = Crate or Wall or Void or Sword or SwordHole or Boss or Dog
SightBlock = Crate or Wall or Void or Sword

DogDead = DogLDead or DogRDead
Deadbody = BossDead or DogDead or PlayerDead

=======
SOUNDS
=======

Player move 67762507
Crate move 84342907
Dog move 47467107

sfx0 51686701
sfx1 30763507
sfx2 15012704

BlockedX create 53181904
sfx4 74522107

BossDead create 95920302
DogDead create 95920302
PlayerDead create 23381302

CrateHole create 36203501
SwordHole create 36203501
sfx5 72995107

undo 89674306
restart 27105906
endlevel 18414108

================
COLLISIONLAYERS
================

Background

DeadU
DeadD
DeadL
DeadR

DeadDLR
DeadDL
DeadDR
DeadUL
DeadUR

CurryX, Curry1, Curry2, CrateHole
Deadbody
Player, Boss, Void, Crate, Sword, Wall, Dog, SwordHole

TurnX
BlockedX
CurryTP

GrabU
GrabD
GrabL
GrabR
NoGrabX

Sight

======
RULES
======

[ CurryX CurryTP ] -> [ Curry1 ]
+ [ Curry1 | CurryX ] -> [ Curry1 | Curry2 ]
+ [ Curry2 | CurryX ] -> [ Curry2 | Curry1 ]



late up    [ Player | no SightBlock ] -> [ Player | SightU ]
late down  [ Player | no SightBlock ] -> [ Player | SightD ]
late left  [ Player | no SightBlock ] -> [ Player | SightL ]
late right [ Player | no SightBlock ] -> [ Player | SightR ]

late up    [ SightU | no SightBlock ] -> [ SightU | SightU ]
late down  [ SightD | no SightBlock ] -> [ SightD | SightD ]
late left  [ SightL | no SightBlock ] -> [ SightL | SightL ]
late right [ SightR | no SightBlock ] -> [ SightR | SightR ]

[ Dog SightU ] -> [ down Dog SightU ]
[ Dog SightD ] -> [ up Dog SightD ]
[ Dog SightL ] -> [ right Dog SightL ]
[ Dog SightR ] -> [ left Dog SightR ]

[ left Dog ] -> [ left DogL ]
[ right Dog ] -> [ right DogR ]

late [ Dog | Player ] -> [ Dog | PlayerDead ]



[ > Player | Crate ] -> [ > Player | > Crate ]

[ > PlayerX | BossDead ] -> [ PlayerX | BossDead ] sfx5
[ > Crate | BossDead ] -> [ Crate | BossDead ]
[ > Dog | BossDead ] -> [ Dog | BossDead ]

[ > PlayerX | DogDead ] -> [ PlayerX | DogDead ] sfx5

vertical   [ > PlayerSU | DogDead ] -> [ PlayerSU | DogDead ] sfx5
vertical   [ > PlayerSD | DogDead ] -> [ PlayerSD | DogDead ] sfx5
horizontal [ > PlayerSL | DogDead ] -> [ PlayerSL | DogDead ] sfx5
horizontal [ > PlayerSR | DogDead ] -> [ PlayerSR | DogDead ] sfx5

[ > Crate | DogDead ] -> [ Crate | DogDead ]
[ > Dog | DogDead ] -> [ Dog | DogDead ]

[ > PlayerX | Curry no SwordHole ] -> [ PlayerX | Curry ] sfx5

vertical   [ > PlayerSU | Curry no SwordHole ] -> [ PlayerSU | Curry ] sfx5
vertical   [ > PlayerSD | Curry no SwordHole ] -> [ PlayerSD | Curry ] sfx5
horizontal [ > PlayerSL | Curry no SwordHole ] -> [ PlayerSL | Curry ] sfx5
horizontal [ > PlayerSR | Curry no SwordHole ] -> [ PlayerSR | Curry ] sfx5

late [ Crate Curry ] -> [ CrateHole ]

late up    [ no PlayerSU | SwordU Curry ] -> [ | SwordHole Curry ]
late down  [ no PlayerSD | SwordD Curry ] -> [ | SwordHole Curry ]
late left  [ no PlayerSL | SwordL Curry ] -> [ | SwordHole Curry ]
late right [ no PlayerSR | SwordR Curry ] -> [ | SwordHole Curry ]




up    [ vertical PlayerSU | SwordU ] -> [ vertical PlayerSU | vertical SwordU ]
down  [ vertical PlayerSD | SwordD ] -> [ vertical PlayerSD | vertical SwordD ]
left  [ horizontal PlayerSL | SwordL ] -> [ horizontal PlayerSL | horizontal SwordL ]
right [ horizontal PlayerSR | SwordR ] -> [ horizontal PlayerSR | horizontal SwordR ]

up    [ left PlayerSU | SwordU ] -> [ left PlayerSU TurnX | left SwordU ]
up    [ right PlayerSU | SwordU ] -> [ right PlayerSU TurnX | right SwordU ]
down  [ right PlayerSD | SwordD ] -> [ right PlayerSD TurnX | right SwordD ]
down  [ left PlayerSD | SwordD ] -> [ left PlayerSD TurnX | left SwordD ]
left  [ down PlayerSL | SwordL ] -> [ down PlayerSL TurnX | down SwordL ]
left  [ up PlayerSL | SwordL ] -> [ up PlayerSL TurnX | up SwordL ]
right [ up PlayerSR | SwordR ] -> [ up PlayerSR TurnX | up SwordR ]
right [ down PlayerSR | SwordR ] -> [ down PlayerSR TurnX | down SwordR ]

[ > Sword | Block ] [ TurnX ] -> [ Sword | Block ] [ BlockedX ]
[ > PlayerS TurnX | Block ] -> [ > PlayerS BlockedX | Block ]

[ moving Sword ] [ BlockedX ] -> [ Sword ] [ BlockedX ]
[ moving PlayerS BlockedX ] -> [ PlayerS BlockedX ]


up    [ horizontal PlayerSU TurnX | SwordU ] -> [ horizontal PlayerSU TurnX | ]
down  [ horizontal PlayerSD TurnX | SwordD ] -> [ horizontal PlayerSD TurnX | ]
left  [ vertical PlayerSL TurnX | SwordL ] -> [ vertical PlayerSL TurnX | ]
right [ vertical PlayerSR TurnX | SwordR ] -> [ vertical PlayerSR TurnX | ]

left  [ left PlayerSU TurnX | ] -> [ left PlayerSL | SwordL ] sfx4
left  [ left PlayerSD TurnX | ] -> [ left PlayerSL | SwordL ] sfx4
right [ right PlayerSU TurnX | ] -> [ right PlayerSR | SwordR ] sfx4
right [ right PlayerSD TurnX | ] -> [ right PlayerSR | SwordR ] sfx4
down  [ down PlayerSL TurnX | ] -> [ down PlayerSD | SwordD ] sfx4
down  [ down PlayerSR TurnX | ] -> [ down PlayerSD | SwordD ] sfx4
up    [ up PlayerSL TurnX | ] -> [ up PlayerSU | SwordU ] sfx4
up    [ up PlayerSR TurnX | ] -> [ up PlayerSU | SwordU ] sfx4



up    [ > Player | SwordD ] -> sfx0
down  [ > Player | SwordU ] -> sfx0
left  [ > Player | SwordR ] -> sfx0
right [ > Player | SwordL ] -> sfx0

horizontal [ > Player | SwordU ] -> [ > Player | > SwordU ] sfx1
horizontal [ > Player | SwordD ] -> [ > Player | > SwordD ] sfx1
vertical   [ > Player | SwordL ] -> [ > Player | > SwordL ] sfx1
vertical   [ > Player | SwordR ] -> [ > Player | > SwordR ] sfx1

up    [ > PlayerX | SwordU ] -> [ > PlayerX | > SwordU ] sfx1
down  [ > PlayerX | SwordD ] -> [ > PlayerX | > SwordD ] sfx1
left  [ > PlayerX | SwordL ] -> [ > PlayerX | > SwordL ] sfx1
right [ > PlayerX | SwordR ] -> [ > PlayerX | > SwordR ] sfx1

up    [ > PlayerSD | SwordU ] -> [ > PlayerSD | > SwordU ] sfx1
down  [ > PlayerSU | SwordD ] -> [ > PlayerSU | > SwordD ] sfx1
left  [ > PlayerSR | SwordL ] -> [ > PlayerSR | > SwordL ] sfx1
right [ > PlayerSL | SwordR ] -> [ > PlayerSL | > SwordR ] sfx1

late up    [ PlayerX | SwordU ] -> [ PlayerX GrabU | SwordU ]
late down  [ PlayerX | SwordD ] -> [ PlayerX GrabD | SwordD ]
late left  [ PlayerX | SwordL ] -> [ PlayerX GrabL | SwordL ]
late right [ PlayerX | SwordR ] -> [ PlayerX GrabR | SwordR ]

late [ GrabU GrabD ] -> [ NoGrabX ]
late [ GrabU GrabL ] -> [ NoGrabX ]
late [ GrabU GrabR ] -> [ NoGrabX ]
late [ GrabD GrabL ] -> [ NoGrabX ]
late [ GrabD GrabR ] -> [ NoGrabX ]
late [ GrabL GrabR ] -> [ NoGrabX ]

late [ NoGrabX GrabD ] -> [ NoGrabX ]
late [ NoGrabX GrabL ] -> [ NoGrabX ]
late [ NoGrabX GrabR ] -> [ NoGrabX ]

late [ PlayerX GrabU ] -> [ PlayerSU ] sfx2
late [ PlayerX GrabD ] -> [ PlayerSD ] sfx2
late [ PlayerX GrabL ] -> [ PlayerSL ] sfx2
late [ PlayerX GrabR ] -> [ PlayerSR ] sfx2



up    [ PlayerS | > SwordU | Boss ] -> [ PlayerX | | BossDead ]
down  [ PlayerS | > SwordD | Boss ] -> [ PlayerX | | BossDead ]
left  [ PlayerS | > SwordL | Boss ] -> [ PlayerX | | BossDead ]
right [ PlayerS | > SwordR | Boss ] -> [ PlayerX | | BossDead ]

up    [ PlayerS | > SwordU | DogL ] -> [ PlayerX | | DogLDead ]
down  [ PlayerS | > SwordD | DogL ] -> [ PlayerX | | DogLDead ]
left  [ PlayerS | > SwordL | DogL ] -> [ PlayerX | | DogLDead ]
right [ PlayerS | > SwordR | DogL ] -> [ PlayerX | | DogLDead ]

up    [ PlayerS | > SwordU | DogR ] -> [ PlayerX | | DogRDead ]
down  [ PlayerS | > SwordD | DogR ] -> [ PlayerX | | DogRDead ]
left  [ PlayerS | > SwordL | DogR ] -> [ PlayerX | | DogRDead ]
right [ PlayerS | > SwordR | DogR ] -> [ PlayerX | | DogRDead ]

up    [ > SwordU | Boss ] -> [ | BossDead ]
down  [ > SwordD | Boss ] -> [ | BossDead ]
left  [ > SwordL | Boss ] -> [ | BossDead ]
right [ > SwordR | Boss ] -> [ | BossDead ]

up    [ > SwordU | DogL ] -> [ | DogLDead ]
down  [ > SwordD | DogL ] -> [ | DogLDead ]
left  [ > SwordL | DogL ] -> [ | DogLDead ]
right [ > SwordR | DogL ] -> [ | DogLDead ]

up    [ > SwordU | DogR ] -> [ | DogRDead ]
down  [ > SwordD | DogR ] -> [ | DogRDead ]
left  [ > SwordL | DogR ] -> [ | DogRDead ]
right [ > SwordR | DogR ] -> [ | DogRDead ]


late up    [ BossDead | ] -> [ BossDead | DeadU ]
late down  [ BossDead | ] -> [ BossDead | DeadD ]
late left  [ BossDead | ] -> [ BossDead | DeadL ]
late right [ BossDead | ] -> [ BossDead | DeadR ]

late down  [ DogDead no Curry | ] -> [ DogDead | DeadDLR ]
late left  [ DogDead no Curry | ] -> [ DogDead | DeadUL ]
late right [ DogDead no Curry | ] -> [ DogDead | DeadUR ]
late left  [ DeadDLR | ] -> [ DeadDLR | DeadDL ]
late right [ DeadDLR | ] -> [ DeadDLR | DeadDR ]

[ BlockedX ] -> [ ]
[ NoGrabX ] -> [ ]
[ Sight ] -> [ ]

==============
WINCONDITIONS
==============

no Boss

=======
LEVELS
=======

message Level 0 of 15 - Take your sword and stab your thieving boss with it

■■■■■■■■■■■
■#########■
■#.......#■
■#.!...p.#■
■#.......#■
■#####...#■
■#####...#■
■...##.^.#■
■...##...#■
■...######■
■■■■■■■■■■■

message Level 1 of 15 - Getting my ultimate revenge

■■■■■■■■■
■#######■
■#..!..#■
■#..#..#■
■#.....#■
■#.#v#.#■
■#.#.#.#■
■#.#p#.#■
■#.....#■
■#.....#■
■#.....#■
■#######■
■■■■■■■■■

message Level 2 of 15 - Johnson's Burrito Spin

■■■■■■■■■■■
■#########■
■######!.#■
■#...##..#■
■#.p^....#■
■#..#..#.#■
■#####...#■
■#########■
■■■■■■■■■■■

message Level 3 of 15 - Knife collection

■■■■■■■■■■
■########■
■#.^.#..#■
■#<....p#■
■#.v.#..#■
■##..#!.#■
■########■
■■■■■■■■■■

message Level 4 of 15 - Swordmanship

■■■■■■■■■■
■..######■
■..##...#■
■..##...#■
■..##...#■
■..##<.>#■
■####.v.#■
■####...#■
■#..#...#■
■#....p.#■
■#!##...#■
■########■
■■■■■■■■■■

message Level 5 of 15 - Needlemouse without the m

■■■■■■■■■■■■■
■###########■
■#..>...##!#■
■#..>..>#..#■
■#<p.>>....#■
■#..>..>#..#■
■#..>...####■
■###########■
■■■■■■■■■■■■■

message Level 6 of 15 - Guard dog

■■■■■■■■■■■■■■■
■#############■
■#!...########■
■#....###....#■
■#.........&>#■
■#....#.#....#■
■#....#.######■
■######.######■
■...##...##...■
■...##.p.##...■
■...#######...■
■■■■■■■■■■■■■■■

message Level 7 of 15 - The palace

■■■■■■■■■■■■■
■###########■
■#^##.!.##^#■
■#....&....#■
■#.........#■
■##.p.....##■
■###########■
■■■■■■■■■■■■■

message Level 8 of 15 - Simple Block Pushing Level

■■■■■■■■■■■■■■
■...#########■
■...##.*.####■
■...##.*...>#■
■#####.*.####■
■#####.#.####■
■#...#......#■
■#.p...#...!#■
■#...########■
■############■
■■■■■■■■■■■■■■

message Level 9 of 15 - Multitask

■■■■■■■■■■■■
■##########■
■#####p..##■
■#!..###.##■
■#...#.*..#■
■##....*v.#■
■#####.*..#■
■##########■
■■■■■■■■■■■■

message Level 10 of 15 - Litterally Stephen's Saussage Roll

■■■■■■■■■■■■
■£%%%%%%%%%■
■%%%%%%%%%%■
■%%%%...%%%■
■%%p..#.%#%■
■%%v..%..#%■
■%%%%%%%.%%■
■%%%%!...%%■
■%%%%####%%■
■■■■■■■■■■■■

message Level 11 of 15 - Curry has a lot of iron

■■■■■■■■■■■■■
■####%£%%%%%■
■#...%%%%%%%■
■#..*%%#...#■
■#<p*%%%.!.#■
■#..*%%#...#■
■#...%%%%%%%■
■####%%%%%%%■
■■■■■■■■■■■■■

message Level 12 of 15 - Especially when there's swords inside

■■■■■■■■■■■■■■
■£%%##%%%%###■
■%%%%%%%%%###■
■%%%.>.%%%###■
■#%..>.>.%%%%■
■#%p>>.>.>.!%■
■#%..>.>.%%%%■
■%%%.>.%%%###■
■%%%%%%%%%###■
■%%%##%%%%###■
■■■■■■■■■■■■■■

message Level 13 of 15 - What da dog doin

■■■■■■■■■■■■■■■■■■■
■%£%###########%£%■
■#####.......#####■
■#####..%%%.&#####■
■#...#..%%%..#...#■
■#.!..p.%£%.&..>.#■
■#...#..%%%..#...#■
■#####..%%%.&#####■
■#####.......#####■
■%£%###########%£%■
■■■■■■■■■■■■■■■■■■■

message Level 14 of 15 - Warzone

■■■■■■■■■■■
■#########■
■%%%%£%%%%■
■%%.p.!.%%■
■%%.....%%■
■&%*.*.*%&■
■&%.....%&■
■&%.*.*.%&■
■&%.....%&■
■&%..*..%&■
■&%&...&%&■
■&%..v..%&■
■%%%%%%%%%■
■#########■
■■■■■■■■■■■

message Level 15 of 15 - This looks familiar

■■■■■■■■■■■■■■■■
■######.#######■
■#....*.......#■
■...*.*.>&>&.&.■
■p..*.*.......!■
■...*.*.>&>&.&.■
■#....*.......#■
■##############■
■■■■■■■■■■■■■■■■

message Now I can finally enjoy my wife's delicious homemade curry in peace without my boss robbing it !!
message Comment 'curry' if this is relatable