Ebuild for the standalone version of KWin https://groups.google.com/group/razor-qt/msg/b1d21a0cb8b665a2

kwin-standalone-9999.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit cmake-utils git-2

DESCRIPTION="KWin version that only depends on kdelibs"
HOMEPAGE="https://groups.google.com/group/razor-qt/msg/b1d21a0cb8b665a2"
SRC_URI=""
EGIT_REPO_URI="git://anongit.kde.org/clones/kde-workspace/graesslin/kde-workspace.git"
EGIT_BRANCH="kwin/standalone"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="gles opengl"
REQUIRED_USE="!opengl? ( gles ) !gles? ( opengl )"

DEPEND="!kde-base/kwin
	kde-base/kdelibs
	dev-qt/qtcore
	dev-qt/qtdbus
	dev-qt/qtdeclarative
	dev-qt/qtgui
	dev-qt/qtscript
	x11-libs/libSM
	x11-libs/libXcomposite
	x11-libs/libXcursor
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libXxf86vm"
RDEPEND="${DEPEND}"


CMAKE_USE_DIR="${S}/kwin"

src_prepare() {
	sed -i -e "s:set(KWIN_NAME \"kwin\"):set(KWIN_NAME \"${PN}\"):" \
		"${CMAKE_USE_DIR}/CMakeLists.txt" || die
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_with gles OpenGLES)
		$(cmake-utils_use gles KWIN_BUILD_WITH_OPENGLES)
		$(cmake-utils_use_with opengl OpenGL)
		-DWITH_X11_Xcomposite=ON

		-DKWIN_BUILD_OXYGEN=OFF
		-DKWIN_BUILD_KCMS=OFF
		-DKWIN_BUILD_KAPPMENU=OFF
		-DKWIN_BUILD_ACTIVITIES=OFF
	)

	cmake-utils_src_configure
}