Модульный подход к разработке на примере программы на языке F#

readme.txt

Форматируем исходники: fantomas .
Запускаем REPL с указанием дополнительный путей поиска исходников: dotnet fsi --lib:c:\lab\fscripts\MeteoInfo
В репле грузим основной модуль:> #load "Main.fsx";;
Загружаем ифну:> Main.printBarnaul();;
или запускаем скрипт из командной строки: dotnet fsi --exec main.fsx
или делаем файл исполняемым(в GNU Linux):
chmod +x Main.fsx
добавляем первой строкой
#!/usr/bin/env -S dotnet fsi --exec
и запускаем как обычную программу: ./Main.fsx

https://docs.microsoft.com/ru-ru/dotnet/fsharp/tools/fsharp-interactive/

ConsoleUtils.fsx

let color col =
    let old = System.Console.ForegroundColor
    System.Console.ForegroundColor <- col

    { new System.IDisposable with
        member it.Dispose() = System.Console.ForegroundColor <- old }

let red () = color System.ConsoleColor.Red
let cyan () = color System.ConsoleColor.Cyan
let green () = color System.ConsoleColor.Green
let yellow () = color System.ConsoleColor.Yellow

let cls () = System.Console.Clear()

Main.fsx

#!/usr/bin/env -S dotnet fsi --exec
#load "Meteo.fsx"

open Meteo

let printBarnaul () =
    MeteoInfo.Load "https://meteoinfo.ru/rss/forecasts/index.php?s=29838"
    |> printMeteoInfo

#time

printBarnaul ()

Meteo.fsx

#r "nuget: fsharp.data"
#load "ConsoleUtils.fsx"
#load "TextUtils.fsx"

open FSharp.Data
open ConsoleUtils
open TextUtils

type MeteoInfo = XmlProvider<"https://meteoinfo.ru/rss/forecasts/index.php?s=29838">

let printMeteoInfo (data: MeteoInfo.Rss) =
    cls ()

    for e in data.Channel.Items do
        use _ = red ()
        printfn $"\n{e.Title}"
        use _ = yellow ()
        e.Description |> fmt |> (printfn "%s")

    use _ = cyan () in
    printf $"\nОбновлено: "
    use _ = green () in printfn $"{System.DateTime.Now:s}"

TextUtils.fsx

let fmt s =
    [| for c in s do
           if System.Char.IsUpper c then yield '\n'
           yield c |]
    |> System.String