broadcom-wl-dkms for linux-3.18

broadcom-sta-6.30.223.248-linux-3.18-null-pointer-crash.patch

diff -urN a/src/wl/sys/wl_linux.c b/src/wl/sys/wl_linux.c
--- a/src/wl/sys/wl_linux.c	2015-01-06 12:33:42.981659618 +0100
+++ b/src/wl/sys/wl_linux.c	2015-01-06 12:34:05.647395418 +0100
@@ -2157,8 +2157,8 @@
 	wlif = WL_DEV_IF(dev);
 	wl = WL_INFO(dev);
 
+	skb->prev = NULL;
 	if (WL_ALL_PASSIVE_ENAB(wl) || (WL_RTR() && WL_CONFIG_SMP())) {
-		skb->prev = NULL;
 
 		TXQ_LOCK(wl);
 

PKGBUILD

# Maintainer: Frank Vanderham <twelve.eighty (at) gmail.>
# Contributor: Hugo Osvaldo Barrera <hugo@barrera.io>
pkgname=broadcom-wl-dkms
_pkgname=broadcom-wl
pkgver=6.30.223.248
pkgrel=5
pkgdesc="Broadcom 802.11 Linux STA wireless driver"
url='http://www.broadcom.com/support/802.11/linux_sta.php'
arch=('i686' 'x86_64')
license=('custom')
depends=('dkms' 'linux-headers')
install=broadcom-wl-dkms.install
conflicts=('broadcom-wl')
[[ $CARCH = x86_64 ]] && _arch=_64 || _arch=
source=("http://www.broadcom.com/docs/linux_sta/hybrid-v35${_arch}-nodebug-pcoem-${pkgver//./_}.tar.gz"
	'broadcom-wl-dkms.conf'
	'dkms.conf'
	'license.patch'
	'linux-recent.patch'
	'gcc.patch'
        'broadcom-sta-6.30.223.248-linux-3.18-null-pointer-crash.patch')
sha256sums=('b196543a429c22b2b8d75d0c1d9e6e7ff212c3d3e1f42cc6fd9e4858f01da1ad'
	'b97bc588420d1542f73279e71975ccb5d81d75e534e7b5717e01d6e6adf6a283'
	'4e719f9c8468f7c802bb0e52939f2680abb1287d3817d91252958f0ae82f983b'
	'2f70be509aac743bec2cc3a19377be311a60a1c0e4a70ddd63ea89fae5df08ac'
	'ebbcac3a37787c86fa8515046d81d1d0bb2669215703d6fa2800233029bf3d63'
	'b07ce80f2e079cce08c8ec006dda091f6f73f158c8a62df5bac2fbabb6989849'
        'a737a9be126a1cadc356b5bf023c7cbdbbe1723c53268e34f1bcece35edf8295')
[[ $CARCH = x86_64 ]] && sha256sums[0]='3d994cc6c05198f4b6f07a213ac1e9e45a45159899e6c4a7feca5e6c395c3022'

backup=('etc/modprobe.d/broadcom-wl-dkms.conf')

build() {
	cd "${srcdir}"

	patch -p1 -i linux-recent.patch
	patch -p1 -i license.patch
	patch -p1 -i gcc.patch
        patch -p1 -i broadcom-sta-6.30.223.248-linux-3.18-null-pointer-crash.patch

	sed -e "/BRCM_WLAN_IFNAME/s:eth:wlan:" \
		-i src/wl/sys/wl_linux.c

	# delete files not needed for packaging
	rm hybrid-v35${_arch}-nodebug-pcoem-${pkgver//./_}.tar.gz
}

package() {
	cd "${srcdir}"
	
	mkdir -p ${pkgdir}/usr/src/${_pkgname}-${pkgver}

	cp -RL * ${pkgdir}/usr/src/${_pkgname}-${pkgver}
	install -D -m 644 lib/LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -D -m 644 broadcom-wl-dkms.conf "${pkgdir}"/etc/modprobe.d/broadcom-wl-dkms.conf
}