claims skript

gistfile1.txt

# Main claim command (for now)
command /claim [<text>] [<number>,<number>]:
        description: Simplified claims, using WorldGuard Regions
        usage: /claim region_name region_size
        permission: skript.claims
        trigger:
                if arg 1 is not set:
                        message "Usage: /claim region_name [region_size]"
                        message " where region_size is <number>,<number>"
                        message "For example: /claim myname 30,50 will create a region named myname which is 30 by 50 in size, centered around where you are standing"
                        message "region_size is optional. If you do not give the size, then your claim will be 32 by 32"
                else:
                        set {_name} to arg 1
                        set {_loc} to player's location
                        set {_x} to ceil(x coord of {_loc})
                        set {_z} to ceil(z coord of {_loc})
                        if arg 2 is not set:
                                set {_x1} to 16
                        else:
                                set {_x1} to ceil(arg 2 / 2)
                        if arg 3 is not set:
                                set {_z1} to 16
                        else:
                                set {_z1} to ceil(arg 3 / 2)
                        set {_x_nw} to {_x} - {_x1}
                        set {_z_nw} to {_z} - {_z1}
                        set {_x_se} to {_x} + {_x1}
                        set {_z_se} to {_z} + {_z1}
                        if player is in "hub":
                                set {_y_nw} to 1
                        else:
                                set {_y_nw} to 0
                        set {_y_se} to 255
                        set {_pos_nw} to "%{_x_nw}%,%{_y_nw}%,%{_z_nw}%"
                        set {_pos_se} to "%{_x_se}%,%{_y_se}%,%{_z_se}%"
                        make command sender execute "//pos1 %{_pos_nw}%"
                        make command sender execute "//pos2 %{_pos_se}%"
                        make command sender execute "/rg claim %{_name}%"

# Add players to claim member list
command /addplayers <text> to <text>:
        description: Add list of players to a region's member list
        usage: /addplayers player_name(s) to claim_name
        permission: skript.claims
        aliases: /addplayer, /addmember, /addmembers
        trigger:
                make command sender execute "/rg addmember %arg 2% %arg 1%"

# Remove players from claim member list
command /delplayers <text> from <text>:
        description: Remove list of players from a region's member list
        usage: /delplayers player_name(s) from claim_name
        permission: skript.claims
        aliases: /delplayer, /delmember, /delmembers
        trigger:
                make command sender execute "/rg removemember %arg 2% %arg 1%"

# Set parent claim for claim
command /setparentclaim of <text> to <text>:
        description: Set the parent region of a region
        usage: /setparentclaim of claim_name to parent_claim_name
        permission: skript.claims
        aliases: /setparent
        trigger:
                make command sender execute "/rg setparent %arg 1% %arg 2%"

# Remove parent claim from claim
command /delparentclaim of <text>:
        description: Remove the parent region from a region
        usage: /delparentclaim of claim_name
        permission: skript.claims
        aliases: /delparent, /unsetparentclaim, /unsetparent
        trigger:
                make command sender execute "/rg setparent %arg 1%"

# Set priority for claim
command /setclaimpriority of <text> to <number>:
        description: Set the priority of a region
        usage: /setclaimpriority of claim_name to number
        permission: skript.claims
        aliases: /setpriority
        trigger:
                make command sender execute "/rg setpriority %arg 1% %arg 2%"