default.nix

{ stdenv, fetchFromGitHub, python3, gettext, gobjectIntrospection, wrapGAppsHook
, gtk3, keybinder3, libnotify, libutempter, vte }:

let
  version = "3.0.5";
 in python3.pkgs.buildPythonApplication rec {
  name = "guake-${version}";
  format = "other";

  src = fetchFromGitHub {
    owner = "Guake";
    repo = "guake";
    rev = version;
    sha256 = "02gx17z9bsn3my3v54w0yjjr0g43lgpd2aw87377p39hjw7ii29k";
  };

  nativeBuildInputs = [ gettext gobjectIntrospection wrapGAppsHook python3.pkgs.pip glibcLocales ];

  buildInputs = [ gtk3 keybinder3 libnotify python3 vte ];

  propagatedBuildInputs = with python3.pkgs; [ dbus-python pbr pycairo pygobject3 ];

  LC_ALL = "en_US.UTF-8";

  PBR_VERSION = version; # pbr needs either .git directory, sdist, or env var

  makeFlags = [
    "PREFIX=$(out)"
  ];

  patches = [
    ./fix-paths.patch
  ];

  postPatch = ''
    sed -i "s|IMAGE_DIR = .*|IMAGE_DIR = '$out/share/pixmaps/guake'|
      s|GLADE_DIR = .*|GLADE_DIR = '$out/share/guake'|
      s|SCHEMA_DIR = .*|SCHEMA_DIR = '$out/share/gsettings-schemas/${name}/glib-2.0/schemas'|
      s|LOCALE_DIR = .*|LOCALE_DIR = '$out/share/locale'|" guake/globals.py
  '';

  postInstall = ''
    install -Dm644 -t "$out/share/guake/" guake/data/*.glade
    install -Dm644 -t "$out/share/pixmaps/guake/" guake/data/pixmaps/*.png
  '';

  postFixup = ''
    gappsWrapperArgs+=(--prefix LD_LIBRARY_PATH : "${stdenv.lib.makeLibraryPath [ libutempter ]}")
  '';

  meta = with stdenv.lib; {
    description = "Drop-down terminal for GNOME";
    homepage = http://guake-project.org;
    license = licenses.gpl2;
    platforms = platforms.linux;
    maintainers = [ maintainers.msteen ];
  };
}