Čia rankenėlė tai lemputei šalia spausdintuvo. Padariau kad viduje būtų apytuščia, su susiaurėjimais galuose; skylutes jungikliui ir magnetukui; taip pat padariau pussferės ir kūbiuko išėmimą lemputės galiukui.

printer lamp handle.scad

$fn=60;

module lampHandle() {
    difference() {
        cylinder(d=35, h = 100);
        translate([0,0,84]){
            bulbSpace();
        }
        holoInside();
        buttonHole();
        magnetHole();
    }
}

module bulbSpace() {
    // square bottom
    translate([-5.5,-8.5,0]){ 
        cube([11, 17, 13]);
    }
    
    // semi sphere top
    translate([0,0,35]){
        difference(){
            sphere(d=50);
            translate([-25, -25, -25+7]){
                cube(50);
            }
        }
    }
}

module buttonHole() {
    translate([-7.5,0,50]) {
        cube([15,20,20]);
    }
}

module holoInside() {
    cylinder(d=10, h=100);
    translate([0,0,5]){
        cylinder(d1=10,d2=25,h=20);
    }
    translate([0,0,25]){
        cylinder(d=25,h=45);
    }
    translate([0,0,65]){
        cylinder(d1=25,d2=10,h=20);
    }
}

module magnetHole() {
    translate([0, -17.5, 70]) {
        rotate([0,90,90]) {
            cylinder(d=11,h=3);
        }
    }
}

lampHandle();