Current working status of the PKGBUILD for ocfs2-tools 1.8.5

PKGBUILD

# Maintainer: Thermi <noel at familie-kuntze dot de>

pkgname=ocfs2-tools
pkgver=1.8.5
pkgrel=1
pkgdesc="ocfs2 tool chain by Oracle, including mkfs, tunefs, fsck, debugfs and utilities for ocfs2"
arch=('x86_64' 'i686')
url="https://github.com/markfasheh/ocfs2-tools/"
license=('GPL2')
optdepends=('pacemaker' 'corosync')
makedepends=('automake')
source=("https://github.com/markfasheh/ocfs2-tools/archive/ocfs2-tools-${pkgver}.tar.gz")

sha256sums=('ccf8bf8a2cccad841a96b41e0a858194ec61e8a765065630595d4218e9008569')

build() {
	# Upstream packaged it like that, it's not a problem in this PKGBUILD.
	cd "${srcdir}/ocfs2-tools-ocfs2-tools-${pkgver}/"
	# Upstream doesn't ship a configure shell script, but only a short script
	# to generate one that uses autoconf from the automake tools. It takes the
	# arguments to it and calls the generated configure-script from it.
	./autogen.sh --prefix=/usr 		\
		--sysconfdir=/etc 			\
		--libexecdir=/usr/lib		\
		--sbindir=/usr/bin			\
		--mandir=/usr/share/man		\
		--enable-dynamic-ctl=yes	\
		--enable-dynamic-fsck=yes
	# The Makefile doesn't always work on Arch. It seems to be a dependency
	# issue in it.
	make
}

package() {
	cd "${srcdir}/ocfs2-tools-ocfs2-tools-${pkgver}/"
	make DESTDIR=${pkgdir} install 
	mv ${pkgdir}/sbin/* ${pkgdir}/usr/bin/
	rmdir ${pkgdir}/sbin
}