Extruct java thread dumps from a log file

extract-tdumps.clj

#!/usr/bin/env inlein

'{:dependencies [[org.clojure/clojure "1.9.0"]]}

(require '[clojure.string :as s]
         '[clojure.java.io :as io])

(def filename (first *command-line-args*))

(when-not filename
  (println "Usage:" (System/getProperty "$0") "logfile")
  (System/exit 1))

(defn write-dump
  [index lines]
  (let [dump (s/join \newline lines)
        filename (format "dump-%d.tdump" index)]
    (println filename)
    (with-open [w (io/writer (io/file filename))]
      (.write w dump))))

(defn parse-log
  [path]
  (let [lines (s/split-lines (slurp path))]
    (loop [lines lines
           dumps []
           current []
           prev nil]
      (if lines
        (let [line (first lines)]
          (cond
            (s/starts-with? line "Full thread dump Java") (recur (next lines) dumps (conj [] prev line) line)
            (s/starts-with? line "  class space") (recur (next lines) (conj dumps (conj current line)) [] line)
            :else (if (empty? current) (recur (next lines) dumps [] line) (recur (next lines) dumps (conj current line) line))))
        dumps))))

(doall (map-indexed (fn [index dump] (write-dump index dump)) (parse-log filename)))