15-puzzle @ http://yal.cc/hx/ldls/

15.ldm

объявить поле(4)(4)(4) % поле с номерами пятнашек
объявить стр(2), стл(2) % строка, столбец
объявить симв(128) % массив символов
объявить а(8), б(8), к(8) % временные переменные
симв = #" 123456789ABCDEF"
поле(0)(0)= 0; поле(0)(1)= 1; поле(0)(2)= 2; поле(0)(3)= 3;
поле(1)(0)= 4; поле(1)(1)= 5; поле(1)(2)= 6; поле(1)(3)= 7;
поле(2)(0)= 8; поле(2)(1)= 9; поле(2)(2)=10; поле(2)(3)=11;
поле(3)(0)=12; поле(3)(1)=13; поле(3)(2)=14; поле(3)(3)=15;
игра:
	% вывод:
	печать "\#z╓────╖"
	а = 0; б = 0; к = 7
	вывод:
		если а(1:0) = #00 печать "║"
		б(6:3) = поле(а(3:2))(а(1:0))
		к(6:3) = б(6:3)
		печать симв(к:б):"\b%c" % (код символа)
		если а(1:0) = #11 печать "\b║"
		а + 1
		если а < 16 идти_к вывод
	печать "╙────╜"
	% ввод
	ввести а:"%к" % (код клавиши)
	если а <> 37 идти_к ввод1 % влево
		если стл == 0 идти_к ввод4
		к = стл; стл - 1
		поле(стр)(к) <-> поле(стр)(стл)
		идти_к ввод4
	ввод1: если а <> 39 идти_к ввод2 % вправо
		если стл == 3 идти_к ввод4
		к = стл; стл + 1
		поле(стр)(к) <-> поле(стр)(стл)
		идти_к ввод4
	ввод2: если а <> 38 идти_к ввод3 % вверх
		если стр == 0 идти_к ввод4
		к = стр; стр - 1
		поле(к)(стл) <-> поле(стр)(стл)
		идти_к ввод4
	ввод3: если а <> 40 идти_к ввод4 % вниз
		если стр == 3 идти_к ввод4
		к = стр; стр + 1
		поле(к)(стл) <-> поле(стр)(стл)
		идти_к ввод4
	ввод4: идти_к игра