A package for Feilian on Nix OS

corplink.nix

{ dpkg, pkgs, fetchurl, lib, buildFHSUserEnv, makeDesktopItem, systemd, ...}:
let
  version = "2.0.9";

  feilian-unwrapped = pkgs.stdenv.mkDerivation rec {
    pname = "feilian-unwrapped";
    inherit version;

    src = fetchurl {
      url = "https://oss-s3.ifeilian.com/linux/FeiLian_Linux_v${version}_r615_97b98b.deb";
      sha256 = "1zgbazvn5wdf7cghy1lq0fmq3q1j14j77wdcp5px7fw94i5187qn";
    };
    nativeBuildInputs = [ dpkg ];

    unpackPhase = ''
      mkdir pkg
      dpkg --fsys-tarfile $src | tar --extract -C pkg
      sourceRoot=pkg
    '';

    installPhase = ''
      runHook preInstall

      mkdir -p $out
      cp -r opt $out/opt

      mkdir -p $out/share/pixmaps
      cp usr/share/icons/corplink.png "$out/share/pixmaps/corplink.png"

      ln -s /run/corplink/rpc.conf "$out/opt/Corplink/rpc.conf"
      ln -s /run/corplink/device.conf "$out/opt/Corplink/device.conf"
      ln -s /run/corplink/logs "$out/opt/Corplink/logs"

      runHook postInstall
    '';

    doInstallCheck = true;

    meta = with lib; {
      homepage = "https://www.volcengine.com/products/feilian";
      platforms = platforms.linux;
    };
  };

  feilian-env = buildFHSUserEnv {
    name = "feilian-env";

    targetPkgs = pkgs: with pkgs; [
      feilian-unwrapped
      xlibs.libX11
      xlibs.libXext
      xlibs.libXdamage
      xlibs.libxshmfence
      xlibs.libXcomposite
      xlibs.libXfixes
      xlibs.libXrandr
      xlibs.libxcb
      libglvnd
      libGL_driver
      alsa-lib
      glib
      nss
      libxkbcommon
      libdrm
      cairo
      gtk3
      pulseaudio
      pciutils
      libva-full
      libudev
      xdg-utils
      nspr
      atk
      cups
      dbus_daemon
      gnome2.pango
      gdk-pixbuf
      expat
      at_spi2_atk
      at_spi2_core
      iproute2
      
      bash
      networkmanager
    ];
    runScript = "${pkgs.bash}/bin/bash";

    meta = with lib; {
      homepage = "https://www.volcengine.com/products/feilian";
      platforms = platforms.linux;
    };
  };

  desktopItem = makeDesktopItem {
    name = "Feilian";
    exec = "${feilian-env}/bin/feilian-env -c /opt/Corplink/corplink";
    genericName = "veCorpLink";
    icon = "corplink";
    desktopName = "Corplink";
  };
  createRunDirectory = pkgs.writeScript "corplink-create-run" ''
    #!${pkgs.runtimeShell}
    ${pkgs.coreutils}/bin/mkdir -p /run/corplink/logs
    ${pkgs.coreutils}/bin/touch /run/corplink/rpc.conf
    ${pkgs.coreutils}/bin/touch /run/corplink/device.conf
    ${pkgs.coreutils}/bin/echo "" > /run/corplink/rpc.conf
  '';
  cleanRunDirectory = pkgs.writeScript "corplink-remove-run" ''
    #!${pkgs.runtimeShell}
    ${pkgs.coreutils}/bin/rm -rf /run/corplink
  '';
  feilianService = pkgs.writeText "corplink.service" ''
    [Unit]
    Description=Corplink Service
    After=network.target

    [Service]
    Environment=CORPLINK_RPC_CONF=/opt/Corplink/rpc.conf
    ExecStartPre=${createRunDirectory}
    ExecStart=${feilian-env}/bin/feilian-env -c '/opt/Corplink/corplink-service'
    ExecStopPost=${cleanRunDirectory}
    Type=simple
    Restart=always
    RestartSec=3s

    [Install]
    WantedBy=multi-user.target
    Alias=corplink.service
  '';
in
pkgs.stdenv.mkDerivation rec {
  pname = "feilian";
  version = "2.0.9";

  unpackPhase = "true";

  installPhase = ''
    runHook preInstall

    mkdir -p $out/share/pixmaps
    ln -s ${feilian-unwrapped}/share/pixmaps/corplink.png "$out/share/pixmaps/corplink.png"

    mkdir -p $out/share/applications
    ln -s ${desktopItem}/share/applications/* $out/share/applications

    mkdir -p $out/lib/systemd/system
    cp ${feilianService} $out/lib/systemd/system/corplink.service

    runHook postInstall
  '';
}