arc-kde-git PKGBUILD proposal

PKGBUILD

pkgbase=arc-kde-git
pkgname=("${pkgbase}" {'konsole-colorscheme-arc','konversation-theme-arc','kvantum-theme-arc','yakuake-skin-arc'}'-git')
pkgver=20170908.r12.g33b91d5
pkgrel=1
epoch=2
arch=('any')
url="https://github.com/PapirusDevelopmentTeam/${pkgbase%-git}"
license=('GPL3')
makedepends=('git')
options=('!strip')
source=("${pkgbase}::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
    cd "${pkgbase}"
    git describe --long --tags | sed 's/-/.r/;s/-/./'
}

prepare() {
    cd "${pkgbase}"
    rm -r konversation/themes/papirus{,-dark}/src
    mv yakuake/{kns_,}skins
}

_install() {
    cd "${pkgbase}"
    install -d "${pkgdir}"/usr/share
    cp -r "$@" "${pkgdir}"/usr/share
}

package_arc-kde-git() {
    pkgdesc="Arc theme for KDE Plasma 5"
    depends=('plasma-workspace')
    optdepends=("arc-gtk-theme: Arc theme for GTK"
                "arc-firefox-theme: Arc theme for Firefox")
    provides=("${pkgbase%-git}")
    conflicts=("${pkgbase%-git}")
    install=${pkgbase}.install

    _install aurorae color-schemes plasma wallpapers
}

package_konsole-colorscheme-arc-git() {
    pkgdesc="Arc theme for Konsole"
    depends=('konsole')
    provides=('konsole-colorscheme-arc')
    conflicts=("${provides[0]}" "${pkgbase}<2:")

    _install konsole
}

package_konversation-theme-arc-git() {
    pkgdesc="Arc theme for Konversation"
    depends=('konversation')
    provides=('konversation-theme-arc')
    conflicts=("${provides[0]}" "${pkgbase}<2:")

    _install konversation
}

package_kvantum-theme-arc-git() {
    pkgdesc="Arc theme for Kvantum"
    depends=('kvantum-qt5')
    provides=('kvantum-theme-arc')
    conflicts=("${provides[0]}" "${pkgbase}<2:")

    _install Kvantum
}

package_yakuake-skin-arc-git() {
    pkgdesc="Arc theme for Yakuake"
    depends=('yakuake')
    provides=('yakuake-skin-arc')
    conflicts=("${provides[0]}" "${pkgbase}<2:")

    _install yakuake
}