Simple script for downloading any version of AmongUs via DepotDownloader. Simply fill in your steam user ID, App manifest ID as well as the installation path of DepotDownloader, and run the script.

download_AmongUs.bat

@echo off
@echo Among Us Downloader v1.0.1 by UpcraftLP
@echo check https://gist.github.com/UpcraftLP/c5972d37474450f56ff8069d96f4b8b6 for updates
@echo(

:setup
:: https://github.com/SteamRE/DepotDownloader
SET "DEPOTDOWNLOADER=depotdownloader/depotdownloader.bat"
SET "STEAM_USER=INVALID"

SET APP_ID=945360
SET DEPOT_ID=945361
SET MANIFEST_ID=INVALID


SET "INSTALL_DIR=AmongUs_%MANIFEST_ID%"

:main
@echo Checking Manifest ID %MANIFEST_ID%...
CALL :normalizePath INSTALL_DIR,"%INSTALL_DIR%"
SET success=0
:while
IF %success% == 0 (
    CALL :checkExisting success
    goto :while
)
CALL :checkEnv

@echo(
@echo(
@echo Done. Press any key to exit.
pause > nul

:: ===== Functions =====
:checkEnv
    IF NOT "%AmongUs%" == "%INSTALL_DIR%" (
        @echo setting global install dir variable...
        @setx AmongUs "%INSTALL_DIR%"
        refreshenv
    )
    EXIT /B

:checkExisting
    @echo checking existing files
    IF EXIST "%INSTALL_DIR%/Among Us.exe" (
        @echo Installation verified.
        CALL :checkSteamAppId %~1
    ) else (
        CALL :download %~1
    )
    EXIT /B
    

:checkSteamAppId
    IF NOT EXIST "%INSTALL_DIR%/steam_appid.txt" (
        @echo creating Steam APP Info file...
        @echo %APP_ID% > "%INSTALL_DIR%/steam_appid.txt"
        SET %~1=0
    ) else (
        @echo App info verified.
        SET %~1=1
    )
    EXIT /B

:download
    @echo downloading Among Us...
    CALL "%DEPOTDOWNLOADER%" -app %APP_ID% -depot %DEPOT_ID% -manifest %MANIFEST_ID% -user "%STEAM_USER%" -remember-password -dir "%INSTALL_DIR%"
    SET %~1=0
    EXIT /B

:normalizePath
  SET "%1=%~f2"
  EXIT /B