IDropkickedTheRockOffABridgeBecauseHeFuckingRobbedMySnickers (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title IDropkickedTheRockOffABridgeBecauseHeFuckingRobbedMySnickers
author Stingby12
homepage https://www.tiktok.com/@jzuqiai/video/7283939408607202592

again_interval 0.05

========
OBJECTS
========

Background
gray darkgray
11111
10111
11111
11101
11111
Grass
lightgreen green
11111
01111
11101
11111
10111
Water
blue darkblue
00000
01000
00000
00010
00000

Fence
black
.....
.0.0.
00000
.0.0.
.0.0.
Wall
brown darkbrown
00010
11111
01000
11111
00010
Void
black



PlayerX
black orange white darkblue purple
.000.
.111.
33233
.444.
.4.4.
PlayerKick
black orange white purple blue
.000.
.111.
33233
.444.
.4.4.
PlayerKickL
black orange white darkblue purple
.000.
.111.
4323.
44443
...4.
PlayerKickR
black orange white darkblue purple
.000.
.111.
.3234
34444
.4...

Rock
darkblue gray
..00.
.0110
01110
01110
.000.
RockKickU
purple lightgray
..00.
.0110
01110
01110
.000.
RockKickD
purple lightgray
..00.
.0110
01110
01110
.000.
RockKickL
purple lightgray
..00.
.0110
01110
01110
.000.
RockKickR
purple lightgray
..00.
.0110
01110
01110
.000.

Crate
orange yellow
00000
01110
01110
01110
00000
CrateSink
brown orange
00000
01110
01110
01110
00000

Snickers
darkbrown brown red
.....
10000
12220
10000
.....
Splat
brown
0..0.
.000.
0000.
.0000
.0.0.
SnickersSink
red
0...0
.0.0.
..0..
.0.0.
0...0

PlayerSnickers
black orange lightgray red darkred pink
.000.
.515.
33233
.444.
.4.4.
PlayerSnickers0
black orange lightgray red darkred pink
..3..
44350
.4210
44350
..3..
PlayerSnickers1
black orange lightgray red darkred pink
.4.4.
.444.
33233
.515.
.000.
PlayerSnickers2
black orange lightgray red darkred pink
..3..
05344
0124.
05344
..3..
PlayerSnickers3
black orange lightgray red darkred pink
.000.
.515.
33233
.444.
.4.4.



FallWaterX
transparent
FallWater0
white
.....
.....
..0..
.....
.....
FallWater1
lightblue
.....
..0..
.0.0.
..0..
.....
FallWater2
purple
..0..
.0.0.
0...0
.0.0.
..0..
FallWater3
darkblue
.000.
0...0
0...0
0...0
.000.

KickTP
transparent

MoveTP0
transparent
MoveTP1
transparent
MoveTP2
transparent

HoverTP
transparent
SnickersTP
transparent

=======
LEGEND
=======

■ = Void
. = Background
: = Grass
~ = Water

# = Fence
§ = Fence and Grass
% = Wall

P = PlayerX
* = Rock
+ = Crate
! = Snickers
$ = PlayerX and Grass
¤ = Rock and Grass
- = Crate and Grass
? = Snickers and Grass

Solid = Wall or Void or Crate
Block = Solid or Fence or Rock

RockKickDir = RockKickU or RockKickD or RockKickL or RockKickR
PlayerKickDir = PlayerKickL or PlayerKickR
PlayerSnickersAnim = PlayerSnickers0 or PlayerSnickers1 or PlayerSnickers2 or PlayerSnickers3

MoveTP = MoveTP0 or MoveTP1 or MoveTP2
FallWater = FallWaterX or FallWater0 or FallWater1 or FallWater2 or FallWater3

Player = PlayerX or PlayerKick or PlayerSnickers

=======
SOUNDS
=======

PlayerX move 67762507
Rock move 84730307
Crate move 36772507
Snickers move 28064707
RockKickDir create 78219304

sfx1 503107
PlayerKick create 76465107
sfx4 47022507
PlayerSnickers create 70363102
Splat create 33282502
SnickersSink create 18156901
PlayerSnickersAnim move 58846101
sfx2 54760704

sfx3 7152502

sfx0 51361104
FallWater0 create 374709
HoverTP create 43131503
CrateSink create 45872102

undo 89674306
restart 27105906
endlevel 18414108

================
COLLISIONLAYERS
================

Background

Grass
Water, CrateSink
FallWater
Snickers, Splat
Player, PlayerKickDir, PlayerSnickersAnim, Solid, Fence, Rock
RockKickDir
SnickersSink

KickTP
MoveTP

HoverTP
SnickersTP

======
RULES
======

[ PlayerKickDir KickTP ] -> [ PlayerX ]
[ PlayerKickDir ] -> [ PlayerKickDir KickTP ] again

up    [ RockKickU MoveTP1 | Fence ] -> [ RockKickU MoveTP2 | Fence ]
down  [ RockKickD MoveTP1 | Fence ] -> [ RockKickD MoveTP2 | Fence ]
left  [ RockKickL MoveTP1 | Fence ] -> [ RockKickL MoveTP2 | Fence ]
right [ RockKickR MoveTP1 | Fence ] -> [ RockKickR MoveTP2 | Fence ]

up    [ RockKickU | Solid ] -> [ RockKickU MoveTP2 | Solid ]
down  [ RockKickD | Solid ] -> [ RockKickD MoveTP2 | Solid ]
left  [ RockKickL | Solid ] -> [ RockKickL MoveTP2 | Solid ]
right [ RockKickR | Solid ] -> [ RockKickR MoveTP2 | Solid ]

up    [ RockKickU | Rock | Block ] -> [ RockKickU MoveTP2 | Rock | Block ]
down  [ RockKickD | Rock | Block ] -> [ RockKickD MoveTP2 | Rock | Block ]
left  [ RockKickL | Rock | Block ] -> [ RockKickL MoveTP2 | Rock | Block ]
right [ RockKickR | Rock | Block ] -> [ RockKickR MoveTP2 | Rock | Block ]

up    [ RockKickU | Rock | no Block ] -> [ RockKickU MoveTP2 | > RockKickU | ]
down  [ RockKickD | Rock | no Block ] -> [ RockKickD MoveTP2 | > RockKickD | ]
left  [ RockKickL | Rock | no Block ] -> [ RockKickL MoveTP2 | > RockKickL | ]
right [ RockKickR | Rock | no Block ] -> [ RockKickR MoveTP2 | > RockKickR | ]

[ RockKickU MoveTP1 ] -> [ up RockKickU up MoveTP2 ]
[ RockKickD MoveTP1 ] -> [ down RockKickD down MoveTP2 ]
[ RockKickL MoveTP1 ] -> [ left RockKickL left MoveTP2 ]
[ RockKickR MoveTP1 ] -> [ right RockKickR right MoveTP2 ]

[ RockKickU MoveTP0 ] -> [ up RockKickU up MoveTP1 ] again
[ RockKickD MoveTP0 ] -> [ down RockKickD down MoveTP1 ] again
[ RockKickL MoveTP0 ] -> [ left RockKickL left MoveTP1 ] again
[ RockKickR MoveTP0 ] -> [ right RockKickR right MoveTP1 ] again

[ RockKickU no MoveTP ] -> [ up RockKickU up MoveTP0 ] again
[ RockKickD no MoveTP ] -> [ down RockKickD down MoveTP0 ] again
[ RockKickL no MoveTP ] -> [ left RockKickL left MoveTP0 ] again
[ RockKickR no MoveTP ] -> [ right RockKickR right MoveTP0 ] again

late [ RockKickDir Fence MoveTP2 ] -> sfx3
late [ RockKickDir MoveTP2 ] -> [ Rock ]



[ > PlayerX | Water ] -> [ PlayerX | Water ] sfx1

[ > Player | Rock ] -> [ > Player | > Rock ]
[ > Player | Crate ] -> [ > Player | > Crate ]

[ > Rock | Snickers ] -> [ > Rock | > Snickers ]
[ > Crate | Snickers ] -> [ > Crate | > Snickers ]
[ > Snickers | Snickers ] -> [ > Snickers | > Snickers ]
[ > Snickers | Block ] -> [ Snickers | Block ]

late [ Crate Snickers ] -> [ Crate Splat ]
late [ Rock Snickers ] -> [ Rock Splat ]

[ > PlayerKick | Rock | Solid ] -> [ PlayerKick | Rock | Solid ] sfx0
[ > PlayerKick | Rock | Fence ] -> [ PlayerKick | Rock | Fence ] sfx0
[ > PlayerKick | Rock | Rock ] -> [ PlayerKick | Rock | Rock ] sfx0

up    [ > PlayerKick | Rock | no Solid ] -> [ PlayerKickL | > RockKickU | ] again
down  [ > PlayerKick | Rock | no Solid ] -> [ PlayerKickR | > RockKickD | ] again
left  [ > PlayerKick | Rock | no Solid ] -> [ PlayerKickL | > RockKickL | ] again
right [ > PlayerKick | Rock | no Solid ] -> [ PlayerKickR | > RockKickR | ] again

[ action PlayerX ] -> [ PlayerKick ]
[ action PlayerKick ] -> [ PlayerX ] sfx4
[ moving PlayerKick ] -> [ moving PlayerX ] sfx4



[ HoverTP | Rock Water ] -> [ | HoverTP > Rock Water ] again
[ > Rock | Water ] -> [ > Rock HoverTP | Water ] again

[ no Water | < Rock HoverTP ] -> [ | < Rock ]
[ Block | < Rock HoverTP ] -> [ Block | < Rock ]

late [ Crate Water ] -> [ CrateSink ]
late [ Snickers Water ] -> [ SnickersSink Water ]



late [ Player Snickers ] -> [ PlayerSnickers ]

[ SnickersTP | PlayerSnickers3 ] -> [ | SnickersTP > PlayerSnickers0 ] again
[ SnickersTP | PlayerSnickers2 ] -> [ | SnickersTP > PlayerSnickers3 ] again
[ SnickersTP | PlayerSnickers1 ] -> [ | SnickersTP > PlayerSnickers2 ] again
[ SnickersTP | PlayerSnickers0 ] -> [ | SnickersTP > PlayerSnickers1 ] again
[ > PlayerSnickers ] -> [ SnickersTP > PlayerSnickers0 ] again

late [ PlayerSnickersAnim Snickers | SnickersTP ] -> [ PlayerSnickers | ]

up    [ no Block | Rock | < PlayerSnickersAnim SnickersTP ] -> [ | < RockKickD | PlayerX ] sfx2
down  [ no Block | Rock | < PlayerSnickersAnim SnickersTP ] -> [ | < RockKickU | PlayerX ] sfx2
left  [ no Block | Rock | < PlayerSnickersAnim SnickersTP ] -> [ | < RockKickR | PlayerX ] sfx2
right [ no Block | Rock | < PlayerSnickersAnim SnickersTP ] -> [ | < RockKickL | PlayerX ] sfx2

[ Crate | < PlayerSnickersAnim SnickersTP ] -> [ < Crate | PlayerX ] sfx2
[ Block | < PlayerSnickersAnim SnickersTP ] -> [ Block | PlayerX ] sfx2



[ FallWater3 ] -> [ ]
[ FallWater2 ] -> [ FallWater3 ] again
[ FallWater1 ] -> [ FallWater2 ] again
[ FallWater0 ] -> [ FallWater1 ] again

late [ Rock Water ] -> [ FallWaterX Water ]
late [ FallWaterX ] [ HoverTP ] -> [ Rock ] [ HoverTP ]
late [ FallWaterX ] -> [ FallWater0 ] again

late [ PlayerX Water ] -> [ FallWater0 Water ] again

==============
WINCONDITIONS
==============

no Rock
no RockKickDir
no Snickers

no Splat
no SnickersSink

no FallWater
some PlayerX

=======
LEVELS
=======

message Level 0 of 15 - Press X to kick The Rock

■■■■■■■■■■■■■■
■~~~~~~~~~~~~■
■~~~~~~~~~~~~■
■~~~~~~~~~~~~■
■############■
■............■
■............■
■..*......p..■
■............■
■............■
■############■
■~~~~~~~~~~~~■
■~~~~~~~~~~~~■
■~~~~~~~~~~~~■
■■■■■■■■■■■■■■

message Level 1 of 15 - The Rock robbed my Snickers ;(

■■■■■■■■■■■■■
■~::::::::::■
■~%§§§§§§%::■
■~%::::::%::■
■~%::::::%::■
■~%::::::%::■
■~%::§§§§%::■
■~%::::::§::■
■~%%%%:::§::■
■~~~~§:::§::■
■~~~~§¤$:§::■
■~~~~§:::§::■
■~~~~%%%%%::■
■~~~~~~~~~~~■
■■■■■■■■■■■■■

message Level 2 of 15 - Hi my name is Fiddle With My BBC

■■■■■■■■■■■■■■
■::::::::~~~~■
■::%%%%%%%%~~■
■::%......%~~■
■::%..*p+.%~~■
■::%......%~~■
■:%%.#####%~~■
■:%.......#~~■
■:%.......%~~■
■:%%%%%%%%%~~■
■::::::::~~~~■
■■■■■■■■■■■■■■

message Level 3 of 15 - He is actually called Jake

■■■■■■■■■■■■■■■
■~~~~~~~~~~~~~■
■~~~~~~~~~~~~~■
■~~%%%#%#%%%~~■
■~~%%.+.+.%%~~■
■~~%.+.+.+.%~~■
■~~#+.+.+.+#~~■
■~~%.+.*.+.%~~■
■~~#+.+.+.+#~~■
■~~%.+.+.+.%~~■
■~~%%.+p+.%%~~■
■~~%%%#%#%%%~~■
■~~~~~~~~~~~~~■
■~~~~~~~~~~~~~■
■■■■■■■■■■■■■■■

message Level 4 of 15 - Tiny pond

■■■■■■■■■■■■■■■
■:::::::::::::■
■:%§§§§§§§§§%:■
■:%:::::::::%:■
■:%::§§§::::%:■
■:%::~~~::::%:■
■:%%:~~~~~~:%:■
■:%%:~~~~~~:%:■
■::%:§§§~~~:%:■
■::%::::::::%:■
■::%¤::::$::%:■
■::%::::::::%:■
■::%§§§§§§§§%:■
■:::::::::::::■
■■■■■■■■■■■■■■■

message Level 5 of 15 - More than one ????

■■■■■■■■■■■■■■■■■■
■~~~~~~~~~~~~~~~~■
■%%%§§%%§§%~~~~~~■
■%:::::::::~~~~~~■
■%::~~::~~:~~~~~~■
■%::~~::~~:~~~::~■
■%::~~::~~::~~¤:~■
■%:¤~~$~~~::~~::~■
■%:%~~:~~~::~~~~~■
■%::::::::::~~~~~■
■%%%§§%%§§%%~~~~~■
■~~~~~~~~~~~~~~~~■
■■■■■■■■■■■■■■■■■■

message Level 6 of 15 - Double kick

■■■■■■■■■■■
■~~~~~~~~~■
■~~~~~~~~~■
■~~~.*.~~~■
■~~~~~~~~~■
■~~~~~~~~~■
■~~~~~~~~~■
■#%.....%#■
■.%..p..%.■
■.%.....%.■
■#%.*.*.%#■
■~~~~~~.~~■
■~~~~~~.~~■
■~~~~~~.~~■
■#%.....%#■
■.%.....%.■
■.%.....%.■
■■■■■■■■■■■

message Level 7 of 15 - Line of crates

■■■■■■■■■■■■■■
■............■
■.%§§§§§§§§%.■
■.§::::::::§.■
■.§:~~~~~~:§.■
■.§:~~~~~~:§.■
■.§:~~~~~~:§.■
■.§:¤----¤:§.■
■.§::::$:::§.■
■.%§§§§§§§§%.■
■............■
■■■■■■■■■■■■■■

message Level 8 of 15 - OMG SNICKERS

■■■■■■■■■■■■■■■
■::#.......#::■
■::#.......#::■
■::#.......#::■
■::#.......#::■
■::#.......#::■
■##%.......%##■
■~~~~~~~~~~~~~■
■##%.......%##■
■::#.!.*.p.#::■
■::#.......#::■
■■■■■■■■■■■■■■■

message Level 9 of 15 - Eat all of the Snickers before The Rock steals them !

■■■■■■■■■■■■■
■~~~~~~~~~~~■
■~~~~~~~~~~~■
■~~...+...~~■
■~~.!...!.~~■
■~~...!...~~■
■~~..!p!.+~~■
■~~...!...~~■
■~~.!...!.~~■
■~~...+...~~■
■~~~~~~~~~~~■
■~~~~~~~~~~~■
■■■■■■■■■■■■■

message Level 10 of 15 - Sneak attack

■■■■■■■■■■■■■■■■■
■:::::::~~~~~~~~■
■:%§§§§§%%~~~~~~■
■:%:::::%%~~~~~~■
■:%:::::%%:¤:~~~■
■:%::?::%%~~~~~~■
■:%:::::%%::::%~■
■:%::$::~~::::%~■
■:%:::::~~::::%~■
■:%::¤::~~:::%%~■
■:%:::::~~:::%%~■
■:%:::::~~:::%%~■
■:%%%%%%~~:::%%~■
■■■■■■■■■■■■■■■■■

message Level 11 of 15 - Chocolate island

■■■■■■■■■■■■■
■~~~~~~~~~~~■
■~~~~~~~~~~~■
■~~?::::~~~~■
■~~:?:::$~~~■
■~~::?:¤::~~■
■~~:::?:::~~■
■~~::¤:?::~~■
■~~~::::?:~~■
■~~~~::::?~~■
■~~~~~~~~~~~■
■~~~~~~~~~~~■
■■■■■■■■■■■■■

message Level 12 of 15 - Wait a minute...

■■■■■■■■■■■
■~~~~~~~~~■
■~~~~~~~~~■
■%%%%.%%%%■
■.........■
■...#.#...■
■%.#.#.#.%■
■%.......%■
■%.*.p.+.%■
■%.......%■
■%%%%%%%%%■
■■■■■■■■■■■

message Level 13 of 15 - Willy McDuff's chocolate river

■■■■■■■■■■■
■%%%%%%%%%■
■~~~~~~~~~■
■!!!!!!!!!■
■*********■
■.........■
■..+.p.+..■
■.........■
■*********■
■~~~~~~~~~■
■%%%%%%%%%■
■■■■■■■■■■■

message Level 14 of 15 - The well

■■■■■■■■■■■■■■■■■■■
■....%%%%%%%%%....■
■.................■
■.................■
■%...%#######%...%■
■%...#.......#...%■
■%...#...*...#...%■
■%...#..***..#...%■
■%...#.**~**.#...%■
■%...#..***..#...%■
■%...#...*.p.#...%■
■%...#.......#...%■
■%...%#######%...%■
■.................■
■.................■
■....%%%%%%%%%....■
■■■■■■■■■■■■■■■■■■■

message Level 15 of 15 - Sugar rush

■■■■■■■■■■■■■■■
■~~~~~~~~~~~~~■
■~~~~~~~~~~~~~■
■~%%%#####%%%~■
■~%~~~~~~~~~%~■
■~%~.!.!.!.~%~■
■~#~!*!*!*!~#~■
■~#~.!*!*!.~#~■
■~#~!*!p!*!~#~■
■~#~.!*!*!.~#~■
■~#~!*!*!*!~#~■
■~%~.!.!.!.~%~■
■~%~~~~~~~~~%~■
■~%%%#####%%%~■
■~~~~~~~~~~~~~■
■~~~~~~~~~~~~~■
■■■■■■■■■■■■■■■

message I finally got revenge from The Rock ! I don't regret anything I did :)