AutoHotKey mute applications

MuteApps.ahk

#NoEnv ;// Recommended for new scripts
#Persistent ;// Recommended for new scripts
SendMode Input  ;// Recommended for new scripts
SetTitleMatchMode 2

; Window title of Volume Mixer
VolumeMixer = Lautstärkemixer
 
;// Set VolumeMute to only silence Media Center
^!M::
    ;Mute Apps
  ;Specify multiple apps like this "Hangouts Plugin; Mozilla Firefox"
    MuteApps("Hangouts Plugin")
return

MuteApps(apps)
{
    global VolumeMixer
	
    ;// Open mixer
    Run, sndvol
    WinWait, % VolumeMixer
		
    ;// Mute Apps
    loop, Parse, apps, ";", %A_Space%%A_Tab%
    {
        appName = %A_LoopField%		
        MuteApp(appName)
    }

    ;// Close mixer
    WinClose, % VolumeMixer
}
 
;// Volume Mixer must exist
MuteApp(appName)
{
    global VolumeMixer
	
    ;// Find X position & width of textblock with text matching our appName
    ControlGetPos, refX, , refW, , % appName, % VolumeMixer
    ;// Find button with left side within the width of the textblockµ
    x = -1
    while ( x != "")
    {
        ;// A_Index is current loop iteration→used to find id
        tbIDX := (A_Index * 2)
        ControlGetPos, x, , , , ToolbarWindow32%tbIDX%, % VolumeMixer
        diff := x - refX
        if (diff > 0 && diff < refW)
        {
            ;// msgbox diff: %diff% refX: %refX% tbIDX: %tbIDX% x: %x% A_Index: %A_Index%
            ControlClick, ToolbarWindow32%tbIDX%, % VolumeMixer
            break
        }
    }
}