AUR apfs-fuse-git

PKGBUILD

# Maintainer: Adam Harvey <adam@adamharvey.name>
pkgname=apfs-fuse-git
pkgver=r54.cecf2aa
pkgrel=1
pkgdesc="FUSE driver for APFS (Apple File System)"
arch=('i686' 'x86_64')
url="https://github.com/sgan81/apfs-fuse"
license=('GPL')
groups=()
depends=('fuse2')
makedepends=('git' 'fuse2' 'cmake')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
replaces=()
backup=()
options=()
install=
source=(
  'apfs-fuse::git+https://github.com/sgan81/apfs-fuse'
  'https://patch-diff.githubusercontent.com/raw/sgan81/apfs-fuse/pull/53.diff'
)
noextract=()
sha256sums=(
  'SKIP'
  '2382ef70c34ebc24f74dac3f0a156526be868eb6d50a35c942cdd421211fb69d'
)

pkgver() {
  cd "$srcdir/${pkgname%-git}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/${pkgname%-git}"
  git apply "${srcdir}/53.diff"
  git submodule update --init
}

build() {
  cd "$srcdir/${pkgname%-git}"
  mkdir -p build
  cd build
  cmake ..
  make
}

package() {
  cd "$srcdir/${pkgname%-git}"
  mkdir -p "$pkgdir/usr/bin"
  install -Dm755 build/bin/{apfs-dump,apfs-dump-quick,apfs-fuse,lzfse} "$pkgdir/usr/bin"
}

Patch is merged, you can remove it.