PKGBUILD for ananicy-cpp

ananicy.conf

check_freq = 60
loglevel = info
cgroup_realtime_workaround = true
rule_load = true
type_load = true
apply_oom_score_adj = true
apply_ionice = true
cgroup_load = true
apply_sched = true
apply_nice = true

PKGBUILD

pkgname=ananicy-cpp
_pkgver=1.0.0-rc5
pkgver=${_pkgver//-/.}
pkgrel=2
pkgdesc="Ananicy rewritten in C++ for much lower CPU and memory usage"
url="https://gitlab.com/ananicy-cpp/ananicy-cpp/"
license=(GPL3)
source=("https://gitlab.com/ananicy-cpp/${pkgname}/-/archive/v${_pkgver}/${pkgname}-v${_pkgver}.tar.gz"
        "ananicy.conf")
sha256sums=('90f4b7ddb49246db2329cfdf5727c1f2caa22285dcbc5b7cdaba6bcf2c946676'
            'fca9b07be70ea2e203f1c70dfde7676dfc55edb1174eaaa3b53e88bc19de3420')
arch=(x86_64 i686 armv7h)
depends=(fmt spdlog systemd-libs)
makedepends=(cmake nlohmann-json systemd)
optdepends=('ananicy-rules-git: community rules')
conflicts=('ananicy')
backup=('etc/ananicy.d/ananicy.conf')

build() {
    cmake \
        -B "build" \
        -S "${pkgname}-v${_pkgver}" \
		-DCMAKE_BUILD_TYPE=None \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DUSE_EXTERNAL_SPDLOG=ON \
		-DUSE_EXTERNAL_JSON=ON \
		-DUSE_EXTERNAL_FMTLIB=ON \
        -DENABLE_SYSTEMD=ON \
		-DVERSION=${_pkgver} \
        -Wno-dev
    cmake --build build
}

package() {
    DESTDIR="${pkgdir}" cmake --install build
    install -D -m0644 "${srcdir}/ananicy.conf" "${pkgdir}/etc/ananicy.d/ananicy.conf"
}