Ele-mental artist

script.txt

title Ele-mental artist
author Stingby12
homepage https://itch.io/jam/mini-jam-111-colors

sprite_size 6
case_sensitive

background_color white
text_color black

run_rules_on_level_start
noaction

level_select
level_select_lock
level_select_unlocked_ahead 2
level_select_solve_symbol &

========
OBJECTS
========

Background
#F2F2F2 #E6E6E6
000000
001100
011110
011110
001100
000000

TileMetal
#CCCCCC #969696
000000
011110
011010
010110
011110
000000

TileFire
#FF9C99 #EB8581
000000
010010
011110
011110
001100
000000

TileWater
#B3BAFF #7F89EB
000000
001100
001100
011110
001100
000000

TileEarth
#FCE7A2 #EBD078
000000
001010
001010
011110
011110
000000

TileWood
#BDF0BD #96F296
000000
000110
011110
011100
000100
000000

TargetMetal
#616161
......
..00..
.0..0.
..00..
.0000.
......

TargetFire
#E60800
......
..0...
.00.0.
..0...
.0000.
......

TargetWater
#0219E6
......
..0.0.
.000..
..0.0.
.00.0.
......

TargetEarth
#E6B000
......
...0..
.0000.
...0..
.0000.
......

TargetWood
#0CEB0C
......
.0000.
..0...
.000..
..0.0.
......

Wall
white

WallLeft
black
0.....
0.....
0.....
0.....
0.....
0.....

WallRight
black
.....0
.....0
.....0
.....0
.....0
.....0

WallUp
black
000000
......
......
......
......
......

WallDown
black
......
......
......
......
......
000000

WallUpLeft
black
00....
0.....
......
......
......
......

WallUpRight
black
....00
.....0
......
......
......
......

WallDownLeft
black
......
......
......
......
0.....
00....

WallDownRight
black
......
......
......
......
.....0
....00

PlayerMetalLeft
#262626 white
......
..00..
.1010.
.0000.
.0..0.
......

PlayerMetalRight
#262626 white
......
..00..
.0101.
.0000.
.0..0.
......

PlayerFireLeft
#B30600 white
......
..00..
.1010.
.0000.
.0..0.
......

PlayerFireRight
#B30600 white
......
..00..
.0101.
.0000.
.0..0.
......

PlayerWaterLeft
#021199 white
......
..00..
.1010.
.0000.
.0..0.
......

PlayerWaterRight
#021199 white
......
..00..
.0101.
.0000.
.0..0.
......

PlayerEarthLeft
#9E7900 white
......
..00..
.1010.
.0000.
.0..0.
......

PlayerEarthRight
#9E7900 white
......
..00..
.0101.
.0000.
.0..0.
......

PlayerWoodLeft
#089E08 white
......
..00..
.1010.
.0000.
.0..0.
......

PlayerWoodRight
#089E08 white
......
..00..
.0101.
.0000.
.0..0.
......

PaintMetal
#616161 black
......
.1111.
.0000.
.0000.
..00..
......

PaintFire
#E60800 black
......
.1111.
.0000.
.0000.
..00..
......

PaintWater
#0219E6 black
......
.1111.
.0000.
.0000.
..00..
......

PaintEarth
#E6B000 black
......
.1111.
.0000.
.0000.
..00..
......

PaintWood
#0CEB0C black
......
.1111.
.0000.
.0000.
..00..
......

SlideLeft
transparent
SlideRight
transparent
SlideUp
transparent
SlideDown
transparent

Trail1
#9E7900 #E6B000
.0000.
011110
011110
011110
011110
.0000.
Trail2
#9E7900 #E6B000
..00..
.0110.
011110
011110
.0110.
..00..
Trail3
#9E7900 #E6B000
......
.0000.
.0110.
.0110.
.0000.
......
Trail4
#9E7900 #E6B000
......
..00..
.0110.
.0110.
..00..
......
Trail5
#9E7900 #E6B000
......
......
..00..
..00..
......
......

