linear interpolation transducer

linear_interpolate.clj

(defn linear-interpolate
  ([]
   (fn [rf]
     (let [rrf (#'clojure.core/preserving-reduced rf)
           skipped (volatile! 0)    ;; n of contiguous nils
           prev    (volatile! nil)] ;; most recent value seen
       (fn
         ([] (rf)) ;; init
         ([result] ;; completion -- skipped stay nils since no endpoint
          (rf (reduce rf result (repeat @skipped nil))))
         ([result x] ;; step
          (if (nil? x)
            (if (nil? @prev)
              (rf result nil)
              (do (vswap! skipped inc)
                  result))
            (if (or (zero? @skipped) (nil? @prev))
              (do (vreset! prev x)
                  (rf result (double x)))
              (let [delta (/ (- x @prev) (inc @skipped))
                    xs (->> (iterate #(+ % delta) @prev)
                            (drop 1)
                            (take @skipped))]
                (do (vreset! skipped 0)
                    (vreset! prev x)
                    (reduce rrf result (map double (concat xs [x]))))))))))))
  ([coll]
   (sequence (linear-interpolate) coll)))