tile.frag

#ifdef GL_ES
precision mediump float;
#endif

uniform vec2 u_resolution;
uniform float u_time;

#define PI 3.14159265358979323846

vec2 rotate2D(vec2 _st, float _angle){
    _st -= 0.5;
    _st =  mat2(cos(_angle),-sin(_angle),
                sin(_angle),cos(_angle)) * _st;
    _st += 0.5;
    return _st;
}

vec2 tile(vec2 _st, float _zoom){
    _st *= _zoom;
    return fract(_st);
}

float box(vec2 _st, vec2 _size, float _smoothEdges){
    _size = vec2(0.5)-_size*0.5;
    vec2 aa = vec2(_smoothEdges*0.5);
    vec2 uv = smoothstep(_size,_size+aa,_st);
    uv *= smoothstep(_size,_size+aa,vec2(1.0)-_st);
    return uv.x*uv.y;
}

void main(void){
    vec2 st = gl_FragCoord.xy/u_resolution.xy;
    vec3 color = vec3(0.0);
    float zoom = 10.;
    float p = u_time;
    float q = -u_time;
    if (fract(st.y*zoom*0.5) > 0.5){
        p = -u_time;
        q = u_time;
    }

    st = tile(st,zoom);

    vec2 origSt = st;
    st = rotate2D(st,PI*0.25+p);
    vec2 st2 = rotate2D(origSt,PI*0.25+q);
    
    color = vec3(box(st,vec2(0.7),0.01) - box(st2,vec2(0.2),0.01));

    gl_FragColor = vec4(color,1.0);
}