Fix case Task

Task.cfc

component {

	variables.sourceFiles = [];
	variables.componentPaths = [];
	variables.verbose = true;
	variables.updated = 0;
	
	public function run() {
		var sourceFiles = findSourceFiles();
		sourceFiles.each(fixDottedPath);
		print.line("#sourceFiles.len()# processed. #variables.updated# updated");
	}

	array private function findSourceFiles() {
		if (!variables.sourceFiles.len()) {
			var Globber = globber( getCWD() & "**.cf*" );
			variables.sourceFiles = Globber.matches().map((el) => el.replace(getCWD(), ''));
		}
		return variables.sourceFiles;
	}

	array private function pathsToCheck() {
		if (!variables.componentPaths.len()) {
			variables.componentPaths = findSourceFiles()
				.filter((el) => el.right(4) == '.cfc')
				.map(pathToDotted);
		}
		return variables.componentPaths;
	}

	string private function pathToDotted(el) {
		var path = el.reReplace('\.cfc$', '');
		return path.replace(server.separator.file, '.', 'all');
	}

	void function fixDottedPath(sourcefilepath) {
		var fileContent = fileRead(sourcefilepath);
		var pre = hash(fileContent);
		var dottedPathsCorrectCase = pathsToCheck();
		dottedPathsCorrectCase.each((el) => {
			fileContent = fileContent.replaceNoCase(el, el, 'all');
		});
		if (compare(hash(filecontent), pre) != 0) {
			debug("file '#sourcefilepath#' updated");
			variables.updated++;
			fileWrite(sourcefilepath, fileContent);
		}
	};

	void function debug(message) {
		if (variables.verbose) {
			print.line(message);
		}
	}

}