Simple Groovy Sftp Server

SftpServer.groovy

@Grab(group='org.apache.sshd', module='sshd-core', version='0.13.0')

import org.apache.sshd.SshServer
import org.apache.sshd.server.PasswordAuthenticator
import org.apache.sshd.server.command.ScpCommandFactory
import org.apache.sshd.server.keyprovider.SimpleGeneratorHostKeyProvider
import org.apache.sshd.server.session.ServerSession
import org.apache.sshd.server.sftp.SftpSubsystem
import org.apache.sshd.server.shell.ProcessShellFactory


int sftpPort = 2200

SshServer sshd = SshServer.setUpDefaultServer()
sshd.setPort(sftpPort)
sshd.setKeyPairProvider(new SimpleGeneratorHostKeyProvider("hostkey.ser"))
sshd.setPasswordAuthenticator(
    [
        authenticate: { String username, String password, ServerSession session ->
            return username.equals('anonymous') || (username && username.equals(password))
        }
    ] as PasswordAuthenticator
)
sshd.setShellFactory(new ProcessShellFactory(["/bin/sh", "-i", "-l"] as String[]))
sshd.setSubsystemFactories([new SftpSubsystem.Factory()])
sshd.setCommandFactory(new ScpCommandFactory())
sshd.start()

println "listening..."