Merge multilple shell.nix files using mkShell

env1-shell.nix

{ pkgs ? import <nixpkgs> {} }:

pkgs.mkShell {
  buildInputs = [
    pkgs.hello
  ];

  shellHook = ''
    echo env1
  '';
}

env2-shell.nix

{ pkgs ? import <nixpkgs> {} }:

pkgs.mkShell {
  buildInputs = [
    pkgs.vim
  ];

  shellHook = ''
    echo env2
  '';

}

shell.nix

let
  pkgs = import <nixpkgs> {};
  lib = pkgs.lib;

  env1 = import ./env1-shell.nix { inherit pkgs; };
  env2 = import ./env2-shell.nix { inherit pkgs; };

  mergeEnvs = envs: pkgs.mkShell (builtins.foldl' (a: v: {
    buildInputs = a.buildInputs ++ v.buildInputs;
    nativeBuildInputs = a.nativeBuildInputs ++ v.nativeBuildInputs;
    propagatedBuildInputs = a.propagatedBuildInputs ++ v.propagatedBuildInputs;
    propagatedNativeBuildInputs = a.propagatedNativeBuildInputs ++ v.propagatedNativeBuildInputs;
    shellHook = a.shellHook + "\n" + v.shellHook;
  }) (pkgs.mkShell {}) envs);

in mergeEnvs [ env1 env2 ]

if you only care about inputs and shellHook

pkgs.mkShell {
  name = "my shell";
  inputsFrom = [ env1 env2 ];
  buildInputs = with pkgs; [ foo ];
};