Example of Phrase for Map Validation

phrase-map-01.cljs

#!/usr/bin/env planck -D phrase:0.3-alpha2

(require '[clojure.spec.alpha :as s])
(require '[phrase.alpha :refer [defphraser phrase]])

(s/def ::required-string (s/and string? not-empty))
(s/def ::name ::required-string)
(s/def ::phone (s/and string? #(re-matches #"(\+47)?\d+" %)))
(s/def ::email (s/and string? #(re-matches #".+@.+" %)))
(s/def ::first-name ::name)
(s/def ::last-name ::name)
(s/def ::orderer (s/keys :req-un [::first-name ::last-name ::email ::phone]))

(defphraser #(re-matches _ %) 
  {:via [::phone]} 
  [_ _] 
  "Invalid phone number.")

(defphraser #(re-matches _ %) 
  {:via [::email]} 
  [_ _] 
  "Invalid email.")

(def invalid-orderer 
  {:first-name "asdf"
   :last-name "hello" 
   :email "asdf" 
   :phone "hello"})

(->> (s/explain-data ::orderer invalid-orderer) 
     ::s/problems 
     (map #(assoc % :msg (phrase nil %))) 
     (reduce (fn [r {:keys [path msg]}]
               (assoc r (first path) msg)) {})
     (println))

• install planck
• download phrase-map-01.cljs
• run:

chmod +x phrase-map-01.cljs 
./phrase-map-01.cljs 

• should output:

{:email Invalid email., :phone Invalid phone number.}