Way to Heaven (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Way to Heaven
author Valentina Silveira
homepage www.lexaloffle.com

background_color Black
text_color LightRed

flickscreen 16x10

========
OBJECTS
========

Exit
Black
.....
.....
.....
.....
.....

Player1
Black
.000.
.000.
00000
.000.
.0.0.

PlayerJump
Black
.000.
00000
.000.
.000.
0...0

PlayerJumpLeft 
Black
.000.
0000.
.000.
.000.
..0.0

PlayerJumpRight 
Black
.000.
.0000
.000.
.000.
0.0..

Blood 
orange yellow
10101
01110
11011
01110
10101

Blood2 
orange yellow
01010
10101
01010
10101
01010


PlayerDead
Red Black
10001
10001
00000
10001
10101

Temp
black

OutdoorBackground 
lightred

IndoorBackground 
white lightgray 
11011
11011
11011
11011
11011

Door
DarkBlue White Blue
00200
10201
00200
10201
00200

Wall
red lightred orange
22222
20220
00020
00000
00000

SolidWall 
#FF0000 #992222
00000
00001
00111
01111
11111

Lava
orange yellow
10001
01110
11011
01110
10001

Key
Blue
.000.
.0.0.
.000.
..0..
.00..

Speed1
DarkGray
..0..
.000.
00.00
.000.
..0..


Speed2
DarkGray
.....
..0..
.0.0.
..0..
.....

WingsAndCrown
white yellow
.111.
.....
0...0
00.00
.000.


(Cloud
white

Sky
blue 

Grass
lightgreen green
11111
01111
11101
11111
10111

Sea
blue lightblue
11111
01111
11101
11111
10111

Checkpoint
brown red
.0...
.11..
.111.
.0...
.0...

Checkpoint1
brown yellow
.0...
.11..
.111.
.0...
.0...


Pinchos
grey black lightgray
0...0
.010.
01210
.010.
0...0)

=======
LEGEND
=======

Background = OutdoorBackground or IndoorBackground
Player = Player1 or PlayerJump or PlayerJumpLeft or PlayerJumpRight or PlayerDead
InGamePlayer = Player1 or PlayerJump
FlyingPlayer = PlayerJumpLeft or PlayerJumpRight
Obstacle = wall or Lava or SolidWall or Door
ObstacleNoLava = wall or SolidWall or Door

p = Player1
. = OutdoorBackground
, = IndoorBackground
# = wall
w = SolidWall
d = Door
x = exit
l = Lava
k = Key and outdoorBackground

=========
SOUNDS
=========

startgame 82028300
endgame 85056702

(collect key 9894100)
sfx0 53720504 (jump up)
sfx1 14370308 (bomb)
sfx2 41983504 (jetpack)
sfx3 86827507 (fall)
sfx4 56160703 (door)
sfx5 98568902 (blockpush)
sfx6 77665108 (collapse)

================
COLLISIONLAYERS
================

Background
Speed1, Speed2, Exit
Player, Wall, SolidWall, temp, playerjumpleft, playerjumpright, lava, Key, WingsAndCrown, Door
blood, blood2

======
RULES
======

right [ moving Playerdead] -> [PlayerDead]

[> IngamePlayer | lava ] -> [ > PlayerDead | blood ] sfx1
Vertical [ Player1 | lava ] -> [ playerdead | blood2 ] sfx1
Horizontal [flyingplayer | lava ] -> [ playerdead | blood2 ] sfx1

Horizontal [> Player1 | Key] [Door] -> [> Player1 | Key] []
Horizontal [> Player1 | Key]-> [> Player1 | ] sfx4

Horizontal [> Player1 | WingsAndCrown] [Door] -> [> Player1 | WingsAndCrown] []
Horizontal [> Player1 | WingsAndCrown]-> [> Player1 | ] sfx6



UP [Up Player1 | No Obstacle | No Obstacle] -> [ | | PlayerJump  ] sfx0
UP [Up Player1 | No Obstacle] -> [ | PlayerJump ] sfx0


right [right PlayerJump] -> [PlayerJumpRight]
left [left PlayerJump] -> [PlayerJumpLeft]
up [up PlayerJump] -> [PlayerJump]
down [down PlayerJump] -> [PlayerJump]

down [Speed2] -> []
down [Speed1] -> [Speed2]

random right [ PlayerJumpRight | No Obstacle] -> [ Speed1 | PlayerJumpRight] again sfx2
horizontal [ PlayerJumpRight | ObstacleNoLava] -> [ Player1 | ObstacleNoLava]
down [ PlayerJumpRight | ObstacleNoLava] -> [ Player1 | ObstacleNoLava]

random left [ PlayerJumpLeft | No Obstacle] -> [Speed1 | PlayerJumpLeft] again sfx2
horizontal [ PlayerJumpLeft | ObstacleNoLava] -> [ Player1 | ObstacleNoLava]
down [ PlayerJumpLeft | ObstacleNoLava] -> [ Player1 | ObstacleNoLava]

horizontal [> Player1 | Wall] -> [> Player1 | > wall] sfx5
horizontal [> Wall | Wall] -> [> Wall | > wall]
horizontal [> Wall | lava] -> [> Wall | > lava]

down [stationary wall] -> [ down wall] again
down [stationary lava] -> [ down lava] again

[blood | no blood ] -> [blood | blood2] again
[blood2 | no blood ] -> [blood2 | blood] again

late down [  Player1 | No Obstacle ] -> [ Speed1 |  temp] again sfx3
late down [temp] -> [player1]

==============
WINCONDITIONS
==============

No WingsAndCrown
All Player on Exit 

=======
LEVELS
=======

Message Level 1

wwwwwwwwwwwwwwwwwwwwwwwwww
w......wwwwk..wwwwwww....w
w........www.............w
w.ww......www...........ww
w..w...............w.....w
ww.ww.........llllwwlw...w
ww.p.w....wwwwwwwwwwl....w
wwww....lwwwxd.....ww..www
wwwwlllwlwwwxd.........www
wwwwwwwwwwwwwwwwwwwwwwwwww
 
Message Level 2