Fruit People Slicing Olympics 2024 (Puzzlescript Plus Script)

readme.txt

Play this game by pasting the script in https://auroriax.github.io/PuzzleScript/editor.html

script.txt

title Fruit People Slicing Olympics 2024
author Stingby12
homepage www.puzzlescript.net

again_interval 0.05
tween_easing linear
tween_length 0.05
run_rules_on_level_start

level_select
level_select_lock
level_select_solve_symbol X

color_palette atari

========
OBJECTS
========

Background
green darkgreen
11111
01111
11101
11111
10111

Wall
darkgray black
00010
11111
01000
11111
00010

Player
black yellow
.000.
.111.
00000
.000.
.0.0.

PlayerSliceU
black yellow white brown
2000.
2000.
0000.
.000.
.0.0.
PlayerSliceUX
black yellow white brown
.....
.....
.....
.....
2....
PlayerSliceD
black yellow white brown
.000.
.111.
.0003
.0002
.0.02
PlayerSliceDX
black yellow white brown
....2
.....
.....
.....
.....
PlayerSliceL
black yellow white brown
.000.
.110.
22230
.000.
.0.0.
PlayerSliceR
black yellow white brown
.000.
.011.
00002
.000.
.0.0.

Crate
orange yellow
00000
01110
01110
01110
00000
CrateIron
lightgray gray
00000
01110
01110
01110
00000

Water
darkblue blue
00000
01100
00000
00011
00000
CrateHole
brown orange
00000
01110
01110
01110
00000
CrateIronHole
gray darkgray
00000
01110
01110
01110
00000

Drown0
lightblue
.....
.....
..0..
.....
.....
Drown1
lightblue
.....
.000.
.0.0.
.000.
.....
Drown2
lightblue
.000.
0...0
0...0
0...0
.000.



Watermelon
lightgreen red black
.....
01120
02110
00100
.000.
WatermelonCU
transparent
WatermelonCD
transparent
WatermelonCL
transparent
WatermelonCR
transparent

Cherry
red lightgreen
..11.
.1.1.
00.1.
00.00
...00
CherryCU
transparent
CherryCD
transparent
CherryCL
transparent
CherryCR
transparent
CherryX
transparent

AppleA
red brown
..1..
.000.
00000
00000
.0.0.
AppleB copy:AppleA
yellow brown
AppleC copy:AppleA
lightgreen brown

Pear
lightgreen brown
..11.
.000.
.000.
00000
.000.
PearCU
transparent
PearCD
transparent
PearCL
transparent
PearCR
transparent

Grape
purple blue brown
..2..
.101.
.010.
.10..
..1..
GrapeSp
transparent
GrapeX
transparent

Orange
lightbrown brown
.010.
00000
00000
00000
.000.
OrangeSp
transparent
OrangeX
transparent

Lemon
yellow
.....
.000.
00000
.000.
.....

Slice
transparent



CrateBroken
orange
.....
..0..
0....
...0.
.....
WatermelonBroken
darkred black
..00.
.1000
00010
0100.
.00..
CherryBroken
darkred black
00...
010..
00000
..010
..00.
AppleBroken
lightbrown black
.....
.0.0.
01.10
00.00
.0.0.
PearBroken
yellow black
.....
.0.0.
.0.0.
01.10
.0.0.
GrapeBroken
darkblue
.....
.000.
00000
.0000
..00.
OrangeBroken
orange yellow
.000.
01010
00000
01010
.000.
LemonBroken
lightbrown yellow
.....
.000.
.010.
.000.
.....


=======
LEGEND
=======

. = Background
# = Wall
@ = Player
* = Crate
+ = CrateIron
▪ = Water

W = Watermelon
C = Cherry
A = AppleA
 = AppleB
Ä = AppleC
P = Pear
G = Grape
O = Orange
L = Lemon



Apples = AppleA or AppleB or AppleC
Fruit = Watermelon or Cherry or Apples or Pear or Grape or Orange or Lemon

