Skip to content

Instantly share code, notes, and snippets.

@agraef
Last active Dec 3, 2020
Embed
What would you like to do?
More maintainer-friendly version of the vuescan PKGBUILD (https://aur.archlinux.org/packages/vuescan-bin)
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: ninian <mcfadzean.org.uk ta linux>
pkgname=vuescan-bin
pkgver=9.7.29
pkgrel=1
pkgdesc="A powerful proprietary scanning tool developed by Hamrick Software"
arch=(i686 x86_64 armv6h aarch64)
url="https://www.hamrick.com/"
license=('custom')
depends=(gtk2 libsm libusb-compat)
makedepends=('wget')
options=(!strip) # required to accept registration details
source=('LICENSE' 'vuescan.sh' 'vuescan.desktop')
source_i686=("$pkgname-x32-$(date +%F-%H-%M).tgz::https://www.hamrick.com/files/vuex3297.tgz")
source_x86_64=("$pkgname-x64-$(date +%F-%H-%M).tgz::https://www.hamrick.com/files/vuex6497.tgz")
source_aarch64=("$pkgname-arm64-$(date +%F-%H-%M).tgz::https://www.hamrick.com/files/vuea6497.tgz")
source_armv6h=("$pkgname-arm32-$(date +%F-%H-%M).tgz::https://www.hamrick.com/files/vuea3297.tgz")
sha256sums=('6dbe377ee83561ef0b12fec64dadb5c81beb1f9ee274284c09184366bad1a6d6'
'a536feed770fa379b3ea0147721a74ad5f19db493c098eec570d363b70f0847d'
'211d104dc5e23530298d25ef0ae3760863b3f97113a1e80b228c866f576381ef')
sha256sums_i686=('SKIP')
sha256sums_x86_64=('SKIP')
sha256sums_armv6h=('SKIP')
sha256sums_aarch64=('SKIP')
pkgver() {
printf "%s" "$(wget -qO- https://www.hamrick.com/alternate-versions.html | egrep '<a href.*[0-9]+\.[0-9]+' | head -1 | sed -E 's/^.*([0-9]+[.][0-9]+[.][0-9]+).*$/\1/')"
}
package() {
install -d "$pkgdir/opt/${pkgname%-bin}"
cp -a "$srcdir/VueScan"/* "$pkgdir/opt/${pkgname%-bin}/"
install -Dm755 "$srcdir/${pkgname%-bin}.sh" "$pkgdir/usr/bin/${pkgname%-bin}"
install -Dm644 "$srcdir/${pkgname%-bin}.desktop" "$pkgdir/usr/share/applications/${pkgname%-bin}.desktop"
install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/${pkgname%-bin}/LICENSE"
}
@Greg-KB2QQM
Copy link

Greg-KB2QQM commented Dec 3, 2020

Thanks for this the Sha256sums 'skip' helped me out... cheers.

@agraef
Copy link
Author

agraef commented Dec 3, 2020

@Greg-KB2QQM, you're welcome. :) For whatever reason, FabioLolix didn't take up my suggestion, so I should probably upload this PKGBUILD as a separate package to the AUR some time.

Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment