CategoryController.groovy

package com.odobo.gr8conf

import grails.rest.RestfulController
import grails.transaction.Transactional

@Transactional(readOnly = true)
class CategoryController extends RestfulController {

    static responseFormats = ['json', 'xml']

    CategoryController() {
        super(Category)
    }

    @Override
    protected List<Category> listAllResources(Map params) {
        if (params.gameId) {
            Game.get(params.gameId).categories as List
        } else {
            Category.list(params)
        }
    }

    @Override
    protected Integer countResources() {
        if (params.gameId) {
            Game.get(params.gameId).categories.size()
        } else {
            Category.count()
        }
    }
}

CategorySpec.groovy

package com.odobo.gr8conf

import spock.lang.Shared
import spock.lang.Specification
import wslite.rest.ContentType
import wslite.rest.RESTClient
import wslite.rest.Response


class CategorySpec extends Specification {

    @Shared
    RESTClient restClient = new RESTClient("http://localhost:8080/restful-gr8conf-2014")

    def "it returns all the cateogories"() {
        when:
        Response response = restClient.get(path: "/categories", accept: ContentType.JSON)

        then:
        response.json.size() == 5
    }

    def "it returns just the categories of a game when is a nested resource"() {
        when:
        Response response = restClient.get(path: "/games/5/categories", accept: ContentType.JSON)

        then:
        response.json.size() == 2
    }

}