README.md

Snippet to apply retry plugin to all projects

settings.gradle

plugins {
    id "org.gradle.test-retry" version "1.3.1" apply false
}

def isCiServer = System.getenv().containsKey("CI")
gradle.beforeProject { p ->
    p.pluginManager.withPlugin("java") {
        p.apply(plugin: "org.gradle.test-retry")
        p.tasks.withType(Test).configureEach {
            retry {
                if (isCiServer) {
                    maxRetries.set(1)
                    maxFailures.set(5)
                }
                failOnPassedAfterRetry.set(true)
            }
        }
    }
}

settings.gradle.kts

plugins {
    id("org.gradle.test-retry") version("1.3.1") apply(false)
}

val isCiServer = System.getenv().containsKey("CI")
gradle.beforeProject {
    pluginManager.withPlugin("java") {
        apply(plugin = "org.gradle.test-retry")
        tasks.withType<Test>().configureEach {
            retry {
                if (isCiServer) {
                    maxRetries.set(1)
                    maxFailures.set(5)
                }
                failOnPassedAfterRetry.set(true)
            }
        }
    }
}