Example tests for Brad

CaptureStdOutTest.cfc

import test.BaseSpec

component extends=BaseSpec {

	function run() {
		describe("Trying to capture stdout", () => {

			var fixtures = {}

			aroundEach((spec) => {
				try {
					fixtures.outFilePath = getTempDirectory() & createUuid() & ".out"
					fixtures.system = createObject("java", "java.lang.System")

					var originalOut = fixtures.system.out
					var fos = createObject("java", "java.io.FileOutputStream").init(fixtures.outFilePath)
					var ps = createObject("java", "java.io.PrintStream").init(fos, true)

					fixtures.system.setOut(ps)

					spec.body()
				} finally {
					fixtures.system.setOut(originalOut)
				}
			})

			it("captures stuff Java puts there", () => {
				var testString = "find this (Java)"
				fixtures.system.out.println(testString)

				var contents = fileRead(fixtures.outFilePath)
				expect(contents).toBe(testString & chr(10))
			})

			it("doesn't capture stuff Lucee puts there", () => {
				systemOutput("find this (Lucee)")

				var contents = fileRead(fixtures.outFilePath)

				expect(contents).toBeEmpty() // except I wish this *wasn't* the case
			})
		})
	}
}