SuperDirt mid/side mixer module

1_midside.scd

(
SynthDef("pulu-midside2", { |out, mid=1, side=1, mspan=0.5|
 	var sig, left, right, midsig, sidesig;
	sig = In.ar(out, 2);
	left = sig[0];
	right = sig[1];
	midsig = (left + right)*0.5*mid;
	sidesig = (right - left)*0.5*side;
	sig = [midsig - sidesig, midsig + sidesig];
	sig = DirtPan.ar(sig, 2, mspan.linlin(0, 1, -1, 1));
	ReplaceOut.ar(out, sig);
}).add;

~dirt.addModule('pulu-midside', { |dirtEvent|
	dirtEvent.sendSynth('pulu-midside' ++ ~dirt.numChannels, ~argNames);
}, { ~mid.notNil || ~side.notNil || ~mspan.notNil });

~dirt.orderModules(['sound', 'pulu-midside']);
)

2_example.tidal

-- here's a synth with a wide stereo field
d1 $ n "<~ [0,3,6]>*8" # s "superprimes"

-- make it mono by removing the side signal
d1 $ n "<~ [0,3,6]>*8" # s "superprimes" # pF "side" 0

-- or maybe just make it a little narrower
d1 $ n "<~ [0,3,6]>*8" # s "superprimes" # pF "side" 0.5

-- removing the mid signal could be fun sometimes
d1 $ n "<~ [0,3,6]>*8" # s "superprimes" # pF "mid" 0

-- unfortunately this breaks SuperDirt's panning because the mid/side module comes after it...
d1 $ n "<~ [0,3,6]>*8" # s "superprimes" # pF "side" 0 # pan rand

-- ...so i added another panning stage, controlled by mspan
d1 $ n "<~ [0,3,6]>*8" # s "superprimes" # pF "side" 0 # pF "mspan" rand