WatermelonCheck = WatermelonCU or WatermelonCD or WatermelonCL or WatermelonCR 
CherryCheck = CherryCU or CherryCD or CherryCL or CherryCR or CherryX
OrangeCheck = OrangeSp or OrangeX
GrapeCheck = GrapeSp or GrapeX
PearCheck = PearCU or PearCD or PearCL or PearCR

PlayerSlice = PlayerSliceU or PlayerSliceD or PlayerSliceL or PlayerSliceR
FruitBroken = WatermelonBroken or CherryBroken or AppleBroken or PearBroken or GrapeBroken or OrangeBroken or LemonBroken

Crates = Crate or CrateIron
Block = Wall or Crates or Water or Fruit
CoverWater = CrateHole or CrateIronHole

=======
SOUNDS
=======

Player move 37829107
PlayerSlice move 99054307

Fruit move 54052507
Crates move 26533307
sfx2 9138904
Drown0 create 34023103

sfx0 68955301
sfx1 80538502
CrateBroken create 99603904
Fruit destroy 5750502

endlevel 80742308

================
COLLISIONLAYERS
================

Background
Water
CrateHole
CrateIronHole
Drown0 Drown1 Drown2

FruitBroken
CrateBroken

PlayerSliceUX PlayerSliceDX
Player PlayerSlice, Wall Crates Fruit

WatermelonCU
WatermelonCD
WatermelonCL
WatermelonCR

CherryCU
CherryCD
CherryCL
CherryCR
CherryX

PearCU
PearCD
PearCL
PearCR

GrapeSp
GrapeX
OrangeSp
OrangeX

Slice

======
RULES
======

late [ WatermelonCheck ] -> [ ]
late [ CherryCheck ] -> [ ]
[ PearCheck no Pear ] -> [ ]
late [ GrapeCheck ] -> [ ]
late [ OrangeCheck ] -> [ ]
late [ Slice ] -> [ ]

[ PlayerSliceUX ] -> [ ]
[ PlayerSliceDX ] -> [ ]

up   [ PlayerSliceU | ] -> [ PlayerSliceU | up PlayerSliceUX ]
down [ PlayerSliceD | ] -> [ PlayerSliceD | down PlayerSliceDX ]

(Slicing)

up    [ > Player | Pear Slice ] -> [ > PlayerSliceU | Pear PearCU ] again
down  [ > Player | Pear Slice ] -> [ > PlayerSliceD | Pear PearCD ] again
left  [ > Player | Pear Slice ] -> [ > PlayerSliceL | Pear PearCL ] again
right [ > Player | Pear Slice ] -> [ > PlayerSliceR | Pear PearCR ] again

up    [ > Player | Fruit Slice ] -> [ > PlayerSliceU | Fruit ] again
down  [ > Player | Fruit Slice ] -> [ > PlayerSliceD | Fruit ] again
left  [ > Player | Fruit Slice ] -> [ > PlayerSliceL | Fruit ] again
right [ > Player | Fruit Slice ] -> [ > PlayerSliceR | Fruit ] again

[ PlayerSliceU ] -> [ up PlayerSliceU ] again
[ PlayerSliceD ] -> [ down PlayerSliceD ] again
[ PlayerSliceL ] -> [ left PlayerSliceL ] again
[ PlayerSliceR ] -> [ right PlayerSliceR ] again



[ > PlayerSlice | Watermelon CrateBroken ] -> [ > PlayerSlice | WatermelonBroken ] sfx0
[ > PlayerSlice | Cherry CrateBroken ] -> [ > PlayerSlice | CherryBroken ] sfx0
[ > PlayerSlice | Orange CrateBroken ] -> [ > PlayerSlice | OrangeBroken ] sfx0
[ > PlayerSlice | Apples CrateBroken ] -> [ > PlayerSlice | AppleBroken ] sfx0
[ > PlayerSlice | Grape CrateBroken ] -> [ > PlayerSlice | GrapeBroken ] sfx0
[ > PlayerSlice | Lemon CrateBroken ] -> [ > PlayerSlice | LemonBroken ] sfx0
[ > PlayerSlice | Pear CrateBroken ] -> [ > PlayerSlice | PearBroken ] sfx0

