Ejemplo Swing Kawa

simple_frame.scm

;; -*- coding:utf-8; mode:Scheme -*-

"Shows howto use Java Swing classes in Kawa Scheme"

(define-alias JLabel javax.swing.JLabel)
(define-alias JButton javax.swing.JButton)

;;========================================================================
(define-simple-class SimpleFrame (javax.swing.JFrame)
  ;; members
  (label ::JLabel init: (JLabel "Swing Application in Kawa"))
  (button init: (JButton "Click Me!"
                         action-listener: (lambda (event)(on-click-btn))))
  ;;----------------------------------------------------------------------
  ;; methods
  ((*init*) ;constructor
   (invoke-special javax.swing.JFrame (this) '*init* "Hello Swing in Kawa")
   (format #t "Initializing ...~%")
   ;; initialize UI
   (add label java.awt.BorderLayout:CENTER)
   (add button java.awt.BorderLayout:SOUTH)
   (setDefaultCloseOperation javax.swing.JFrame:EXIT_ON_CLOSE)
   (pack))
  ;;----------------------------------------------------------------------
  ((on-click-btn)  ;event handler
   (label:setText "You clicked the button!")))
;;========================================================================
(define (main)
  (let ((frame (SimpleFrame)))
    (frame:setVisible #t)))

(main)

No, de hecho las definiciones de clases en Kawa no son inmutables, esta es una diferencia con respecto a Clojure AFAIK.