HorBlock1
#08A808
......
......
0....0
0....0
......
......
HorBlock2
#0CEB0C
......
0....0
0....0
0....0
0....0
......
VerBlock1
#08A808
..00..
......
......
......
......
..00..
VerBlock2
#0CEB0C
.0000.
......
......
......
......
.0000.

=======
LEGEND
=======

(ΑΒΓΔΕ ΖΗΘΙΚ)

PlayerMetal = PlayerMetalLeft or PlayerMetalRight
PlayerFire = PlayerFireLeft or PlayerFireRight
PlayerWater = PlayerWaterLeft or PlayerWaterRight
PlayerEarth = PlayerEarthLeft or PlayerEarthRight
PlayerWood = PlayerWoodLeft or PlayerWoodRight

PlayerLeft = PlayerMetalLeft or PlayerFireLeft or PlayerWaterLeft or PlayerEarthLeft or PlayerWoodLeft
PlayerRight = PlayerMetalRight or PlayerFireRight or PlayerWaterRight or PlayerEarthRight or PlayerWoodRight
player = PlayerMetal or PlayerFire or PlayerWater or PlayerEarth or PlayerWood

Tile = TileMetal or TileFire or TileWater or TileEarth or TileWood
Target = TargetMetal or TargetFire or TargetWater or TargetEarth or TargetWood
Paint = PaintMetal or PaintFire or PaintWater or PaintEarth or PaintWood

. = Background
# = Wall
P = PlayerMetalLeft

Α = TargetFire
Β = TargetWater
Γ = TargetEarth
Δ = TargetWood
Ε = TargetMetal

α = TargetFire and PlayerMetalLeft
β = TargetWater and PlayerMetalLeft
γ = TargetEarth and PlayerMetalLeft
δ = TargetWood and PlayerMetalLeft
! = TileMetal

Η = PaintFire
Θ = PaintWater
Ι = PaintEarth
Κ = PaintWood
Ζ = PaintMetal

Trail = Trail1 or Trail2 or Trail3 or Trail4 or Trail5

Slide = SlideLeft or SlideRight or SlideUp or SlideDown
Block = Wall or PaintWater or Trail

HorBlock = HorBlock1 or HorBlock2
VerBlock = VerBlock1 or VerBlock2

=======
SOUNDS
=======

player move 80051107

TileMetal create 49543707
TileFire create 86203102
TileWater create 31325904
TileEarth create 55838102
TileWood create 79965109

Trail1 create 72823902
HorBlock2 create 49529702
VerBlock2 create 49529702

sfx0 47663903

sfx1 42555902
sfx2 64515104

undo 98450500
restart 46962102

startgame 80867908
showmessage 53025506
startlevel 56663708
endlevel 47004300

================
COLLISIONLAYERS
================

Background
Tile

Target, Paint
player, Wall

Slide
Trail

HorBlock
VerBlock

WallLeft
WallRight
WallUp
WallDown

WallUpLeft
WallUpRight
WallDownLeft
WallDownRight

======
RULES
======

left [ Wall | no Wall ] -> [ Wall WallLeft | ]
right [ Wall | no Wall ] -> [ Wall WallRight | ]
up [ Wall | no Wall ] -> [ Wall WallUp | ]
down [ Wall | no Wall ] -> [ Wall WallDown | ]

up [ Wall no WallLeft | Wall WallLeft ] -> [ Wall WallUpLeft | Wall WallLeft ]
up [ Wall no WallRight | Wall WallRight ] -> [ Wall WallUpRight | Wall WallRight ]
down [ Wall no WallLeft | Wall WallLeft ] -> [ Wall WallDownLeft | Wall WallLeft ]
down [ Wall no WallRight | Wall WallRight ] -> [ Wall WallDownRight | Wall WallRight ]

[ left PlayerMetal ] -> [ left PlayerMetalLeft ]
[ right PlayerMetal ] -> [ right PlayerMetalRight ]

[ left PlayerFire ] -> [ left PlayerFireLeft ]
[ right PlayerFire ] -> [ right PlayerFireRight ]

[ left PlayerWater ] -> [ left PlayerWaterLeft ]
[ right PlayerWater ] -> [ right PlayerWaterRight ]

