PKGBUILD

# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>

pkgname=jiri-git
pkgver=r1423
pkgrel=1
pkgdesc='A tool for multi-repo development similar to Android repo'
arch=(i686 x86_64)
url='https://fuchsia.googlesource.com/jiri'
license=(MIT)
depends=()
makedepends=(git go cmake ninja python2 dep)
source=(
  git+https://fuchsia.googlesource.com/jiri
)
sha1sums=('SKIP')

pkgver() {
  cd jiri
  echo r$(git rev-list --count master)
}

prepare() {
  mkdir -p gopath/src/fuchsia.googlesource.com
  ln -rTsf jiri gopath/src/fuchsia.googlesource.com/jiri
  export GOPATH="$srcdir"/gopath

  # the dependencies can be fetched here if needed
  cd gopath/src/fuchsia.googlesource.com/jiri
  dep init
  dep ensure
}

build() {
  export GOPATH="$srcdir"/gopath
  cd gopath/src/fuchsia.googlesource.com/jiri
  go install -v .
}

package() {
  cd jiri
  install -D -m755 jiri "$pkgdir"/usr/bin/jiri
  install -D -m644 scripts/jiri-bash-completion.sh "$pkgdir"/usr/share/bash-completion/completions/jiri
}