指定したフレーム数だけステージをキャプチャしてデスクトップに保存する

Recorder.as

// 1フレーム目に以下のスクリプトを記述する
// new Recorder(stage /*ステージ*/, 60 /*キャプチャしたいフレーム総数*/, "loading" /*プリフィックス*/);

package
{
	import flash.desktop.NativeApplication;
	import flash.display.BitmapData;
	import flash.display.Stage;
	import flash.events.Event;
	import flash.filesystem.File;
	import flash.filesystem.FileMode;
	import flash.filesystem.FileStream;
	import flash.geom.Point;
	import flash.utils.ByteArray;

	public class Recorder
	{

		//----------------------------------------------------------
		//
		//   Constructor 
		//
		//----------------------------------------------------------

		public function Recorder(stage:Stage, totalFrames:int, baseName:String = "capture"):void
		{
			_stage = stage;
			_totalFrames = totalFrames;
			_baseName = baseName;
			_index = 0;
			_dir = File.desktopDirectory.resolvePath(_baseName);
			_bmd = new BitmapData(stage.stageWidth, stage.stageHeight, true, 0x0);
			_clear = _bmd.clone();
			_stage.addEventListener(Event.ENTER_FRAME, _enterFrameHandler);
			_enterFrameHandler();
		}

		//----------------------------------------------------------
		//
		//   Property 
		//
		//----------------------------------------------------------

		private var _baseName:String;
		private var _bmd:BitmapData;
		private var _clear:BitmapData;
		private var _dir:File;
		private var _index:int;
		private var _stage:Stage;
		private var _totalFrames:int;

		//----------------------------------------------------------
		//
		//   Function 
		//
		//----------------------------------------------------------

		private function _enterFrameHandler(event:Event = null):void
		{
			_bmd.copyPixels(_clear, _clear.rect, new Point());
			_bmd.draw(_stage);
			var bytes:ByteArray = PNGEncoder.encode(_bmd);
			var fs:FileStream = new FileStream();
			var file:File = _dir.resolvePath(_baseName + "_" + _index + ".png");
			trace("save " + (_index + 1) + " : " + file.nativePath);
			fs.open(file, FileMode.WRITE);
			fs.writeBytes(bytes);
			fs.close();
			bytes.clear();
			if (++_index == _totalFrames)
			{
				_stage.removeEventListener(Event.ENTER_FRAME, _enterFrameHandler);
				NativeApplication.nativeApplication.exit();
			}
		}
	}
}

/*
Copyright (c) 2008, Adobe Systems Incorporated
All rights reserved.

Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are
met:

* Redistributions of source code must retain the above copyright notice,
this list of conditions and the following disclaimer.

* Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in the
documentation and/or other materials provided with the distribution.

* Neither the name of Adobe Systems Incorporated nor the names of its
contributors may be used to endorse or promote products derived from
this software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/
import flash.display.BitmapData;
import flash.utils.ByteArray;

/**
 * Class that converts BitmapData into a valid PNG
 */
internal class PNGEncoder
{

	//----------------------------------------------------------
	//
	//   Static Property 
	//
	//----------------------------------------------------------

	private static var crcTable:Array;
	private static var crcTableComputed:Boolean = false;

	/**
	 * Created a PNG image from the specified BitmapData
	 *
	 * @param image The BitmapData that will be converted into the PNG format.
	 * @return a ByteArray representing the PNG encoded image data.
	 * @langversion ActionScript 3.0
	 * @playerversion Flash 9.0
	 * @tiptext
	 */
	public static function encode(img:BitmapData):ByteArray
	{
		// Create output byte array
		var png:ByteArray = new ByteArray();
		// Write PNG signature
		png.writeUnsignedInt(0x89504e47);
		png.writeUnsignedInt(0x0D0A1A0A);
		// Build IHDR chunk
		var IHDR:ByteArray = new ByteArray();
		IHDR.writeInt(img.width);
		IHDR.writeInt(img.height);
		IHDR.writeUnsignedInt(0x08060000); // 32bit RGBA
		IHDR.writeByte(0);
		writeChunk(png, 0x49484452, IHDR);
		// Build IDAT chunk
		var IDAT:ByteArray = new ByteArray();
		for (var i:int = 0; i < img.height; i++)
		{
			// no filter
			IDAT.writeByte(0);
			var p:uint;
			var j:int;
			if (!img.transparent)
			{
				for (j = 0; j < img.width; j++)
				{
					p = img.getPixel(j, i);
					IDAT.writeUnsignedInt(
						uint(((p & 0xFFFFFF) << 8) | 0xFF));
				}
			}
			else
			{
				for (j = 0; j < img.width; j++)
				{
					p = img.getPixel32(j, i);
					IDAT.writeUnsignedInt(
						uint(((p & 0xFFFFFF) << 8) |
						(p >>> 24)));
				}
			}
		}
		IDAT.compress();
		writeChunk(png, 0x49444154, IDAT);
		// Build IEND chunk
		writeChunk(png, 0x49454E44, null);
		// return PNG
		return png;
	}

	private static function writeChunk(png:ByteArray,
		type:uint, data:ByteArray):void
	{
		if (!crcTableComputed)
		{
			crcTableComputed = true;
			crcTable = [];
			var c:uint;
			for (var n:uint = 0; n < 256; n++)
			{
				c = n;
				for (var k:uint = 0; k < 8; k++)
				{
					if (c & 1)
					{
						c = uint(uint(0xedb88320) ^
							uint(c >>> 1));
					}
					else
						c = uint(c >>> 1);
				}
				crcTable[n] = c;
			}
		}
		var len:uint = 0;
		if (data != null)
			len = data.length;
		png.writeUnsignedInt(len);
		var p:uint = png.position;
		png.writeUnsignedInt(type);
		if (data != null)
			png.writeBytes(data);
		var e:uint = png.position;
		png.position = p;
		c = 0xffffffff;
		for (var i:int = 0; i < (e - p); i++)
		{
			c = uint(crcTable[
				(c ^ png.readUnsignedByte()) &
				uint(0xff)] ^ uint(c >>> 8));
		}
		c = uint(c ^ uint(0xffffffff));
		png.position = e;
		png.writeUnsignedInt(c);
	}
}