Steam -no-browser after patch

README.md

Steam -no-browser after patch (Working June 2023)

• Disregard the original steam shortcut and only use the batch scripts below to launch steam

• There is a slight CPU utilization penalty which can be circumvented by suspending the problematic thread

  • See this comment

steam-no-browser.bat:

@echo off
setlocal EnableDelayedExpansion

set "steam_path=C:\Program Files (x86)\Steam"

:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"

:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
    set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
    if exist "!bin!" (
        ren "!bin!" "steamwebhelper.exe"
    )
)

:: open steam
start "" "!steam_path!\steam.exe" +open steam://open/minigameslist -vgui

:: only continue if steamwebhelper is running in case steam is updating
:query_steamwebhelper
tasklist | findstr /i "steamwebhelper.exe" || goto :query_steamwebhelper

:: allow a few seconds for steam to initialize/login
timeout /t 5 /nobreak

:: rename binary and kill the process
for %%a in ("cef.win7", "cef.win7x64") do (
    set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exe"
    if exist "!bin!" (
        ren "!bin!" "steamwebhelper.exee"
    )
)

taskkill /f /im "steamwebhelper.exe"

steam-normal.bat:

@echo off
setlocal EnableDelayedExpansion

set "steam_path=C:\Program Files (x86)\Steam"

:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"

:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
    set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
    if exist "!bin!" (
        ren "!bin!" "steamwebhelper.exe"
    )
)

:: open steam
start "" "!steam_path!\steam.exe"

I'm not aware of a method that works currently. Haven't looked either since I don't use steam.

yup me to, i switched to epic games from steam coz 200mb to 400 mb is too much for me plus cpu spike by steam webhelper no matter what tweak i use they revert back after few updates by steam
as most games i play r already available in epic so i m using epic on Rare launcher open-source ,light , fast takes 40mb and closes automatically with game