hex_using_math.s

        ; Display the the byte in A as two hex digits at the current
        ; screen position
        ;
        ; Inputs:
        ; A     byte to display
        ;
        ; Destroys A
display_hex:
        pha
        lsr
        lsr
        lsr
        lsr
        ora #$30 ; screen code for 0
        cmp #58
        bcc out3
        sbc #57
out3:
        jsr scr_output

        pla
        and #$0f
        ora #$30 ; screen code for 0
        cmp #58
        bcc out4
        sbc #57
out4:
        jmp scr_output ; implicit rts

hex_using_table.s

        ; Display the the byte in A as two hex digits at the current
        ; screen position
        ;
        ; Inputs:
        ; A     byte to display
        ;
        ; Destroys A, X
display_hex:
        pha
        lsr
        lsr
        lsr
        lsr
        tax
        lda hex_digits,x
        jsr scr_output

        pla
        and #$0f
        tax
        lda hex_digits,x
        jmp scr_output ; implicit rts

hex_digits:     !scr "0123456789abcdef"