[ left PlayerEarth ] -> [ left PlayerEarthLeft ]
[ right PlayerEarth ] -> [ right PlayerEarthRight ]

[ left PlayerWood ] -> [ left PlayerWoodLeft ]
[ right PlayerWood ] -> [ right PlayerWoodRight ]



[ > player | Wall ] -> [ player | Wall ]
[ > player | Trail ] -> [ player | Trail ] sfx2
[ > PlayerFire | Tile ] -> [ PlayerFire | Tile ] sfx2
[ horizontal PlayerWood HorBlock2 ] -> [ PlayerWood HorBlock2 ] sfx2
[ vertical PlayerWood VerBlock2 ] -> [ PlayerWood VerBlock2 ] sfx2

[ > PlayerMetal | PaintMetal ] -> [ PlayerMetal | PaintMetal ] sfx1
[ > PlayerFire | PaintFire ] -> [ PlayerFire | PaintFire ] sfx1
[ > PlayerWater | PaintWater ] -> [ PlayerWater | PaintWater ] sfx1
[ > PlayerEarth | PaintEarth ] -> [ PlayerEarth | PaintEarth ] sfx1
[ > PlayerWood | PaintWood ] -> [ PlayerWood | PaintWood ] sfx1

left [ > PlayerWater | no Block ] -> [ > SlideLeft > PlayerWater | ] again
right [ > PlayerWater | no Block ] -> [ > SlideRight > PlayerWater | ] again
up [ > PlayerWater | no Block ] -> [ > SlideUp > PlayerWater | ] again
down [ > PlayerWater | no Block ] -> [ > SlideDown > PlayerWater | ] again

left [ SlideLeft PlayerWater | no Block ] -> [ left SlideLeft left PlayerWater | ] again
right [ SlideRight PlayerWater | no Block ] -> [ right SlideRight right PlayerWater | ] again
up [ SlideUp PlayerWater | no Block ] -> [ up SlideUp up PlayerWater | ] again
down [ SlideDown PlayerWater | no Block ] -> [ down SlideDown down PlayerWater | ] again

late left [ SlideLeft | Block ] -> [ | Block ]
late right [ SlideRight | Block ] -> [ | Block ]
late up [ SlideUp | Block ] -> [ | Block ]
late down [ SlideDown | Block ] -> [ | Block ]
late [ Slide Paint ] -> [ Paint ]

[ vertical PlayerWood HorBlock ] -> [ vertical PlayerWood ]
[ horizontal PlayerWood VerBlock ] -> [ horizontal PlayerWood ]

[ horizontal PlayerWood HorBlock1 ] -> [ horizontal PlayerWood horizontal HorBlock2 ]
[ vertical PlayerWood VerBlock1 ] -> [ vertical PlayerWood vertical VerBlock2 ]

[ horizontal PlayerWood no HorBlock ] -> [ horizontal PlayerWood horizontal HorBlock1 ]
[ vertical PlayerWood no VerBlock ] -> [ vertical PlayerWood vertical VerBlock1 ]

late [ HorBlock ] [ PlayerMetal ] -> [ ] [ PlayerMetal ]
late [ HorBlock ] [ PlayerFire ] -> [ ] [ PlayerFire ]
late [ HorBlock ] [ PlayerWater ] -> [ ] [ PlayerWater ]
late [ HorBlock ] [ PlayerEarth ] -> [ ] [ PlayerEarth ]

late [ VerBlock ] [ PlayerMetal ] -> [ ] [ PlayerMetal ]
late [ VerBlock ] [ PlayerFire ] -> [ ] [ PlayerFire ]
late [ VerBlock ] [ PlayerWater ] -> [ ] [ PlayerWater ]
late [ VerBlock ] [ PlayerEarth ] -> [ ] [ PlayerEarth ]