[ > PlayerSlice | Watermelon ] -> [ > PlayerSlice | WatermelonBroken ] sfx0
[ > PlayerSlice | Cherry ] -> [ > PlayerSlice | CherryBroken ] sfx0
[ > PlayerSlice | Orange ] -> [ > PlayerSlice | OrangeBroken ] sfx0
[ > PlayerSlice | Apples ] -> [ > PlayerSlice | AppleBroken ] sfx0
[ > PlayerSlice | Grape ] -> [ > PlayerSlice | GrapeBroken ] sfx0
[ > PlayerSlice | Lemon ] -> [ > PlayerSlice | LemonBroken ] sfx0
[ > PlayerSlice | Pear ] -> [ > PlayerSlice | PearBroken ] sfx0

[ > PlayerSlice | Crate ] -> [ > PlayerSlice | CrateBroken ] sfx0

[ > PlayerSlice | Wall ] -> [ Player | Wall ] sfx1
[ > PlayerSlice | CrateIron ] -> [ Player | CrateIron ] sfx1

[ Player ] [ PlayerSliceUX ] -> [ Player ] [ ]
[ Player ] [ PlayerSliceDX ] -> [ Player ] [ ]

(Basic)

[ > Player | Fruit ] -> [ > Player | > Fruit ]
[ > Player | Crates ] -> [ > Player | > Crates ]

[ > Player | Water no CoverWater ] -> [ Player | Water ]
[ > Fruit | Water no CoverWater ] -> [ Fruit | Water ]

[ Drown2 ] -> [ ]
[ Drown1 ] -> [ Drown2 ] again
[ Drown0 ] -> [ Drown1 ] again
late [ Player Water no CoverWater ] -> [ Drown0 Water ] again

[ > Crate | Water no CoverWater ] -> [ > CrateHole | Water ] sfx2
[ > CrateIron | Water no CoverWater ] -> [ > CrateIronHole | Water ] sfx2

(Watermelon)

late up    [ Watermelon | Block ] -> [ Watermelon WatermelonCU | Block ]
late down  [ Watermelon | Block ] -> [ Watermelon WatermelonCD | Block ]
late left  [ Watermelon | Block ] -> [ Watermelon WatermelonCL | Block ]
late right [ Watermelon | Block ] -> [ Watermelon WatermelonCR | Block ]

late up    [ WatermelonCU | CoverWater no Crates no Fruit ] -> [ | CoverWater ]
late down  [ WatermelonCD | CoverWater no Crates no Fruit ] -> [ | CoverWater ]
late left  [ WatermelonCL | CoverWater no Crates no Fruit ] -> [ | CoverWater ]
late right [ WatermelonCR | CoverWater no Crates no Fruit ] -> [ | CoverWater ]

late [ WatermelonCU WatermelonCD WatermelonCL ] -> [ Slice ]
late [ WatermelonCU WatermelonCD WatermelonCR ] -> [ Slice ]
late [ WatermelonCL WatermelonCR WatermelonCU ] -> [ Slice ]
late [ WatermelonCL WatermelonCR WatermelonCD ] -> [ Slice ]

(Cherry)

late up   [ Cherry | Cherry ] -> [ Cherry CherryCU | Cherry CherryCD ]
late left [ Cherry | Cherry ] -> [ Cherry CherryCL | Cherry CherryCR ]

late [ CherryCU CherryCD ] -> [ CherryX ]
late [ CherryCL CherryCR ] -> [ CherryX ]

late [ CherryCU CherryCL ] -> [ CherryX ]
late [ CherryCU CherryCR ] -> [ CherryX ]
late [ CherryCD CherryCL ] -> [ CherryX ]
late [ CherryCD CherryCR ] -> [ CherryX ]

