IBurnedDownBigBenBecauseRishiSunakFuckingRobbedMyFish&Chips (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title IBurnedDownBigBenBecauseRishiSunakFuckingRobbedMyFish&Chips
author Stingby12
homepage https://www.tiktok.com/@jzuqiai/video/7283198440698432800

again_interval 0.05

(
verbose_logging
)

========
OBJECTS
========

Background
darkbrown brown
00100
00000
10101
00000
00100
Wall
orange brown
00000
10111
00000
11101
00000
Wood
lightbrown yellow
00000
01110
01110
01110
00000
WoodFire0
red yellow
00000
00100
01110
00100
00000
WoodFire1
red yellow
00000
01110
01010
01110
00000
Void
black



ExitClose
orange brown darkbrown yellow
00200
02220
02230
02220
02220
ExitOpen
orange brown black black
00200
02220
02230
02220
02220

Player
black orange darkgreen white purple
.000.
.111.
22322
.444.
.4.4.
PlayerDead
yellow red
10001
10001
00000
10001
10101
PlayerDeadU
red
.....
.....
.....
.....
00000
PlayerDeadD
red
00000
.....
.....
.....
.....
PlayerDeadL
red
....0
....0
....0
....0
....0
PlayerDeadR
red
0....
0....
0....
0....
0....


Barrel0
black red yellow
..1..
.121.
.000.
.000.
.000.
Barrel1
black yellow red
.2.2.
.121.
.000.
.000.
.000.
Crate
brown lightbrown
.....
.111.
.101.
.111.
.....
CrateFire
yellow red
.....
.111.
.101.
.111.
.....
Ash
black
.....
.....
..0..
.000.
.....


Broom
lightbrown darkgray
..0..
..0..
..0..
.000.
.111.
BroomFire
lightbrown white
..1..
..1..
..1..
.111.
.000.

Target
red darkred
.000.
01110
01110
01110
.000.
TargetX
red darkred black
.000.
01210
02220
01210
.000.


Hole
darkblue
Bridge
brown darkred
00000
11111
00000
11111
00000
BridgeFire
red yellow
00000
11111
00000
11111
00000



Anim
transparent

BurnTP
transparent
BurnX
transparent

OpenTP
transparent
LoseX
transparent

=======
LEGEND
=======

■ = Void
. = Background

% = Wall
# = Wood
^ = ExitClose

¤ = Hole
§ = Bridge

P = Player
* = Barrel0
+ = Crate
@ = Crate and Bridge

! = Broom
o = Target


Barrel = Barrel0 or Barrel1
WoodFire = WoodFire0 or WoodFire1

Fire = WoodFire or CrateFire or BroomFire
PlayerDeadB = PlayerDeadU or PlayerDeadD or PlayerDeadL or PlayerDeadR

Exit = ExitClose or ExitOpen

Block = Barrel or Crate or Broom or Wall or Exit or Fire

=======
SOUNDS
=======

Player move 67762507
sfx2 76468707

Barrel move 98622507
Crate move 62869307
Broom move 67474107
Ash move 59193907
sfx3 23228101

sfx0 80593502
sfx1 513102

PlayerDead create 77908102
TargetX create 12890104

undo 89674306
restart 27105906
endlevel 18414108

================
COLLISIONLAYERS
================

Background

Hole
Bridge, BridgeFire

Target, TargetX

Ash
PlayerDeadU
PlayerDeadD
PlayerDeadL
PlayerDeadR

Void, Wall, Wood, Exit, Player, PlayerDead, Barrel, Crate, Broom, Fire

Anim

BurnTP
BurnX

OpenTP
LoseX

======
RULES
======

[ Anim ] -> []
[ BurnTP ] -> []
[ BurnX ] -> []
[ PlayerDeadB ] -> []


[ Barrel1 no Anim ] -> [ Barrel0 Anim ]
[ Barrel0 no Anim ] -> [ Barrel1 Anim ]

[ WoodFire1 no Anim ] -> [ WoodFire0 Anim ]
[ WoodFire0 no Anim ] -> [ WoodFire1 Anim ]



[ > Player | Hole ] -> [ Player | Hole ] sfx2

[ > Player | Barrel ] -> [ > Player | > Barrel ]
[ > Player | Crate ] -> [ > Player | > Crate ]
[ > Player | Broom ] -> [ > Player | > Broom ]

[ > Player | BridgeFire ] -> [ Player | BridgeFire ] sfx2

[ > Broom | Ash ] -> [ > Broom | > Ash ]
[ > Ash | Ash ] -> [ > Ash | ]
[ > Ash | Block ] -> [ Ash | Block ]
[ > Ash | Block ] -> [ Ash | TargetX ]

[ Block Ash ] -> [ Block ]



late [ Barrel | Wood ] -> [ Barrel | WoodFire0 BurnTP ] sfx0
late [ Barrel | Crate ] -> [ Barrel | CrateFire BurnTP ] sfx0
late [ Barrel Bridge ] -> [ Barrel BridgeFire BurnTP ] sfx0

late [ Fire no BurnTP | Wood ] -> [ Fire | WoodFire0 BurnTP ] sfx0
late [ Fire no BurnTP | Crate ] -> [ Fire | CrateFire BurnTP ] sfx0
late [ Fire Bridge ] -> [ Fire BridgeFire BurnTP ] sfx0

late [ PlayerDead no BurnTP | Wood ] -> [ PlayerDead | WoodFire0 BurnTP ] sfx0
late [ PlayerDead no BurnTP | Crate ] -> [ PlayerDead | CrateFire BurnTP ] sfx0
late [ PlayerDead Bridge ] -> [ PlayerDead BridgeFire BurnTP ] sfx0

late [ BridgeFire no BurnTP | Bridge ] -> [ BridgeFire | BridgeFire BurnTP ] sfx0
late [ BridgeFire Crate ] -> [ BridgeFire CrateFire BurnTP ] sfx0
late [ BridgeFire Broom ] -> [ BridgeFire BroomFire BurnTP ] sfx0



[ BridgeFire ] -> [ BridgeFire BurnX ]
late [ BridgeFire BurnX ] -> [ Hole BurnX ] sfx1

[ CrateFire ] -> [ CrateFire BurnX ]
late [ CrateFire BurnX ] -> [ Ash BurnX ] sfx1
[ BroomFire ] -> [ BroomFire BurnX ]
late [ BroomFire BurnX ] -> [ Ash BurnX ] sfx1

late [ Ash Target ] -> [ TargetX ]
[ > Block | TargetX ] -> [ Block | TargetX ]
[ > Player | TargetX ] -> [ Player | TargetX ]



late [ Barrel Hole ] -> [ Hole ] sfx3
late [ Crate Hole ] -> [ Hole ] sfx3
late [ Broom Hole ] -> [ Hole ] sfx3
late [ PlayerDead Hole ] -> [ Hole ] sfx3
late [ Ash Hole ] -> [ Hole ]



late [ Player | WoodFire ] -> [ PlayerDead BurnTP LoseX | WoodFire ]
late [ Player BridgeFire ] -> [ PlayerDead BurnTP LoseX BridgeFire ]

late up    [ PlayerDead | ] -> [ PlayerDead | PlayerDeadU ]
late down  [ PlayerDead | ] -> [ PlayerDead | PlayerDeadD ]
late left  [ PlayerDead | ] -> [ PlayerDead | PlayerDeadL ]
late right [ PlayerDead | ] -> [ PlayerDead | PlayerDeadR ]



late [ ExitClose ] -> [ ExitClose OpenTP ]

late [ OpenTP ] [ Wood ] -> [] [ Wood ]

late [ OpenTP ] [ Crate ] -> [] [ Crate ]
late [ OpenTP ] [ CrateFire ] -> [] [ CrateFire ]

late [ OpenTP ] [ Bridge ] -> [] [ Bridge ]
late [ OpenTP ] [ BridgeFire ] -> [] [ BridgeFire ]

late [ OpenTP ] [ Target ] -> [] [ Target ]

late [ ExitClose OpenTP ] -> [ ExitOpen ]

[ > Player | ExitOpen ] -> [ | ExitOpen ]

==============
WINCONDITIONS
==============

no Player
no LoseX

=======
LEVELS
=======

message Level 0 of 15 - Burn down all of the wood then run away

■■■■■■■■■■■
■%%%%^%%%%■
■%.......%■
■%.......%■
■%..p.*..%■
■%.......%■
■%.......%■
■%.#####.%■
■%.......%■
■%%%%%%%%%■
■■■■■■■■■■■

message Level 1 of 15 - Rishi Sunak robbed my fish & chips :(

■■■■■■■■■■
■%%%%%%%%■
■%.*....%■
■%...p..%■
■%......%■
■^.++++%%■
■%.....#%■
■%%%%%%%%■
■■■■■■■■■■

message Level 2 of 15 - There is no fish & chips in this game lmao

■■■■■■■■■■■
■%%%%^%%%%■
■%%..p..%%■
■%#.....#%■
■%#.+++.#%■
■%#.....#%■
■%#..*..#%■
■%%%%%%%%%■
■■■■■■■■■■■

message Level 3 of 15 - Double entry

■■■■■■■■■■■
■%%%%%%%%%■
■%......%%■
■%.+.#...%■
■%...#...%■
■%%.%#.p.^■
■%...#...%■
■%.*.#...%■
■%......%%■
■%%%%%%%%%■
■■■■■■■■■■■

message Level 4 of 15 - Colon

■■■■■■■■■■■
■%%%%%%%%%■
■%%..#..%%■
■%...+...%■
■%...#...%■
■^.p...*.%■
■%...#...%■
■%...+...%■
■%%..#..%%■
■%%%%%%%%%■
■■■■■■■■■■■

message Level 5 of 15 - 2050 door model

■■■■■■■■■■■■■
■%%%^%#####%■
■%%*.%.....%■
■%#.p%+++++%■
■%#..%.....%■
■%%.%%+++++%■
■%...%.....%■
■%.*.......%■
■%...%.....%■
■%%%%%%%%%%%■
■■■■■■■■■■■■■

message Level 6 of 15 - Burning bridges

■■■■■■■■■
■%%%^%%%■
■%.....%■
■%..p..%■
■%.....%■
■%¤§¤§¤%■
■%¤§¤§¤%■
■%.....%■
■%.+.*.%■
■%.....%■
■%%%^%%%■
■■■■■■■■■

message Level 7 of 15 - Don't ask why there are bridges inside Big Ben

■■■■■■■■■■■■■■■■
■%%%%%%%%%%^%%%■
■%%...¤¤¤..p..%■
■%.+..§§§.....%■
■%..*.¤¤§.+.+.%■
■%....§¤¤.....%■
■%.+..§§§.+.+.%■
■%%...¤¤¤.....%■
■%%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■■

message Level 8 of 15 - Callback

■■■■■■■■■■■
■%%%%%%%%%■
■%...%..%%■
■%...§...%■
■%...§...%■
■%%.%%.p.^■
■%...§...%■
■%.*.§...%■
■%...%..%%■
■%%%%%%%%%■
■■■■■■■■■■■

message Level 9 of 15 - Cremation

■■■■■■■■■■■■■■■■
■%%%%%%%%%%^%%%■
■%%.*.%%%.....%■
■%....%*%..p..%■
■%*.o.........%■
■%....%*%.+.!.%■
■%%.*.%%%.....%■
■%%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■■

message Level 10 of 15 - Fireplace

■■■■■■■■■■■
■%%^%%%%%%■
■%...%...%■
■%.p.o.+.%■
■%...%...%■
■%.*.o.+.%■
■%...%...%■
■%%%%%%%%%■
■■■■■■■■■■■

message Level 11 of 15 - No entry

■■■■■■■■■■■■■■
■%%%%%%%%%%%%■
■%.....%¤¤¤¤%■
■%..!..%¤¤¤¤%■
■%.....%%%%%%■
■%.....%....%■
■%.*.+.o..p.%■
■%.....%....%■
■%%%%%%%%%^%%■
■■■■■■■■■■■■■■

message Level 12 of 15 - Cleaning room

■■■■■■■■■■■■■■■■■
■%%%^%%%%%%%%%%%■
■%.....¤¤¤¤¤...#■
■%.p.!.§¤¤¤§.+.#■
■%.....§§§§§.+.#■
■%.+.*.§¤¤¤§.+.#■
■%.....¤¤¤¤¤...#■
■%%%%%%%%%%%.o.%■
■%¤¤¤¤¤¤¤¤¤%...%■
■%%%%%%%%%%%%%%%■
■■■■■■■■■■■■■■■■■

message Level 13 of 15 - Stranded island

■■■■■■■■■■■■■
■%%%##^##%%%■
■%%%§§p§§%%%■
■%%§§§§§§§%%■
■#§§+.*.+§§#■
■#§§.+.+.§§#■
■#§§*.+.*§§#■
■#§§.+.+.§§#■
■#§§+.*.+§§#■
■%%§§§§§§§%%■
■%%%§§§§§%%%■
■%%%#####%%%■
■■■■■■■■■■■■■

message Level 14 of 15 - Better than ManlyBadassHero

■■■■■■■■■■■■■
■%%%%%^%%%%%■
■%%%§§p§§%%%■
■%%§§§§§§§%%■
■#§§*.*.*§§#■
■#§§.*.*.§§#■
■#§§+.*.+§§#■
■#§§.*.*.§§#■
■#§§*.*.*§§#■
■%%§§§§§§§%%■
■%%%§§§§§%%%■
■%%%#####%%%■
■■■■■■■■■■■■■

message Level 15 of 15 - Tricked treat

■■■■■■■■■■■■■
■%%%%%%%%%%%■
■%¤¤%..o%¤¤%■
■%%%%..%%%%%■
■%*%§@§@§%*%■
■%..@.*.@..%■
■^po§.!.§o.^■
■%..@.*.@..%■
■%*%§@§@§%*%■
■%%%%%..%%%%■
■%¤¤%o..%¤¤%■
■%%%%%%%%%%%■
■■■■■■■■■■■■■

message That thief Rishi Sunak got exactly what he deserved for robbing my delicious fish & chips !!!
message The judge has decided to sentence me the death penalty
message Let's get to 250 views on this game so you can watch my public execution !
message Comment 'fire in the hole' if this is relatable