List all Gradle Dependencies

allDependencies.gradle

/**
 * List all Dependencies of main / subprojects for given configurations.
 */
task allDependencies {
    doLast {
        // only check defined configurations
        def includedConfigurations = ['compile', 'testCompile', 'runtime']

        def deps = [:]
        allprojects.each { p ->
            p.configurations.all.findAll {
                !it.allDependencies.empty && includedConfigurations.contains(it.name)
            }.each { config ->
                // create a SortedSet per configuration
                if (!deps.containsKey(config.name)) {
                    deps[config.name] = [] as SortedSet
                }
                // add dependencies to matching set
                config.allDependencies.each { dep ->
                    deps[config.name].add("$dep.group:$dep.name:$dep.version")
                }
            }
        }

        // print sorted dependencies per configuration
        deps.each { config, configDeps ->
            println " ${config} ".center(60, '-')

            configDeps.each { dep ->
                println dep
            }
            println "-" * 60
        }
    }
}