late [ Cherry CherryX | Cherry ] -> [ Cherry CherryX | Cherry CherryX ]
late [ Cherry CherryCU no CherryX ] -> [ Cherry Slice ]
late [ Cherry CherryCD no CherryX ] -> [ Cherry Slice ]
late [ Cherry CherryCL no CherryX ] -> [ Cherry Slice ]
late [ Cherry CherryCR no CherryX ] -> [ Cherry Slice ]

(Apple)

late [ AppleA | AppleA | AppleA ] -> [ AppleA Slice | AppleA Slice | AppleA Slice ]
late [ AppleB | AppleB | AppleB ] -> [ AppleB Slice | AppleB Slice | AppleB Slice ]
late [ AppleC | AppleC | AppleC ] -> [ AppleC Slice | AppleC Slice | AppleC Slice ]

(Pear)

late [ PearCU ] [ Pear ] -> [ PearCU ] [ Pear PearCU ]
late [ PearCD ] [ Pear ] -> [ PearCD ] [ Pear PearCD ]
late [ PearCL ] [ Pear ] -> [ PearCL ] [ Pear PearCL ]
late [ PearCR ] [ Pear ] -> [ PearCR ] [ Pear PearCR ]

late [ Pear ] -> [ Pear Slice ]

late up    [ no Player | Pear PearCU Slice ] -> [ | Pear PearCU ]
late down  [ no Player | Pear PearCD Slice ] -> [ | Pear PearCD ]
late left  [ no Player | Pear PearCL Slice ] -> [ | Pear PearCL ]
late right [ no Player | Pear PearCR Slice ] -> [ | Pear PearCR ]

(Grape)

late [ Player ] -> [ Player GrapeSp ]

late [ GrapeSp ] [ Grape ] -> [ ] [ Grape GrapeX ]
late [ GrapeX | Grape ] -> [ GrapeX | Grape GrapeX ]

late [ Grape no GrapeX ] [ Grape GrapeX ] -> [ Grape ] [ Grape ]
late [ Grape GrapeX ] -> [ Grape Slice ]

(Orange)

late [ Player ] -> [ Player OrangeSp ]

startloop
 late [ OrangeSp | no Block ] -> [ OrangeSp | OrangeSp ]
 late [ OrangeSp | Water ] -> [ OrangeSp | Water OrangeSp ]
 late [ OrangeSp | Orange ] -> [ OrangeSp | Orange OrangeSp ]
endloop

late [ Player OrangeSp ] [ Orange OrangeSp ] -> [ Player ] [ Orange Slice ]
late [ Orange OrangeSp ] -> [ Orange OrangeX ]
late [ Orange OrangeSp ] [ OrangeX ] -> [ Orange OrangeX ] [ OrangeX ]
late [ Orange Slice ] [ OrangeX ] -> [ Orange OrangeX ] [ OrangeX ]

==============
WINCONDITIONS
==============

no Fruit
some Player

=======
LEVELS
=======

section 1 - Watermelon People
message Challenge 1 - Watermelon People

section Straight line
message I am tired of those Fruit People fanum taxing my ass
#########
#...#####
#.@.w...#
#...#####
#########

section Hole in ones
message So I'm participating in the Fruit People Slicing Olympics 2024 so that I can get rid of them once and for all
###....#
#.######
#......#
#.w.@w.#
#......#
######.#
#....###

section Tool
message So far I'm at the Watermelon trials, it's kinda easy tbh
#######
#.....#
#.w...#
#.....#
#.@.*.#
#.....#
#######

section Mouth
message This seems trickier
###########
#.........#
#....w....#
#...###...#
#....@....#
#...###...#
#....w....#
#.........#
###########

section Out of bounds
message Finally an actual challenge
########
#......#
#.w..#.#
#......#
#.@....#
#....w.#
#.w....#
########

section Waiting line
message Look at those poor Watermelon People trying to defend themselves
########
#....###
#....#.#
#@.www.#
#....#.#
#....###
########

section Big watermelon
message I think I have the strategy in my head now
#######
#....@#
#.www.#
#.w*w.#
#.w*w.#
#.www.#
#.....#
#######

