AutoHotkey kodlarıyla farenin tuşu ile tıklama, Sürükleme ve bırakma

click-3.ahk

; AutoHotkey kodlarıyla farenin tuşu ile tıklama, Sürükleme ve bırakma
; 13/05/2024
; Mesut Akcan
; makcan@gmail.com
; youtube.com/mesutakcan

#Requires AutoHotkey v2.0 

SendMode "Event"
SetMouseDelay 50
CoordMode "Mouse","Screen"

; Esc tuşu ile programı sonlandır.
Esc::ExitApp()

1:: ;Klavyedeki 1 tuşu basıldığında
{
  MouseGetPos &x,&y ; fare konumunu x ve y değişkenlerine aktar
  Click "D" ; Fare sol tuşuna basılı tut
  Click 470,540,"U" ; fareyi 470,540 konumuna sürükle ve sol tuşu bırak
  SetMouseDelay -1 ; Fare işlemlerinde bekleme olmasın
  ;Click x,y ; fareyi x,y konumuna taşı
  MouseMove x,y ; fareyi x,y konumuna taşı
}

2:: ;Klavyedeki 2 tuşu basıldığında
{
  Click "D" ; Fare sol tuşuna basılı tut
  Click 300,300,"U","Rel" ;fareyi bulunduğu konumdan göreceli x:300 y:400 konumuna sürükle ve sol tuşu bırak
}

; Yıldız çiz
3:: ;Klavyedeki 3 tuşu basıldığında
{
  SetMouseDelay -1 ; Fare işlemlerinde bekleme olmasın
  MouseGetPos &x,&y ; fare konumunu x ve y değişkenlerine aktar
  cizgiSayisi :=Integer(InputBox("Çizgi sayısı:").Value) ; Kullanıcıdan çizgi sayısını iste
  aci:=0 ; başlangıç açısı 0
  pi:=4*ATan(1) ; bu formül pi sayısını verir
  Loop cizgiSayisi { ;cizgiSayisi kadar döngü
    Click x,y,"D" ; x,y konumuna git fare sol tuşuna basılı tut
    aci:=(A_Index-1) * 360/cizgiSayisi * pi/180 ; döngüdeki açıyı hesapla. radyana dönüştür
    x2:=Integer(x+(100 * Cos(aci))) ; çizgi uç noktasının x konumu
    y2:=Integer(y+(100 * Sin(aci))) ; çizgi uç noktasının y konumu
    Click x2,y2,"U" ; çizgi uç noktasına fareyi sürükle, sol tuşu bırak
  }
}

; Çokgen çiz
4:: ;Klavyedeki 4 tuşu basıldığında
{
  SetMouseDelay -1 ; Fare işlemlerinde bekleme olmasın
  MouseGetPos &x,&y ; fare konumunu x ve y değişkenlerine aktar
  kenarSayisi :=Integer(InputBox("Kenar sayısı:").Value) ; Kullanıcıdan kenar sayısını iste
  aci:=0 ; başlangıç açısı 0
  pi:=4*ATan(1) ; bu formül pi sayısını verir
  Loop kenarSayisi+1 { ;kenarSayisi+1 kadar döngü
    aci:=(A_Index-1) * 360/kenarSayisi * pi/180 ; döngüdeki açıyı hesapla. radyana dönüştür
    x2:=Integer(x+(100 * Cos(aci))) ; çokgen köşe noktasının x konumu
    y2:=Integer(y+(100 * Sin(aci))) ; çokgen köşe noktasının y konumu
    Click x2,y2,"D" ; çokgen köşe noktasına fareyi sürükle, sol tuşu bırak
    Sleep 300 ; 300ms bekle
  }
  Click "U" ; fare sol tuşunu bırak
}