SICP_ex2_56.scm

;; -*- mode:scheme; coding:utf-8 -*-
;; 2.3.2 Derivation
(define (deriv exp var)
  (cond ((number? exp) 0)
	((variable? exp) 
	 (if (same-variable? exp var) 1 0))
	((sum? exp)
	 (make-sum (deriv (addend exp) var)
		   (deriv (augend exp) var)))
	((product? exp)
	 (make-sum
	  (make-product (multiplier exp)
			(deriv (multiplicand exp) var))
	  (make-product (deriv (multiplier exp) var)
			(multiplicand exp))))
	(else
	 (error "unknown expression type -- DERIV" exp))))

(define (variable? x) (symbol? x))

(define (same-variable? v1 v2)
  (and (variable? v1) (variable? v2) (eq? v1 v2)))

(define (sum? x)
  (and (pair? x) (eq? (car x) '+)))

(define (addend s) (cadr s))
(define (augend s) (caddr s))

(define (product? x)
  (and (pair? x) (eq? (car x) '*)))

(define (multiplier p) (cadr p))
(define (multiplicand p) (caddr p))

(define (make-sum a1 a2)
  (cond ((=number? a1 0) a2)
	((=number? a2 0) a1)
	((and (number? a1) (number? a2)) (+ a1 a2))
	(else (list '+ a1 a2))))

(define (=number? exp num)
  (and (number? exp) (= exp num)))

(define (make-product m1 m2)
  (cond ((or (=number? m1 0) (=number? m2 0)) 0)
	((=number? m1 1) m2)
	((=number? m2 1) m1)
	((and (number? m1) (number? m2)) (* m1 m2))
	(else (list '* m1 m2))))

;; ex 2.56
(define (exponentiation? x)
  (and (pair? x) (eq? (car x) '**)))

(define (base e) (cadr e))
(define (exponent e) (caddr e))

(define (make-exponentiation e1 e2)
  (cond ((=number? e2 0) 1)
	((or (=number? e1 0) (=number? e1 1) (=number? e2 1)) e1)
	(else (list '** e1 e2))))

(define (ex-deriv exp var)
  (cond ((number? exp) 0)
	((variable? exp)
	 (if (same-variable? exp var) 1 0))
	((sum? exp)
	 (make-sum (ex-deriv (addend exp) var)
		   (ex-deriv (augend exp) var)))
	((product? exp)
	 (let ((u (multiplier exp))
	       (v (multiplicand exp)))
	   (make-sum
	    (make-product u (ex-deriv v var))
	    (make-product (ex-deriv u var) v))))
	((exponentiation? exp)
	 (let ((u (base exp))
	       (n (exponent exp))
	       (dec (lambda (n) (if (number? n) (- n 1) (list '- n 1)))))
	   (make-product
	    (make-product n
			  (make-exponentiation u (dec n)))
	    (ex-deriv u var))))
	(else 
	 (error "unknown expression type -- DERIV" exp))))