section 2 - Cherry People
message Challenge 2 - Cherry People

section Two cherries
message Moving on to these Cherry People
#########
#.......#
#.......#
#.c.@.c.#
#.......#
#.......#
#########

section Still out of bounds
message Kinda easy to deal with tbh
#######
#...c.#
#.c...#
#.....#
#...@.#
#.c...#
#######

section Group rules
message These guys are already in pairs lol
#######
#.....#
#.....#
#.....#
##ccc##
.##.##.
.#...#.
.#.@.#.
.#...#.
.#####.

section Line of cherries
message They legit are conjoined twins fr
.#####.
##...##
#ccccc#
#.....#
#..@..#
##...##
.#####.

section Cherry box
message They asking for an entire built in family or smth ???
########
##.@..##
#.cccc.#
#.c..c.#
#.c..c.#
#.cccc.#
##....##
########

section 3 - Apple People
message Challenge 3 - Apple People

section Conga line
message Let's take a look at those Apple People
#########
#.......#
#.a.a.a.#
#.......#
#...@...#
#.......#
#########

section Two strokes
message Trying to become the Cherry guys ?
#######
#.....#
#.äää.#
#.ä...#
#.ä.@.#
#.....#
#######

section Target shooting
message Okay maybe not
#########
##aa##a##
#.......#
#...@...#
#.......#
#.âââââ.#
#.......#
#########

section Guinean nightmare
message Woah they def move based than Cherry People
#########
#..aâä..#
#..aâä..#
#@.a#ä..#
#..aâä..#
#..aâä..#
#########

section Apple farm
message And they still trying to fanum tax everyone
##########
#........#
#.aâä#...#
#.äaâä...#
#.âäaâ.ä.#
#.#âäa...#
#.....@..#
#...ä..ä.#
#........#
##########

section 4 - Obstacles
message Challenge 4 - Obstacles

section Watergate
message Ooooh a river now it's getting serious
#####▪#####
#....▪....#
#.c..▪..c.#
#...@▪....#
#.c..▪..c.#
#....▪....#
#####▪#####

section Crawlspace
message Almost forgot about how thirsty are Watermelon People
....###
#####.#
#..w..#
#.▪▪.▪#
#.....#
#.w.w.#
#.....#
##.@.##
.#####.

section Cheeky corner
message These Cheery People stand no chance
#######
#▪...▪#
#.ccc.#
#.c@c.#
#.ccc.#
#▪....#
#######

section Stranded
message I'm gonna put those crates in use here
##########
#▪▪▪▪▪▪▪▪#
#▪...w..▪#
#▪.*....▪#
#▪...@.w▪#
#▪w.....▪#
#▪....*.▪#
#▪..w...▪#
#▪▪▪▪▪▪▪▪#
##########

section Ironed
message Bet this upgrade gotta make it epic
###########
#▪▪▪▪▪▪▪▪▪#
#▪▪▪▪▪▪▪▪▪#
#▪▪.....▪▪#
#▪▪.w.w.▪▪#
#▪▪.+@+.▪▪#
#▪▪.w.w.▪▪#
#▪▪.....▪▪#
#▪▪▪▪▪▪▪▪▪#
#▪▪▪▪▪▪▪▪▪#
###########

section Comeback
message Watermelon planing revenge !
###########
#▪▪▪▪▪▪▪▪▪#
#▪▪▪▪▪▪▪▪▪#
#▪▪.....▪▪#
#▪▪.www.▪▪#
#▪▪.w+w.▪▪#
#▪▪.w*w.▪▪#
#▪▪.www.▪▪#
#▪▪..@..▪▪#
#▪▪▪▪▪▪▪▪▪#
#▪▪▪▪▪▪▪▪▪#
###########

section 5 - Pear People
message Challenge 5 - Pear People

section Simple looking
message I've never seen those pear people before
#########
#.......#
#...@...#
#p......#
#...p...#
#......p#
#########