[ Trail5 ] [ moving player ] -> [ ] [ moving player ]
[ Trail4 ] [ moving PlayerEarth ] -> [ Trail5 ] [ moving PlayerEarth ]
[ Trail3 ] [ moving PlayerEarth ] -> [ Trail4 ] [ moving PlayerEarth ]
[ Trail2 ] [ moving PlayerEarth ] -> [ Trail3 ] [ moving PlayerEarth ]
[ Trail1 ] [ moving PlayerEarth ] -> [ Trail2 ] [ moving PlayerEarth ]
[ moving PlayerEarth ] -> [ moving PlayerEarth Trail1 ]

late [ Trail ] [ PlayerMetal ] -> [ Trail5 ] [ PlayerMetal ]
late [ Trail ] [ PlayerFire ] -> [ Trail5 ] [ PlayerFire ]
late [ Trail ] [ PlayerWater ] -> [ Trail5 ] [ PlayerWater ]
late [ Trail ] [ PlayerWood ] -> [ Trail5 ] [ PlayerWood ]



[ > PlayerLeft | PaintMetal ] -> [ > PlayerMetalLeft | PaintMetal ] sfx0
[ > PlayerRight | PaintMetal ] -> [ > PlayerMetalRight | PaintMetal ] sfx0

[ > PlayerLeft | PaintFire ] -> [ > PlayerFireLeft | PaintFire ] sfx0
[ > PlayerRight | PaintFire ] -> [ > PlayerFireRight | PaintFire ] sfx0

[ > PlayerLeft | PaintWater ] -> [ > PlayerWaterLeft | PaintWater ] sfx0
[ > PlayerRight | PaintWater ] -> [ > PlayerWaterRight | PaintWater ] sfx0

[ > PlayerLeft | PaintEarth ] -> [ > PlayerEarthLeft | PaintEarth ] sfx0
[ > PlayerRight | PaintEarth ] -> [ > PlayerEarthRight | PaintEarth ] sfx0

[ > PlayerLeft | PaintWood ] -> [ > PlayerWoodLeft | PaintWood ] sfx0
[ > PlayerRight | PaintWood ] -> [ > PlayerWoodRight | PaintWood ] sfx0

late [ PlayerMetal TargetMetal ] -> [ PlayerMetal TileMetal ]
late [ PlayerFire TargetFire ] -> [ PlayerFire TileFire ]
late [ PlayerWater TargetWater ] -> [ PlayerWater TileWater ]
late [ PlayerEarth TargetEarth ] -> [ PlayerEarth TileEarth ]
late [ PlayerWood TargetWood ] -> [ PlayerWood TileWood ]

==============
WINCONDITIONS
==============

no Target

=======
LEVELS
=======

section 1 of 15 - Fiery start

message "I love painting on the ground !"
message "But the paint wakes up my bad side..."
message "...and gives me negative elemental effects !"

message Painting 1 of 15 - Fiery start

#######
#ΑΑΑΑΑ#
#ΑΑΑΑΑ#
#ΑΑΗΑΑ#
#ΑΑΑΑΑ#
#αΑΑΑΑ#
#######

section 2 of 15 - Labyrinth

message "Fire prevents me from walking on already painted tiles."

message Painting 2 of 15 - Labyrinth

########
#Η.#####
#..ΑΑΑ##
##ΑΑΑΑ##
##ΑΑΑΑ##
##ΑΑΑΑΑ#
#####Αα#
########

section 3 of 15 - Water slide

message "I want to be more varied with the colors."

message Painting 3 of 15 - Water slide

#######
#ΘΒΒΒΒ#
#ΒΒΒΒΒ#
#ΒΒΘΒΒ#
#ΒΒΒΒΒ#
#βΒΒΒΘ#
#######

section 4 of 15 - Duality

message "Water makes me slide around."

message Painting 4 of 15 - Duality

#######
#ΘΒΒΑΑ#
#ΒΒΑΗΑ#
#ΒΑαΑΒ#
#ΑΗΑΒΒ#
#ΑΑΒΒΘ#
#######

section 5 of 15 - The river

message "I don't need multiple colors just for painting."

message Painting 5 of 15 - The river

