Trigger recursion control with static variables fails with roll-backs

AccountExclamation.cls

public with sharing class AccountExclamation implements TriggerAction.BeforeUpdate {

    public void beforeUpdate(List<Account> newList, List<Account> oldList) {
        for(Account thisAccount : newList) {
            if(TriggerBase.idToNumberOfTimesSeenBeforeUpdate.get(thisAccount.Id) == 1 && !thisAccount.Name.endsWith('!')) {
                thisAccount.Name += '!';
            }
        }
    }
}

AccountExclamationTest.cls

@IsTest
private class AccountExclamationTest {

    static Account testAccount = new Account(Name = 'ACME');

    static {
        insert testAccount;
    }

    @IsTest
    static void standardBehaviour() {
        testAccount = [SELECT Name FROM Account];
        System.assert(!testAccount.Name.endsWith('!'));

        update testAccount;

        testAccount = [SELECT Name FROM Account];
        System.assert(testAccount.Name.endsWith('!'));
    }

    @IsTest
    static void withRollback() {
        testAccount = [SELECT Name FROM Account];
        System.assert(!testAccount.Name.endsWith('!'));

        Savepoint sp = Database.setSavepoint();
        update testAccount;
        Database.rollback(sp);
        update testAccount;

        testAccount = [SELECT Name FROM Account];
        System.assert(testAccount.Name.endsWith('!')); // FAILS
    }

    @IsTest
    static void allOrNothingFalse() {
        testAccount = [SELECT Name FROM Account];
        System.assert(!testAccount.Name.endsWith('!'));

        Database.update(new Account(Id = testAccount.Id, ParentId = testAccount.Id), false);
        update testAccount;

        testAccount = [SELECT Name FROM Account];
        System.assert(testAccount.Name.endsWith('!')); // FAILS
    }
}