section Sharp turn
message What kind of person is that
###########
#...#.....#
#......@..#
#...#.....#
#▪▪▪#.p.p.#
#.p.#.....#
###########

section Wait
message This competition feels like a zoo
###.###
#.#####
#p....#
##..w.#
#.....#
#@.p..#
#.....#
#.w..##
#....p#
#####.#
###.###

section Even more out of reach
message Is that fanum tax gang that massive ???
##########..
#........#..
#..p.....###
#.....#....#
#.p.w.#.@.c#
#.....#....#
#..p.....###
#........#..
##########..

section 6 - Grape People
message Challenge 6 - Grape People

section Another line
message Yeah kinda expected that this exist
...#####
..##▪▪▪#
###....#
#ggggg.#
#....###
#.@..#..
#...##..
######..

section Wine range
message Now that's just a entire cult
....######
#####▪▪▪▪#
#▪.gg...▪#
#▪.gggg.▪#
##.gggg.▪#
.#.ggggg##
.#.ggggg#.
.#@.....#.
.#####▪▪#.
.....####.

section Gripe
message Those Grape People creepy af I'm glad they didn't tried to fanum tax my ass
.###...###.
##▪########
#▪..g.g..##
##.......##
.#g.p...g#.
.#...@...#.
.#g...p.g#.
##.......##
##..g.g..▪#
########▪##
.###..####.

section Similarities
message Gotta wipe them out as fast as possible
###########
▪▪▪▪▪▪▪▪▪▪▪
#.g..▪..c.#
#g.g.▪.c.c#
#.g.g▪c.c.#
#g.g.@.c.c#
#.g.g▪c.c.#
#g.g.▪.c.c#
#.g..▪..c.#
▪▪▪▪▪▪▪▪▪▪▪
###########

section 7 - Citrus People
message Challenge 7 - Citrus People

section Do it yourself
message This is the final challenge before the results
▪▪▪▪▪▪#######▪▪
▪▪▪▪▪▪#..####▪▪
#######.p.l.#▪▪
#.....#..#..#▪▪
#.l.@.#.l.p.#▪▪
#.....#.....#▪▪
#...w.#.#######
#.......#.....#
#######.#g.l..#
▪▪▪▪▪▪#..g....#
▪▪▪▪▪▪###g.l..#
▪▪▪▪▪▪▪▪#.....#
▪▪▪▪▪▪▪▪#######

section Segregation puzzle
message Now it's just Orange People and Lemon People
#########
#o.###..#
#..c.c..#
#...@...#
#..###.o#
#########

section Easier than it looks
message I trained hard for this moment
#########
#.......#
#.o.o.o.#
#...@...#
#.w.w.w.#
#.......#
#########

section Baricade
message Those Orange People gotta be the trickiest
#######
#.....#
#o...o#
#.....#
#lglgl#
#.....#
#o.@.o#
#.....#
#######

section Not how it works
message I want the competition trophy
.#########.
.#.......#.
.#..o.o..#.
.#...*...#.
.#.......#.
###▪#▪#▪###
#.o..@..o.#
#.........#
#..ää.ää..#
#.........#
###########

section Four by four
message Only a few trials yet
######▪######
#.....▪.....#
#.g.g.▪.l...#
#.....▪..l..#
#.g.*.▪...l.#
#.....▪.....#
▪▪▪▪▪▪#▪▪▪▪▪▪
#....@▪.....#
#.p...▪.*.c.#
#..p..▪.....#
#...p.▪.c.c.#
#.....▪.....#
######▪######

section All in one
message This is the final challenge
#######################
#▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪#
#▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪#
#▪▪▪...............▪▪▪#
#▪▪.w.c.a.â.p.g.o.l.▪▪#
#▪▪...c.a.â.p.g.o.l.▪▪#
#▪▪.+.c.a.â.p.g...l.▪▪#
#▪▪.@.......p.g.....▪▪#
#▪▪▪...............▪▪▪#
#▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪#
#▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪▪#
#######################

message YES I DID IT I AM THE FRUIT PEOPLE SLICE MASTER
message the end :)