########
##ΒΒΒ.Η#
#ΒΗΒΒβ.#
#ΒΒΘΒΒΒ#
#ΒΒΒΘΒΒ#
#.ΒΒΒΗΒ#
#Η.ΒΒΒ##
########

section 6 of 15 - Rocky road

message "I might need another color."

message Painting 6 of 15 - Rocky road

#######
#ΓΓΓΓΓ#
#ΓΓΓΓΓ#
#ΓΓΙΓΓ#
#ΓΓΓΓΓ#
#γΓΓΓΓ#
#######

section 7 of 15 - Labyrinth II

message "Earth makes a trail behind me."

message Painting 7 of 15 - Labyrinth II

#########
#PΗ.Γ.Γ.#
#Γ#Γ#Ι#Ι#
#.Ι.Η.Γ.#
#Γ#Η#Ι#Γ#
#.Γ.Η.Γ.#
#Η#Ι#Γ#Η#
#.Γ.Ι.Γ.#
#########

section 8 of 15 - Strips

message "This trail makes everything claustrophobic."

message Painting 8 of 15 - Strips

#########
#ΓΑΓαΓΑΓ#
#ΓΑΓΑΓΑΓ#
#ΗΙΗΙΗΙΗ#
#ΓΑΓΑΓΑΓ#
#ΓΑΓΑΓΑΓ#
#########

section 9 of 15 - Forest area

message "The next color will make things more problematic."

message Painting 9 of 15 - Forest area

#######
#ΔΔΔΔΔ#
#ΔΔΔΔΔ#
#ΔΔΚΔΔ#
#ΔΔΔΔΔ#
#δΔΔΔΔ#
#######

section 10 of 15 - Tree plantation

message "Wood prevents me to move in the same orientation."

message Painting 10 of 15 - Tree plantation

################
####.ΔΔΑΑΑΔΔ...#
#P.Κ.ΔΑΑΔΑΑΔ.Η.#
####.ΔΔΑΑΑΔΔ...#
################

section 11 of 15 - Pallete

message "There are a lot of colors that limits me..."
message "But there is one that I like using."

message Painting 11 of 15 - Pallete

########
##ΓΓΔ###
#ΓΓΓΔΔ##
#ΓΓΗΘΔΔ#
#ΒΒΚΙΑΑ#
##βΒΑΑΑ#
###ΒΑΑ##
########

section 12 of 15 - Checkers

message "Metal has no negative effect."

message Painting 12 of 15 - Checkers

########
#Ζ.P..Ζ#
#......#
#ΕΑ##ΕΑ#
#ΑΕΑΕΑΕ#
#ΕΑΕΑΕΑ#
###ΑΕ###
#......#
#Η....Η#
########

section 13 of 15 - Frontier

message "I prefer colorless rather than colorful."

message Painting 13 of 15 - Frontier

#########
#ΑΑΑΖΕΕΕ#
#ΕΕΕΖΒΒΒ#
#ΑΗαΖΒΘΒ#
#ΕΕΕΖΒΒΒ#
#ΑΑΑΖΕΕΕ#
#########

section 14 of 15 - Strips II

message "Gray don't feel exiting, but..."

message Painting 14 of 15 - Strips II

###########
##ΑΒΒΔΒΒΑ##
##ΑΓΓΔΓΓΑ##
#ΕΑΕΕΔΕΕΑΕ#
#ΕΚΙΘΗΘΙΚΕ#
#ΕΑΕΕΔΕΕΑΕ#
##ΑΓΓδΓΓΑ##
##ΑΒΒΔΒΒΑ##
###########

section 15 of 15 - Cheerful

message "...That's how I like it."

message Painting 15 of 15 - Cheerful

#############
###!!!#!!!###
##!ΖΘΚ!ΗΘΖ!##
#!ΖΙΔΓΗΒΔΙΖ!#
#!ΘΔΓΑΒΔΓΑΘ!#
#!ΙΓΑΒΔΓΑΒΚ!#
##!ΗΒΔγΑΒ.!##
###!ΘΓΑΒΘ!###
####!ΗΒ.!####
#####!Κ!#####
######!######
#############

message -- Mini jam 111 --